/HELP PROGRAM
	/NOTE: RIM AND BIN LOADER MUST BE IN CORE
	/BEFORE USING THE SOURCE PROGRAM
	/TO GENERATE THE BOOTSTRAP LOADER.
*7400
	CLA CLL
	TLS
	TAD KOUNT
	DCA KOWNT
	TAD BGIN
	DCA START	/CONTAINS CONTENT OF FIRST
	TAD BGIN	/ADDRESS TO BE PUNCHED
	DCA COUNT	/CREATE SOME BLANK TAPE
	JMS PUNCH
	ISZ COUNT	/DONE PUNCHING BLANK TAPE?
	JMP .-2		/NO
LOOP,	TAD I START
	JMS PUNCH
	ISZ START	/MODIFY ADDRESS IN START
	ISZ KOWNT	/DONE WITH FIRST SECTION?
	JMP LOOP	/NO, GO BACK
LOADER,	TAD I START	/NOW START PUNCHING BINARY
	RTR		/CONTENT ON 2 LINES OF OUTPUT
	RTR
	RTR
	AND MASK	/SAVE LEFT HALF OF WORD
	JMS PUNCH	/PUNCH IT
	TAD I START
	AND MASK
	JMS PUNCH	/PUNCH THE RIGHT HALF
	ISZ START	/MODIFY ADDRESS
	JMP LOADER
	TAD BGIN
	DCA COUNT
	TAD COD200
	JMS PUNCH	/PUNCH CHANNEL 8
	ISZ COUNT	/DONE?
	JMP .-3		/NO
	HLT
PUNCH,	0
	TSF
	JMP .-1
	TLS
	CLA
	JMP I PUNCH
BGIN,	7551		/7551 IS USED AS S.A. AND AS A COUNTER
COUNT,	0
MASK,	77
KOUNT,	-27		/NO. OF INST. FROM 7751 TO 7577
KOWNT,	0
COD200,	200
START,	0
*7551
	50		/5 (GETS PUT IN LOC. 7 AS 1ST INSTRUCTION
	317		/KSF     OF NEW PROGRAM)
	102		/JMP 10
	367		/KRB
	67		/RTL
	67		/RTL
	67		/RTL
	51		/DCA 5
	317		/KSF
	172		/JMP 17
	367		/KRB
	54		/TAD 5
	231		/DCA 23
	 75		/ISZ 7
	106		/JMP 10
	 66		/JMP 6
	102		/JMP 10 (TRANSFERS CONTROL TO NEW PRO)
	34
	07		/3407 IS DCA I 7
	74
	02		/7402 IS AN HLT
	75
	77		/7577 IS THE S.A. OF BIN LOADER-1
$