/EAE PART 3A OF INSTRUCTION TEST

CAM=7621
SCA=7441
NMI=7411
ASR=7415
MQL=7421
MQA=7501
LSR=7417
SHL=7413

*0020
GEN,	0
	ISZ Z GENX
	JMP I GEN
	CLA OSR			/TEST SW 3
	RTL CLL
	RTL
	SZL
	JMP I BACK
	JMP I NEXT
BACK,	0000
NEXT,	0000
XMQLT1,		MQLT1
XMQAT,	MQAT
XMQAT1,		MQAT1

CRLF,	0
	CLA CMA
	AND CR			/CR
	JMS PRXLOP
	CLA CMA
	AND LF			/LF
	JMS PRXLOP
	JMP I CRLF

PRXLOP,	0
	TLS			/PRINT LOOP
	TSF
	JMP .-1
	CLA
	JMP I PRXLOP

PLINK,	0
	CLA CMA
	AND LINK		/LINK
	JMS ONZER
	JMP I PLINK

ONZER,	0
	SZA
	JMP ONEP		/PRINT ONE
	JMS ZEROR		/PRINT ZERO
	JMP I ONZER
ONEP,	CLA CMA			/ONE
	AND ONE
	JMS PRXLOP
	JMP I ONZER
ZEROR,	0
	CLA CMA
	AND  ZERO		/ZERO
	JMS PRXLOP
	JMP I ZEROR

MESSG,	0
	CLA CMA
	AND COUNTX
	DCA STRCNT
	ISZ STRCNT
	SKP
	JMP I MESSG
	CLA CMA
	AND BITSTR
	CLL
	RAL
	DCA BITSTR
	SZL
	JMP PRONE
	JMS ZEROR
	JMP .-13
PRONE,	CLA CMA
	AND ONE			/ONE
	JMS PRXLOP
	JMP MESSG+4
ACP,	0			/GOOD AC
LXP,	0			/GOOD LINK
GENX,	0
BLXP,	0			/BAD LINK
BACP,	0			/BAD AC
CR,	0215			/CARRIAGE RETURN
LF,	0212			/LINE FEED
M,	0315			/M
Q,	0321			/Q
LL,	0314			/L
TT,	0324			/T
SP,	0240			/SPACE
A,      0301                    /A
C,      0303                    /C
ONE,    0261                    /1
ZERO,   0260                    /0
LINK,   0
TO,     0255                    /DASH
COUNTX,	7763
STRCNT,	0
BITSTR,	0
XMQAT2,	MQAT2
XMQAT3,	MQAT3
INCOR,	0326			/V
XSCAT,	STEST
THREE,	0263			/3
TWO,	0262
SETL,	0
	CLA CMA
	JMP I SETL

PRNUM,	0
LFTAC,	0
RITAC,	0
RITMQ,	0
LFTMQ,	0
K7764,	7764
XK400,	4000

*0010
ACIND,	0
MQIND,	0
XACNMI,	0
XMQNMI,	0
*200
MQLT,	JMP HSE			/HOUSE KEEPING
	JMS Z GEN
	STL CLA CMA		/SET LINK
	AND Z GENX
	DCA Z ACP		/STORE AC PATTERN
	CLA CMA
	DCA Z LXP		/STORE LINK TO A ONE
	CMA
	AND Z ACP		/LOAD AC
	MQL
	DCA Z BACP		/STORE AC RESULT
	CLA SNL
	JMP XPACP+5		/STORE LINK RESULT 0000
	JMS Z SETL
	DCA Z BLXP		/STORE LINK RESULT 7777
	CMA
	AND Z BACP
	SZA
	JMP .+6			/AC NOT EQUAL TO 0000
	CLA CMA
	AND BLXP
	SNA
	JMP .+2			/LINK NOT EQUAL TO A ONE
	JMP .+12		/CONTINUE TEST MQLT

	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SZL
	JMS PMQLT		/PRINT ERROR
	CLL CLA OSR		/TEST SW 0
	RAL
	SZL
	HLT			/HALT MQLT ERROR
	CLA OSR
	RTL CLL			/TEST SW1
	SZL
	JMP MQLT+2		/PROGRAM LOOP
	JMP MQLT+1			/CONTINUE PROGRAM
HSE,	CLA CLL
	DCA Z GENX
	TAD XPACP+4
	DCA Z BACK
	TAD Z XMQLT1
	DCA Z NEXT
	NOP
	NOP
	JMP MQLT+1
PMQLT,	0			/PRINT ROUTINE
	JMS Z CRLF
	JMS MQ
	JMS L
	JMS T
CP,	JMS Z CRLF
	JMS SP2
	JMS AC
	JMS SP2
	JMS PLXP
	JMS SP1
	JMS I XPACP
	JMS Z CRLF
	JMS Z ZEROR
	JMS I XPACP+1		/RIGHT ARROW
	JMS AC
	JMS SP2
	JMS I XPACP+2
	JMS SP1
	JMS I XPACP+3
	JMP I PMQLT		/RETURN TO SWITCH ROUTINE

MQ,	0
	CLA CMA
	AND Z M			/M
	JMS Z PRXLOP
	CLA CMA
	AND Z Q			/Q
	JMS Z PRXLOP
	JMP I MQ

L,	0
	CLA CMA
	AND Z LL		/L
	JMS Z PRXLOP
	JMP I L

T,	0
	CLA CMA			/T
	AND Z TT
	JMS Z PRXLOP
	JMP I T

SP2,	0
	CLA CMA
	AND Z SP		/SP
	JMS Z PRXLOP
	CLA CMA
	AND Z SP		/SP
	JMS Z PRXLOP
	JMP I SP2
AC,	0
	CLA CMA
	AND Z A			/A
	JMS Z PRXLOP
	CLA CMA
	AND Z C			/C
	JMS Z PRXLOP
	JMP I AC

SP1,	0
	CLA CMA
	AND Z SP		/SP
	JMS Z PRXLOP
	JMP I SP1

PLXP,	0
	CLA CMA
	AND Z LXP		/GOOD LINK
	DCA Z LINK
	JMS Z PLINK
	JMP I PLXP
XPACP,	PACP
	PTO
	PBLXP
	PBACP
	MQLT
	DCA Z BLXP
	JMP MQLT+17
*400
PBLXP,	0
	CLA CMA
	AND Z BLXP		/BAD LINK
	DCA Z LINK
	JMS Z PLINK
	JMP I PBLXP

PTO,	0
	CLA CMA
	AND TO			/RIGHT ARROW
	JMS Z PRXLOP
	JMP I PTO

PACP,	0
	CLA CMA
	AND Z ACP		/ACP
	DCA Z BITSTR
	JMS Z MESSG
	JMP I PACP

PBACP,	0
	CLA CMA
	AND Z BACP		/BACP
	DCA Z BITSTR
	JMS Z MESSG
	JMP I PBACP

MQLT1,	JMP HSE1
	JMS GEN
	CLL CLA CMA		/CLEAR LINK
	AND Z GENX
	DCA Z ACP		/STORE AC PATTERN
	DCA Z LXP		/STORE LINK TO A ZERO
	CMA
	AND Z ACP		/LOAD AC
	MQL
	DCA Z BACP		/STORE AC RESULT
	CLA SNL
	JMP XONE+6		/STORE LINK RESULT 0000
	JMS Z SETL
	DCA Z BLXP		/STORE LINK RESULT 7777
	CMA
	AND Z BACP
	SZA
	JMP .+20		/AC NOT EQUAL TO 0000
	CLA CMA
	AND Z BLXP
	SZA
	JMP .+14		/LINK NOT EQUAL TO A ZERO
	JMP MQ1+4		/CONTINUE TEST MQLT1

HSE1,	CLA CLL
	DCA Z GENX
	TAD Z XMQLT1
	DCA Z BACK
	TAD Z XMQAT
	DCA Z NEXT
	NOP
	NOP
	NOP
	JMP MQLT1+1

	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SZL
	JMP XMQ1+1		/PRINT ERROR
MQ1,	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR
	RTL CLL
	SZL
	JMP MQLT1+2		/PROGRAM LOOP
	JMP MQLT1+1		/CONTINUE PROGRAM
XMQ1,	MQ1
	CLA CMA
	AND XMQ1
	DCA I XONE+5
	JMS Z CRLF
	JMS I XCP+1
	JMS I XCP+2
	JMS I XCP+3
	JMS XONE
	JMP I XCP
XCP,	CP
	MQ
	L
	T

XONE,	0
	CLA CMA			/ONE
	AND Z ONE
	JMS Z PRXLOP
	JMP I XONE
	PMQLT
	DCA Z BLXP
	JMP MQLT1+16
*600
MQAT,	JMP HSE2
	JMS GEN
	STL CLA CMA		/SET LINK
	AND Z GENX
	DCA Z ACP		/STORE AC PATTERN
	CLA CMA
	DCA Z LXP		/STORE LINK TO A ONE
	CMA
	AND Z ACP		/LOAD AC
	MQL			/LOAD MQ FROM AC
	MQA			/LOAD AC FROM MP
	DCA Z BACP		/STORE RESULT OF MQL MQA
	CLA SNL
	JMP YA+5		/STORE LINK RESULT 0000
	JMS Z SETL
	DCA BLXP
RL2,	CMA
	AND Z ACP		/COMPARE ACP WITH BACP
	CLL CMA
	TAD Z BACP
	CMA
	SNA
	SZL
	JMP HSE2+12		/MQ DID NOT EQUAL AC
	CLA CMA
	AND Z BLXP
	SNA
	JMP HSE2+12		/LINK DID NOT EQUAL A ONE
	JMP PMQAT-5

HSE2,	CLA CLL
	DCA Z GENX
	TAD Z XMQAT
	DCA Z BACK
	TAD Z XMQAT1
	DCA Z NEXT
	NOP
	NOP
	NOP
	JMP MQAT+1
	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SNL
	JMP .+3
	JMS PMQAT		/PRINT ERROR
	JMS MQA1
	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP MQAT+2		/PROGRAM LOOP
	JMP MQAT+1		/CONTINUE PROGRAM
PMQAT,	0
	JMS Z CRLF
	JMS I YSP2+5
	JMS AT
	JMP I PMQAT

MQA1,	0
	JMS Z CRLF
	JMS I YSP2+3
	JMS I YSP2
	JMS I YSP2
	JMS I YSP2+1
	JMS I YSP2
	JMS I YSP2+2
	JMS I YSP2+3
	JMS I YSP2+4
	JMS Z CRLF
	JMS I YSP2+5
	JMS I YSP2+6
	JMS I YSP2+3
	JMS I YSP2+5
	JMS YA
	JMS I YSP2
	JMS I YSP2+7
	JMS I YSP2+3
	JMS I YSP2+10
	JMP I MQA1
YSP2,	SP2
	AC
	PLXP
	SP1
	PACP
	MQ
	L
	PBLXP
	PBACP

AT,	0
	CLA CMA
	AND Z A			/A
	JMS Z PRXLOP
	CLA CMA
	AND Z TT		/T
	JMS Z PRXLOP
	JMP I AT

YA,	0
	CLA CMA
	AND Z A			/A
	JMS Z PRXLOP
	JMP I YA
	DCA Z BLXP
	JMP RL2
*1000
MQAT1,	JMP HSE3
	JMS GEN
	CLL CLA CMA		/CLEAR LINK
	AND Z GENX
	DCA Z ACP		/STORE AC PATTERN
	DCA Z LXP		/STORE LINK TO A ZERO
	CMA
	AND Z ACP		/LOAD AC
	MQL			/LOAD MQ FROM AC
	MQA			/LOAD AC FROM MQ
	DCA Z BACP		/STORE RESULT OF MQL, MQA
	CLA SNL
	JMP NOPR+14
	JMS Z SETL
	DCA Z BLXP		/STORE LINK RESULT 7777
	CMA
	AND Z ACP		/COMPARE ACP WITH BACP
	CLL CMA
	TAD Z BACP
	CMA
	SNA
	SZL
	JMP MQAER1		/MQ DID NOT EQUAL AC
	CLA CMA
	AND Z BLXP
	SZA
	JMP MQAER1		/LINK DID NOT EQUAL A ZERO
	JMP NOPR+4
HSE3,	CLA CLL
	DCA Z GENX
	TAD Z XMQAT1
	DCA Z BACK
	TAD Z XMQAT2
	DCA Z NEXT
	NOP
	NOP
	NOP
	JMP MQAT1+1
MQAER1,	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SNL
	JMP NOPR
	JMS I NOPR+11		/PRINT ERROR
	JMS I NOPR+12
	JMS I NOPR+13
NOPR,	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP MQAT1+2		/PROGRAM LOOP
	JMP MQAT1+1		/CONTINUE PROGRAM
	PMQAT
	XONE
	MQA1
	DCA Z BLXP
	JMP MQAT1+17
*1200
MQAT2,	JMP HSE4
	JMS GEN
	STL CLA CMA		/SET LINK
	AND Z GENX
	CMA			/COMPLEMENT GENX PATTERN
	DCA Z ACP		/STORE AC PATTERN
	CMA
	DCA Z LXP		/STORE LINK TO A ONE
	CMA
	AND Z GENX
	MQL			/LOAD MQ
	CLA CMA
	AND Z ACP		/LOAD AC WITH COMPLEMENTED GENX
	MQA
	DCA Z BACP		/STORE RESULT OF MQA
	CLA SNL
	JMP CLRL4		/STORE LINK RESULT 0000
	JMS Z SETL
	DCA Z BLXP		/STORE LINK RESULT 7777

RL4,	CLA CMA
	AND Z BACP		/AC SHOULD EQUAL 7777
	CMA
	SZA
	JMP MQAER2		/MQ DID NOT INCLUSIVE OR WITH AC
	CMA
	AND Z BLXP
	SNA
	JMP MQAER2		/LINK DID NOT EQUAL A ONE
	JMP LNPR2+4

HSE4,	CLA CLL
	DCA Z GENX
	TAD Z XMQAT2
	DCA Z BACK
	TAD Z XMQAT3
	DCA Z NEXT
	NOP
	NOP
	NOP
	JMP MQAT2+1

MQAER2,	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SNL
	JMP LNPR2		/PRINT ERROR
	JMS I XPMQAT
	JMS EMQAT2
LNPR2,	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP MQAT2+2		/PROGRAM LOOP
	JMP MQAT2+1		/CONTINUE PROGRAM
XPMQAT,	PMQAT

EMQAT2,	0
	JMS PTWO
AT3,	JMS Z CRLF
	JMS I XSP1+1
	JMS I XSP1
	JMS I XSP1+2
	JMS I XSP1+1
	JMS I XSP1+3
	JMS I XSP1
	JMS I XSP1+4
	JMS Z CRLF
	JMS I XSP1+1
	JMS I XSP1
	JMS I XSP1+5
	JMS I XSP1+1
	JMS I XSP1+1
	CLA CMA
	AND Z GENX
	DCA Z ACP
	JMS I XSP1+4
	JMS Z CRLF
	JMS I XSP1+5
	JMS VOR
	JMS I XSP1+2
	JMS I XSP1+1
	JMS I XSP1+6
	JMS I XSP1
	JMS I XSP1+7
	JMP I EMQAT2

XSP1,	SP1
	SP2
	AC
	PLXP
	PACP
	MQ
	PBLXP
	PBACP
VOR,	0			/PRINT INCLUSIVE OR
	CLA CMA
	AND Z INCOR
	JMS Z PRXLOP
	JMP I VOR

PTWO,	0			/PRINT 2
	CLA CMA
	AND Z TWO
	JMS Z PRXLOP
	JMP I PTWO
CLRL4,	DCA Z BLXP
	JMP RL4
*1400
MQAT3,	JMP HSE5
	JMS GEN
	CLL CLA CMA		/CLEAR LINK
	AND Z GENX
	CMA			/COMPLEMENT GENX PATTERN
	DCA Z ACP		/STORE AC PATTERN
	DCA Z LXP		/STORE LINK TO A ZERO
	CMA
	AND Z GENX
	MQL			/LOAD MQ
	CLA CMA
	AND Z ACP		/LOAD AC WITH COMPLEMENTED GENX
	MQA
	DCA Z BACP		/STORE RESULT OF MQA
	CLA SNL
	SKP
	JMS Z SETL
	DCA Z BLXP		/STORE LINK RESULT 7777
	CLA CMA
	AND Z BACP		/AC SHOULD EQUAL 7777
	CMA
	SZA
	JMP MQAER3		/MQ DID NOT INCLUSIVE OR WITH AC
	CMA
	AND Z BLXP
	SZA
	JMP MQAER3		/LINK DID NOT EQUAL A ZERO
	JMP NOPR3+4

HSE5,	CLA CLL
	DCA Z GENX
	TAD Z XMQAT3
	DCA Z BACK
	TAD Z XSCAT
	DCA Z NEXT
	NOP
	NOP
	NOP
	JMP MQAT3+1
MQAER3,	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SNL
	JMP NOPR3		/PRINT ERROR
	JMS I APMQAT
	JMP AMQAT3
NOPR3,	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP MQAT3+2		/PROGRAM LOOP
	JMP MQAT3+1		/CONTINUE PROGRAM
APMQAT,	PMQAT
	NOPR3
	EMQAT2
AMQAT3,	JMS PTHREE
	CLA CMA
	AND APMQAT+1
	DCA I APMQAT+2
	JMP I XAT3
XAT3,	AT3
PTHREE,	0
	CLA CMA
	AND Z THREE
	JMS Z PRXLOP
	JMP I PTHREE
*1600
STEST,	JMS KP1			/HOUSE KEEPING
SHLLSR,	JMS Z GEN		/NUMBER GENERATOR
	STL CLA CMA		/SET LINK (NO SHIFT GUARD)
	AND Z GENX
	MQL			/LOAD MQ
	SHL			/SHIFT LEFT
LEFTS,	0			/NUMBER OF SHIFTS
	DCA Z LFTAC		/STORE AC SHIFTED LEFT
	SNL
	JMP CLLINK		/CLEAR AND STORE LINK LFTAC
	JMP STLINK		/SET AND STORE LINK LFTAC

	MQA CLA
	DCA Z LFTMQ		/STORE MQ SHIFTED LEFT
	CMA
	AND Z LFTAC		/RESTORE AC
	LSR			/SHIFT RIGHT
RIGHTS,	0
	DCA Z RITAC		/STORE AC SHIFTED RIGHT
	SNL
	JMP CLRINK		/CLEAR AND STORE LINK RITAC
	JMP STRINK		/SET AND STORE LINK RITAC
	MQA CLA
	DCA Z RITMQ		/STORE MQ SHIFTED RIGHT
	CMA
	AND LFTINK
	SZA
	JMP SHERR		/LINK EQUALS A ONE IN ERROR
	CMA
	AND RITINK
	SZA
	JMP SHERR		/LINK EQUALS A ONE IN ERROR
	CMA
	AND Z RITAC
	SZA
	JMP SHERR		/RITAC SHOULD EQUAL 0000
	CMA
	AND Z GENX
	CLL CMA
	TAD Z RITMQ
	CMA
	SZA
	JMP SHERR		/RITMQ DID NOT EQUAL GENX
	SZL
	JMP SHERR		/RITMQ DID NOT EQUAL GENX
	JMP SHERR+15
SHERR,	CLA OSR			/TEST SW2
	RTL CLL
	RAL
	SNL
	JMP SHERR+11
	JMS I PRINT
	NOP
	NOP
	NOP
	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP STEST+2		/PROGRAM LOOP
	JMP SHLLSR		/CONTINUE TEST
PRINT,	PRINTS

KP1,	0
	CLA CMA
	AND Z K7764		/MINUS 12
	DCA TWELVE		/STORE 12 COUNT FOR EXIT
	DCA Z GENX		/DEAR GENX
	DCA LEFTS		/CLEAR SHIFT COUNT STORE LEFT
	CMA
	AND SNUM
	DCA Z PRNUM		/STORE SHIFT #
	CMA
	AND RSUB
	DCA Z BACK		/SW3 REPEAT SUB TEST
	CMA
	AND NSUB
	DCA Z NEXT		/SW3 NEXT TEST
	DCA RIGHTS
	CMA
	AND PRTAA
	DCA I PRTAA+1
	JMP I KP1
INCSUB,	ISZ LEFTS		/INCREMENT SHIFT COUNT LEFT
	ISZ RIGHTS		/INCREMENT SHIFT COUNT RIGHT
	ISZ Z PRNUM		/INCREMENT SHIFT # TO PRINT
	ISZ TWELVE		/TWELVE SHIFT TESTS
	JMP SHLLSR		/CONTINUE PROGRAM
	JMP I INCSUB+6		/JUMP TO NEXT SHIFT TEST
	STEST1

CLLINK,	DCA LFTINK		/CLEAR LFTAC LINK
	JMP LEFTS+5
STLINK,	CMA
	DCA LFTINK		/SET LFTAC LINK
	JMP LEFTS+5
CLRINK,	DCA RITINK		/CLEAR RITAC LINK
	JMP RIGHTS+5

STRINK,	CMA			/SET RITAC LINK
	DCA RITINK
	JMP RIGHTS+5

RSUB,	SHLLSR
NSUB,	INCSUB

LFTINK,	0
RITINK,	0
TWELVE,	0
SNUM,	TNUM
PRTAA,	PRTW
	PRT
*2000
PRINTS,	0
	JMS Z CRLF
	JMS I Z12+15
	JMS I SHLX+5
	JMP I Z PRNUM
PRTW,	JMS Z CRLF
	JMS I Z12+12
	JMS I Z12+13
	JMS I Z12+14
	JMS I SHLX+1
	JMS I SHLX+5
	CMA
	AND Z GENX
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMS TENSP
	JMS I Z12+12
	JMS I Z12+13
	JMS I SHLX+2
	JMS I SHLX+1
	JMS TENSP
	JMS I Z12+12
	JMS I Z12+13
	JMS I Z12+14
	JMS I SHLX+1
	JMS Z CRLF
	JMS I SHLX
	JMS Z CRLF
	JMP I PRINTS
SHLX,	SHLP

	RPAR
	AC
	PTHREE
	PTWO
	SP1
TNUM,	JMP Z1
	JMP Z2
	JMP Z3
	JMP Z4
	JMP Z5
	JMP Z6
	JMP Z7
	JMP Z8
	JMP Z9
	JMP Z10
	JMP Z11
	JMP Z12
PRET,	JMS Z PRXLOP
	JMP I PRT
Z1,	CMA
	JMS Z ONZER		/1
	JMP I PRT
Z2,	JMS I SHLX+4		/2
	JMP I PRT
Z3,	JMS I SHLX+3		/3
	JMP I PRT
Z4,	CLA CMA
	AND FOUR		/4
	JMP PRET

Z5,	CLA CMA
	AND FIVE		/5
	JMP PRET

Z6,	CLA CMA
	AND SIX			/6
	JMP PRET
Z7,	CLA CMA
	AND SEVEN		/7
	JMP PRET

Z8,	CLA CMA
	AND EIGHT		/8
	JMP PRET
Z9,	CLA CMA			/9
	AND NINE
	JMP PRET
Z10,	CMA
	JMS Z ONZER		/10
	JMS Z ONZER
	JMP I PRT
Z11,	CMA
	JMS Z ONZER		/11
	CMA
	JMS Z ONZER
	JMP I PRT
Z12,	CMA
	JMS Z ONZER		/12
	JMS I SHLX+4
	JMP I PRT
FOUR,	0264
FIVE,	0265
SIX,	0266
SEVEN,	0267
EIGHT,	0270
NINE,	0271
	PC
	LPAR
	MQ
	SHIFT
TENSP,	0
	CLA CMA
	AND TCOUNT
	DCA SPACST		/STORE MINUS TEN
	JMS I SHLX+5		/PRINT 10 SPACES
	ISZ SPACST
	JMP TENSP+4
	JMP I TENSP
TCOUNT,7765
SPACST,	0
PRT,	0
*2200
PC,	0
	CLA CMA
	AND Z C
	JMS Z PRXLOP
	JMP I PC

LPAR,	0
	CLA CMA
	AND LPAREN
	JMS Z PRXLOP
	JMP I LPAR

RPAR,	0
	CLA CMA
	AND RPAREN
	JMS Z PRXLOP
	JMP I RPAR

LPAREN,	0250
RPAREN,	0251

SHLP,	0
	CLA CMA
	AND SX
	JMS Z PRXLOP
	CMA
	AND HX
	JMS Z PRXLOP
	JMS I LX
	JMS I LX+3
	CLA CMA
	AND I LX+4
	JMS Z ONZER
	JMS I LX+3
	CLA CMA
	AND Z LFTAC
	DCA Z BITSTR
	JMS Z MESSG
	JMS I LX+3
	JMS I LX+3
	JMS I LX+3
	CLA CMA
	AND Z LFTMQ
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMS I LX
	CLA CMA
	AND SX
	JMS Z PRXLOP
	CLA CMA
	AND RX
	JMS Z PRXLOP
	JMS I LX+3
	CLA CMA
	AND I LX+6
	JMS Z ONZER
	JMS I LX+3
	CLA CMA
	AND Z RITAC
	DCA Z BITSTR
	JMS Z MESSG
	JMS I LX+3
	JMS I LX+3
	JMS I LX+3
	CLA CMA
	AND Z RITMQ
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMP I SHLP
LX,	L
HX,	0310
SX,	0323
	SP1
	LFTINK
RX,	0322
	RITINK
*2400
STEST1,	JMS KP1XX		/HOUSE KEEPING
T13,	CLA CMA
	AND T14X
	DCA NTST		/STORE NEXT TEST ADDRESS
	JMS GENN		/GENERATOR JUMP
SCP13,	JMS I TXXX
	JMP SCP13
T14,	JMS I KKKNU
	AND T14X+1
	DCA NTST
	JMS GENN
SCP14,	JMS I TXXX
	JMP SCP14
T15,	JMS I KKKNU
	AND T14X+2
	DCA NTST
	JMS GENN
SCP15,	JMS I TXXX
	JMP SCP15
T16,	JMS I KKKNU
	AND T14X+3
	DCA NTST
	JMS GENN
SCP16,	JMS I TXXX
	JMP SCP16
T17,	JMS I KKKNU
	AND T14X+4
	DCA NTST
	JMS GENN
SCP17,	JMS I TXXX
	JMP SCP17
T18,	JMS I KKKNU
	AND T14X+5
	DCA NTST
	JMS GENN
SCP18,	JMS I TXXX
	JMP SCP18
T19,	JMS I KKKNU
	AND T14X+6
	DCA NTST
	JMS GENN
SCP19,	JMS I TXXX
	JMP SCP19
T20,	JMS I KKKNU
	AND T14X+7
	DCA NTST
	JMS GENN
SCP20,	JMS I TXXX
	JMP SCP20
T21,	JMS I KKKNU
	AND T14X+10
	DCA NTST
	JMS GENN
SCP21,	JMS I TXXX
	JMP SCP21
T22,	JMS I KKKNU
	AND T14X+11
	DCA NTST
	JMS GENN
SCP22,	JMS I TXXX
	JMP SCP22
T23,	JMS I KKKNU
	AND T14X+12
	DCA NTST
	JMS GENN
SCP23,	JMS I TXXX
	JMP SCP23
GENN,	0
CONTIN,	ISZ NGEN		/CONTINUE CURRENT TEST
	CLA CMA
NCOMP,	AND KKK
	CMA
	TAD NGEN
	CMA
	SNA
	SKP
	JMP I GENN
	DCA NGEN
	CLA OSR			/TST SW3
	RTL CLL
	RTL
	SZL
	JMP I GENN
	ISZ I KX12+3		/INCREMENT SHIFT COUNTER LEFT
	ISZ I KX12+2		/INCREMENT SHIFT COUNTER RIGHT
	ISZ Z PRNUM		/INCREMENT SHIFT NUMBER TO PRINT
	JMP I NTST
KP1XX,	0
	CLA CMA
	AND K4000
	DCA KKK
	DCA NGEN

	TAD KX12
	DCA I KX12+3
	TAD KX12
	DCA I KX12+2
	TAD PPPNUM
	DCA Z PRNUM		/PRINT NUMBERS 13 TO 23
	TAD PRTTA
	DCA I PRZTA
	JMP I KP1XX
PPPNUM,	PPNUM

KKK,	0
NGEN,	0
ELEVEN,	0
NTST,	0
T14X,	T14
	T15
	T16
	T17
	T18
	T19
	T20
	T21
	T22
	T23
	STEST2
K4000,	4000
KX12,	0014
KKKNU,	KKKN
	RITXXX
	LFTXXX
TXXX,	TXXXX
PRTTA,	PRTW
PRZTA,	PRTT
*2600
KKKN,	0
	CLL CLA CMA		/COMPARE CONSTANTS FOR TESTS
	AND I KKKN+7
	RAR
	DCA I KKKN+7
	CMA
	JMP I KKKN
	KKK

TXXXX,	0			/SCOPE MODE RETURN INDIRECT
	CLA CMA
	AND I NGENX
	MQL			/LOAD MQ
	CMA
	AND K2525		/LOAD AC 2525 (OCTAL)
	SHL			/SHIFT LEFT
LFTXXX,	0
	DCA Z LFTAC		/STORE AC SHIFTED LEFT
	SNL
	JMP CLLI		/CLEAR  AND STORE LEFT LINK
	JMP CLLI+2		/SET AND STORE LEFT LINK
	MQA CLA
	DCA Z LFTMQ		/STORE MQ SHIFTED LEFT
	CMA
	AND Z LFTAC		/RESTORE AC
	LSR			/SHIFT RIGHT
RITXXX,	0
	DCA Z RITAC		/STORE AC SHIFTED RIGHT
	SNL
	JMP CRLI		/CLEAR AND STORE RIGHT LINK
	JMP CRLI+2
	MQA CLA
	DCA Z RITMQ		/STORE MQ SHIFTED RIGHT
	CMA
	AND I LLIN
	SZA
	JMP SHERRX	/LINK EQUALS A ONE IN ERROR
	CMA
	AND I RLIN
	SZA
	JMP SHERRX	/LINK EQUALS A ONE IN ERROR
	CMA
	AND Z RITAC
	SZA
	JMP SHERRX	/RITAC SHOULD EQUAL 0000
	CMA
	AND I NGENX
	CLL CMA
	TAD Z RITMQ
	CMA
	SZA
	JMP SHERRX	/RITMQ DID NOT EQUAL NGEN
	SZL
	JMP SHERRX	/RITMQ DID NOT QUEAL NGEN
	JMP SHERRX+15
CLLI,	DCA I LLIN	/CLEAR LEFT LINK STORE
	JMP LFTXXX+5
	CMA
	DCA I LLIN	/SET LEFT LINK STORE
	JMP LFTXXX+5
CRLI,	DCA I RLIN	/CLEAR RIGHT LINK STORE
	JMP RITXXX+5
	CMA			/SET RIGHT LINK STORE
	DCA I RLIN
	JMP RITXXX+5
NGENX,	NGEN
K2525,	2525
LLIN,	LFTINK
RLIN,	RITINK
NNEG,	GENN
	PRINTS
TINUE,	CONTIN

SHERRX,	CLA OSR			/TEST SE2
	RTL CLL
	RAL
	SNL
	JMP SHERRX+11
	CLA CMA
	AND I NGENX
	DCA Z GENX
	JMS I TINUE-1
	CLA OSR			/TEST SW0
	RAL CLL
	SZL
	HLT
	CLA OSR			/TEST SW1
	RTL CLL
	SZL
	JMP I TXXXX		/SCOPE MODE
	JMP I TINUE		/CONTINUE MODE

/DPI PAUSE

/EAE PART 3A OF INSTRUCTION TEST  -  TAPE 2
*3000
PPNUM,	JMP Z13
	JMP Z14
	JMP Z15
	JMP Z16
	JMP Z17
	JMP Z18
	JMP Z19
	JMP Z20
	JMP Z21
	JMP Z22
	JMP Z23

Z13,	JMS ONEONE	/1
	JMP I PRT3	/3
Z14,	JMS ONEONE	/1
	JMP I PRT3+1	/4
Z15,	JMS ONEONE	/1
	JMP I PRT3+2	/5
Z16,	JMS ONEONE	/1
	JMP I PRT3+3	/6
Z17,	JMS ONEONE	/1
	JMP I PRT3+4	/7
Z18,	JMS ONEONE	/1
	JMP I PRT3+5	/8
Z19,	JMS ONEONE	/1
	JMP I PRT3+6	/9
Z20,	JMS I TWOTWO	/2
	CMA
	JMS ONEONE	/0
	JMP I PRTT
Z21,	JMS I TWOTWO	/2
	JMS ONEONE	/1
	JMP I PRTT
Z22,	JMS I TWOTWO	/2
	JMS I TWOTWO	/2
	JMP I PRTT
Z23,	JMS I TWOTWO	/2
	JMP I PRT3	/3

ONEONE,	0		/PRINT ONE
	CMA
	JMS Z ONZER
	JMP I ONEONE
PRT3,	Z3
	Z4
	Z5
	Z6
	Z7
	Z8
	Z9
PRTT,	0
TWOTWO,	PTWO

SHIFT,	0
	CMA
	AND SS		/S
	JMS Z PRXLOP
	CMA
	AND SS+1	/H
	JMS Z PRXLOP
	CMA
	AND SS+2	/I
	JMS Z PRXLOP
	CMA
	AND SS+3	/F
	JMS Z PRXLOP
	CMA
	AND Z TT	/T
	JMS Z PRXLOP
	JMP I SHIFT

SS,	0323
	0310
	0311
	0306
*3200
STEST2,	JMS HSKK
	JMS GENRR
	CLA CLL		/CLEAR LINK
	MQL		/CLEAR AC AND MQ
	CMA
	AND Z XK400	/SET BIT 0
	ASR
ASRSHF,	0		/SHIFT # OF PLACES
	DCA Z LFTAC	/STORE AC
	MQA
	DCA Z LFTMQ	/STORE MQ
	SNL
	JMP SSINK+1	/CLEAR AND STORE LINK
	JMP SSINK	/SET AND STORE LINK
	CLA CMA
	AND Z LFTAC	/AC CONTENTS
	CLL CMA
	TAD ACCOMP	/AC COMPARE CONSTANTS
	CMA
	SZA
	JMP ASRERR	/ASR ERROR (AC IN ERROR)
	SZL
	JMP ASRERR	/ASR ERROR (AC IN ERROR)
	CMA
	AND Z LFTMQ	/MQ CONTENTS
	CMA CLL
	TAD MQCOMP	/MQ COMPARE CONSTANTS
	CMA
	SZA
	JMP ASRERR	/ASR ERROR (MQ IN ERROR)
	SZL
	JMP ASRERR	/ASR ERROR (MQ IN ERROR)
	CLA CMA
	AND I LLLLNK	/AC LINK
	SNA
	JMP ASRERR	/LINK ERROR (DID NOT EQUAL A ONE)
	JMP TSSW0+4

GENRR,	0
	CLA CMA
	AND I Z ACIND	/AC AUTO INDEX PATTERN COMPARE
	DCA ACCOMP
	CMA
	AND I Z MQIND	/MQ AUTO INDEX PATTERN COMPARE
	DCA MQCOMP
	ISZ ASRSHF	/INCREMENT SHIFT #
	ISZ Z PRNUM	/INCREMENT ASR PRINT #
	ISZ ASREX	/INCREMENT TEST COUNT
	JMP I GENRR
	ISZ REEE
	JMP STEST2
	CLA OSR		/TEST SW3
	RTL CLL
	RTL
	SZL
	JMP STEST2	/REPEAT TEST
	JMP I SSTEST	/EXIT TO NEXT PROGRAM
SSINK,	CMA
	DCA I LLLLNK	/STORE LINK
	JMP ASRSHF+7

ACCOMP,	0
MQCOMP,	0
ASREX,	0
ASREXX,	7750
LLLLNK,	LFTINK
SSTEST,	STEST3
MQAUT,	MQAUTX
ACAUT,	ACAUTX
STPR,	ASRPNU+1
	TYPE
	PRT
	PRTT
	TYPRE
	TYPE2
	TYPEA

HSKK,	0
	CLA CMA
	AND ASREXX+11
	DCA I ASREXX+7
	CMA
	AND ASREXX+11
	DCA I ASREXX+10
	CMA
	AND ACAUT
	DCA Z ACIND
	CMA
	AND MQAUT
	DCA Z MQIND
	CMA
	DCA ASRSHF
	CMA
	AND STPR
	DCA Z PRNUM
	CMA
	AND ASREXX
	DCA ASREX
	NOP
	NOP
	JMP I HSKK
ASRERR,	CLA OSR
	RTL CLL		/TEST SW2
	RAL
	SNL
	JMP TSSW0
	JMS I ASREXX+6	/PRINT ERROR
	JMS I ASREXX+12
	JMS I ASREXX+13
TSSW0,	CLA OSR
	RAL CLL		/TEST SW0
	SZL
	HLT
	CLA OSR		/TEST SW1
	RTL CLL
	SZL
	JMP STEST2+2	/SCOPE MODE
	JMP STEST2+1	/CONTINUE MODE
REEE,	0
*3400
TYPE,	0
	JMS Z CRLF
	JMS I ASHIFT
	JMS I ASHIFT+1
	JMP I Z PRNUM
TYPRE,	JMS Z CRLF
	JMS I ASHIFT+2
	JMS I TYLPAR
	JMS I ASHIFT+4
	JMS I TYRPAR
	JMS I ASHIFT+1
	JMP I TYPE

TYPEA,	0
	JMS Z CRLF
	JMS I ASHIFT+6
	JMS I ASHIFT+2
	JMS I TYLPAR
	JMS I ASHIFT+4
	JMS I TYRPAR
	JMS I ASHIFT+6
	JMS I ASHIFT+2
	JMS I TYLPAR
	JMS I ASHIFT+7
	JMS I TYRPAR
	JMS Z CRLF
	CLA CMA
	AND Z A
	JMS Z PRXLOP
	CLA CMA
	AND TYS
	JMS Z PRXLOP
	CLA CMA
	AND TYR
	JMS Z PRXLOP
	JMS I ASHIFT+1
	JMS I ASHIFT+1
	JMS I ASHIFT+1
	CLA CMA
	AND I TYLI
	JMS Z ONZER
	JMS I ASHIFT+1
	CLA CMA
	AND Z LFTAC
	DCA Z BITSTR
	JMS Z MESSG
	JMS I ASHIFT+1
	JMS I ASHIFT+1
	JMS I ASHIFT+1
	CLA CMA
	AND Z LFTMQ
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMP I TYPEA
ASHIFT,	SHIFT
	SP1
	PC
TYLPAR,	LPAR
	AC
TYRPAR,	RPAR
	TENSP
	MQ
TYS,	0323
TYR,	0322
TYLI,	LFTINK
KA3777,	3777

MQAUTX,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
ACAUTX,	4000
	6000
	7000
	7400
	7600
	7700
	7740
	7760
	7770
	7774
	7776
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777

TYPE2,	0
	CLA
	JMS Z ONZER
	JMS I ASHIFT+1
	CLA CMA
	AND ACAUTX
	DCA Z BITSTR
	JMS Z MESSG
	JMP I TYPE2

TYPE3,	0
	CLA CMA
	JMS Z ONZER
	JMS I ASHIFT+1
	CLA CMA
	AND KA3777
	DCA Z BITSTR
	JMS Z MESSG
	JMP I TYPE3
*3600
ASRPNU,	0
	JMP I TY1
	JMP I TY1+1
	JMP I TY1+2
	JMP I TY1+3
	JMP I TY1+4
	JMP I TY1+5
	JMP I TY1+6
	JMP I TY1+7
	JMP I TY1+10
	JMP I TY1+11
	JMP I TY1+12
	JMP I TY1+13
	JMP I TY1+14
	JMP I TY1+15
	JMP I TY1+16
	JMP I TY1+17
	JMP I TY1+20
	JMP I TY1+21
	JMP I TY1+22
	JMP I TY1+23
	JMP I TY1+24
	JMP I TY1+25
	JMP I TY1+26
TY1,	Z1
	Z2
	Z3
	Z4
	Z5
	Z6
	Z7
	Z8
	Z9
	Z10
	Z11
	Z12
	Z13
	Z14
	Z15
	Z16
	Z17
	Z18
	Z19
	Z20
	Z21
	Z22
	Z23
MQCLC,	0
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
	7777
ACCLC,	3777
	1777
	0777
	0377
	0177
	0077
	0037
	0017
	0007
	0003
	0001
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000
	0000

*4000
STEST3,	JMS HKEEP
	JMS GNNN
	CLA CMA STL	/SET LINK
	MQL
	CMA
	AND TEST4+5	/AC TEST PATTERM
	ASR
ASR3,	0
	DCA Z LFTAC	/STORE AC
	MQA
	DCA Z LFTMQ	/STORE MQ
	SNL
	JMP SXLINK+1	/CLEAR AND STORE LINK
	JMP SXLINK	/SET AND STORE LINK
CXSX,	CLA CMA
	AND Z LFTAC	/AC CONTENTS
	CLL CMA
	TAD ACCHK	/AC COMPARE CONSTANTS
	CMA
	SZA
	JMP AASREX	/ASR ERROR (AC IN ERROR)
	SZL
	JMP AASREX	/ASR ERROR (AC IN ERROR)
	CMA
	AND Z LFTMQ	/MQ CONTENTS
	CLL CMA
	TAD MQCHK	/MQ COMPARE CONSTANTS
	CMA
	SZA
	JMP AASREX	/ASR ERROR (MQ IN ERROR)
	SZL
	JMP AASREX	/ASR ERROR (MQ IN ERROR)
	CLA CMA
	AND I LIINK	/AC LINK
	SZA
	JMP AASREX	/LINK ERROR (DID NOT EQUAL ZERO)
	JMP AS3PR-5

SXLINK,	CMA
	DCA I LIINK
	JMP CXSX
AASREX,	CLA OSR		/TEST SW2
	RTL CLL
	RAL
	SZL
	JMS AS3PR	/PRINT ERROR
	CLA OSR		/TEST SW0
	RAL CLL
	SZL
	HLT		/ERROR HALT STEST3
	CLA OSR		/TEST SW1
	RTL CLL
	SZL
	JMP STEST3+2	/SCOPE MODE
	JMP STEST3+1	/CONTINUE MODE

AS3PR,	0
	JMS I .+12
	JMS I .+10
	JMS I .+6
	JMP I .-4

ACCHK,	0
MQCHK,	0
ASREXT,	0
TEST4,	NORMT		/NORMALIZE TEST
	TYPEA
	TYPE3
	TYPE
LIINK,	LFTINK
	3777
	TYPRE
	PRT
	PRTT
	ACCLC

	7750
	ASRPNU+1
	MQCLC
GNNN,	0
	CLA CMA
	AND I Z ACIND	/AC AUTO INDEX PATTERN COMPARE
	DCA ACCHK
	CMA
	AND I Z MQIND	/MQ AUTO INDEX PATTERN COMPARE
	DCA MQCHK
	ISZ ASR3	/INCREMENT SHIFT #
	ISZ Z PRNUM	/INCREMENT ASR PRINT #
	ISZ ASREXT	/INCREMENT TEST COUNT
	JMP I GNNN
	ISZ REEEE
	JMP STEST3
	CLA OSR		/TEST SW3
	RTL CLL
	RTL
	SZL
	JMP STEST3	/REPEAT TEST
	JMP I TEST4
HKEEP,	0
	CLA CMA
	AND TEST4+6
	DCA I TEST4+7
	CMA
	AND TEST4+6
	DCA I TEST4+10
	CMA
	AND TEST4+11
	DCA Z ACIND
	CMA
	AND TEST4+14
	DCA Z MQIND
	CMA
	DCA ASR3
	CMA
	AND TEST4+13
	DCA Z PRNUM
	CMA
	AND TEST4+12
	DCA ASREXT
	JMP I HKEEP
REEEE,	0
*4200
NORMT,	JMP HSENMI
	JMS GXEN
	CLA CMA
	AND MQNMIX
	
	MQL		/LOAD MQ INDEXED PATTERN
	CMA
	AND ACNMIX	/LOAD AC INDEX PATTERN
	NMI
	DCA ACNMIN	/STORE AC
	MQA
	DCA MQNMIN	/STORE MQ
	SCA
	DCA SCAST	/STORE SCA COUNT
	CMA
	AND ACNMIN
	CLL CMA
	TAD NMIODD	/6000
	CMA
	SZA
	JMP NMIERR	/AC DID NOT EQUAL 6000
	SZL
	JMP NMIERR	/AC DID NOT EQUAL 6000
	CLA CMA
	AND MQNMIN
	SZA
	JMP NMIERR	/MQ DID NOT EQUAL 0000
	CMA
	AND SCAST
	CLL CMA
	TAD SCASTX	/INDEXED STEP COUNT #
	CMA
	SZA
	JMP NMIERR	/SC IN ERROR
	SZL
	JMP NMIERR	/SC IN ERROR
	CLA CMA
	AND SCASTX	/TEST SCA COUNT FOR 0
	SZA		/TO EXIT
	JMP NMIERR+12	/CONTINUE TEST
	JMP EXINMI
NMIERR,	CLA OSR		/TEST SW2
	RTL CLL
	RAL
	SNL
	SKP
	JMS I SCAST+11	/JUMP TO PRINT ROUTINE
	CLA OSR
	RAL CLL
	SZL		/TEST SW0
	HLT
	CLA OSR
	RTL CLL
	SZL		/TEST SW1
	JMP NORMT+2
	JMP NORMT+1
HSENMI,	CLA CMA
	AND ACNMIQ
	DCA XACNMI	/AC AUTO START ADDRESS
	CMA
	AND MQNMIQ
	DCA XMQNMI	/MQ AUTO START ADDRESS
	CMA
	AND SCC23	/SC 23
	DCA SCASTX	/STORE DECIMAL 23
	JMP NORMT+1
EXINMI,	CLA OSR		/TEST SW3
	RTL CLL
	RTL
	SZL
	JMP NORMT	/REPEAT ENTIRE TEST
	JMP I SCAST+10	/JMP TO NEXT NMI TEST
SCAST,	0
NMIODD,	6000
SCC23,	0027		/23 DECIMAL
SCASTX,	0
ACNMIX,	0
MQNMIX,	0
MQNMIN,	0
ACNMIN,	0
	NORMT1
	PRNMI
GXEN,	0
	CLA CMA
	AND I Z XACNMI
	DCA ACNMIX	/STORE AC PATTERN
	CMA
	AND I Z XMQNMI
	DCA MQNMIX	/STORE MQ PATTERN
	CMA
	AND SCASTX	/SUBTRACT ONE FROM SCA COUNT
	CIA
	CMA
	DCA SCASTX	/STORE DECREMENTED SCA COUNT
	JMP EXEN
ACNMIQ,	ACNMI
MQNMIQ,	MQNMI
EXEN,	CLA CMA
	AND SCASTX
	SZA
	JMP I GXEN
	JMP EXINMI
*4400
PRNMI,	0		/PRINT ROUTINE
	JMS Z CRLF
	JMS I SPR2+16
	JMS I SPR2
	JMS I SPR2
	JMS I SPR2
	JMS I SPR2+1
	JMS I SPR2+2
	JMS I SPR2+3
	JMS I SPR2+4
	JMS I SPR2+5
	JMS I SPR2+1
	JMS I SPR2+2
	JMS I SPR2+6
	JMS I SPR2+4
	JMS Z CRLF
	JMS I SPR2
	JMS I SPR2
	JMS I SPR2
	CLA CMA
	AND I SPR2+7
	DCA Z BITSTR
	JMS Z MESSG
	JMS I SPR2
	JMS I SPR2+10
	CLA CMA
	AND I SPR2+11
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMS I SPR2+17
	JMS I SPR2
	JMS I SPR2+10
	CLA CMA
	AND I SPR2+12
	DCA Z BITSTR
	JMS Z MESSG
	JMS I SPR2
	JMS I SPR2+10
	CLA CMA
	AND I SPR2+13
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMS I SPR2+20
	JMS I SPR2
	CLA CMA
	AND I SPR2+14
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMS I SPR2+21
	JMS I SPR2
	JMS I SPR2+10
	CLA CMA
	AND I SPR2+15
	DCA Z BITSTR
	JMS Z MESSG
	JMS Z CRLF
	JMP I PRNMI
SPR2,	SP2
	PC
	LPAR
	AC
	RPAR
	TENSP
	MQ
	ACNMIX
	SP1
	MQNMIX
	ACNMIN
	MQNMIN
	SCASTX
	SCAST
	NMITPR
	NMIXX
	SCATXX
	SCAXX
	0

ACNMI,	0
	7777		/SC22
	7777		/SC21
	7777		/SC 20
	7777		/SC 19
	7777		/SC 18
	7777		/SC 17
	7777		/SC 16
	7777		/SC 15
	7777		/SC 14
	7777		/SC 13
	7777		/SC 12
MQNMI,	7777		/SC 11
	7777		/SC 10
	7776		/SC 9
	7774		/SC 8
	7770		/SC 7
	7760		/SC 6
	7740		/SC 5
	7700		/SC 4
	7600		/SC 3
	7400		/SC 2
	7000		/SC 1
	6000		/SC 0
	4000
	0000
	0000
	0000
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
*4600
NMITPR,	0
	JMS PNORM
	JMS XNORMT
	JMP I NMITPR
PNORM,	0
	CLA CMA
	AND N
	JMS Z PRXLOP
	CLA CMA
	AND N+1
	JMS Z PRXLOP
	CLA CMA
	AND N+2
	JMS Z PRXLOP
	JMP I PNORM
XNORMT,	0

	CLA CMA
	AND N+3
	JMS Z PRXLOP
	JMP I XNORMT
NMIXX,	0
	JMS PNORM
	JMP I NMIXX
SCATXX,	0
	JMS PSTEP
	JMS PSTEPT
	JMP I SCATXX
SCAXX,	0
	JMS PSTEP
	JMP I SCAXX
PSTEP,	0
	CLA CMA
	AND N+4
	JMS Z PRXLOP
	CLA CMA
	AND N+5
	JMS Z PRXLOP
	CLA CMA
	AND N+6
	JMS Z PRXLOP
	JMP I PSTEP
PSTEPT,	0
	CLA CMA
	AND N+3
	JMS Z PRXLOP
	JMP I PSTEPT
N,	0316		/N
	0315		/M
	0311		/I
	0324		/T
	0323		/S
	0303		/C
	0301		/A
*5000
NORMT1,	JMP HSENM
	JMS GENNMI
	CLA CMA
	AND I TST25+1	/LOAD MQ PATTERN
	MQL
	CLA CMA
	AND I TST25+2	/LOAD AC PATTERN
	NMI
	DCA I TST25+10	/STORE NORMALIZED AC
	MQA
	DCA I TST25+11	/STORE NORMALIZED MQ
	SCA
	DCA I TST25+12	/STORE THE SCA COUNT
	CLA CMA
	AND I TST25+10
	CLL CMA
	TAD I TST25+1
	CMA
	SZA
	JMP NMERR	/AC DID NOT EQUAL 2525
	SZL
	JMP NMERR	/AC DID NOT EQUAL 2525
	CLA CMA
	AND I TST25+11
	SZA
	JMP NMERR	/MQ DID NOT EQUAL 0000
	CLA CMA
	AND I TST25+12
	CLL CMA
	TAD DEC12	/DECIMAL 12
	CMA
	SZA
	JMP NMERR	/SC DID NOT EQUAL 12
	SZL
	JMP NMERR	/SC DID NOT EQUAL 12
	ISZ TST25	/REPEAT CURRENT TEST PATTERN
	JMP NORMT1+2
	CLA OSR		/TEST SW1
	RTL CLL
	SZL
	JMP NORMT1+2
	ISZ NMFLG
	
	JMP NORMT1+1
	CLA OSR		/TEST SW3
	RTL CLL
	RTL
	SZL
	JMP NORMT1
	JMP I NEXNMI
HSENM,	CLA
	DCA TST25	/CLEAR TEST COUNTER
	NOP
	CMA
	AND NM7776
	DCA NMFLG
	TAD DEC12
	DCA I TST25+13
	JMP NORMT1+1
GENNMI,	0
	CLA CMA
	AND NMFLG
	CMA
	SZA
	JMP PA2525	/GENERATE 2525
	JMP PA2525+5	/GENERATE 5252
PA2525,	CLA CMA
	AND NM2525	/MQ PATTERN 2525
	DCA I TST25+1
	DCA I TST25+2	/AC PATTERN 0000
	JMP I GENNMI
	CLA CMA
	AND NM5252	/MQ PATTERN 5252
	DCA I TST25+1
	CMA
	DCA I TST25+2	/AC PATTERN 7777
	JMP I GENNMI
TST25,	0
	MQNMIX
	ACNMIX
NM2525,	2525
NM5252,	5252
NMFLG,	0
NM7776,	7776
NEXNMI,	NORMT2
	ACNMIN
	MQNMIN
	SCAST
	SCASTX
DEC12,	0014
	PRNMI
NMERR,	CLA OSR		/TEST SW2
	RTL CLL
	RAL
	SNL
	SKP
	JMS I DEC12+1
	CLA OSR
	RAL CLL
	SZL		/TEST SW0
	HLT
	CLA OSR		/TEST SW1
	RTL CLL
	SNL
	JMP NORMT1+2	/CONTINUE
	CLA
	DCA TST25	/CLEAR CURRENT TEST COUNTER
	JMP NORMT1+2	/SCOPE
*5200

NORMT2,	JMP HKE		/HOUSE KEEPING
	JMS GEX		/PATTERN GENERATOR
	CAM
	CMA
	AND I PAT01
	MQL		/MQ PATTERN
	CLL CMA
	AND I PAT00	/AC PATTERN
	NMI
	DCA I SPAT00	/STORE AC NORMALIZED PATTERN
	MQA
	DCA I SPAT01	/STORE MQ NORMALIZED PATTERN
	SCA
	DCA I SCANM	/STORE SCA COUNT
	CMA
	AND I SPAT00	/AC PATTERN
	CMA
	TAD CHKAC	/CHECK PATTERN AC
	CMA
	SZA		/TEST AC BITS
	JMP MT2ER	/SPAT00 NOT EQUAL TO CHKAC
	SZL
	JMP MT2ER	/SPAT00 NOT EQUAL TO CHKAC
	CMA
	AND I SPAT01	/MQ PATTERN
	CMA
	TAD CHKMQ	/CHECK PATTERN MQ
	CMA
	SZA		/TEST MQ BITS
	JMP MT2ER	/SPAT01 NOT EQUAL TO CHKMQ
	SZL
	JMP MT2ER	/SPAT01 NOT EQUAL TO CHKMQ
	CMA
	AND I SCANM	/SCA COUNT PATTERN
	CIA
	TAD I CHKSCA	/CHECK PATTERN SCA
	SNL
	JMP MT2ER	/SCANM NOT EQUAL TO CHKSCA
	ISZ AGAIN	/4096 REPEATS CURRENT TEST
	JMP NORMT2+2
NMTS1,	CLA OSR		/TEST SW1
	RTL CLL
	SZL	
	JMP NORMT2+2
	JMP PATCH	/JUMP TO SW3
GEX,	0
	CLA CMA
	AND TPFLAG
	CMA
	SZA
	JMP .+2		/GENERATE 0000 MQ PATTERN
	JMP .+10	/GENERATE 0001 MQ PATTERN
	CLA
	DCA I PAT00	/STORE AC PATTERN
	DCA I PAT01	/STORE MQ PATTERN
	DCA CHKAC	/STORE AC CHECK
	DCA CHKMQ	/STORE MQ CHECK
	DCA I CHKSCA	/STORE SCA CHECK
	JMP I GEX
	CLA CMA
	AND SCANM+1	/MQ PATTERN (0001)
	DCA I PAT01	/STORE MQ PATTERN
	CMA
	AND TPFLAG+1	/22 DECIMAL PLACES (0030)
	DCA I CHKSCA
	DCA I PAT00	/STORE AC PATTERN
	DCA CHKMQ	/STORE MQ CHECK
	CMA
	AND TPFLAG+2	/20000
	DCA CHKAC	/STORE AC CHECK
	JMP I GEX

HKE,	CLA CMA		/HOUSE KEEPING
	AND TPFLAG+3	/7776
	DCA TPFLAG	/LOAD FLAG
	DCA AGAIN	/CHECK TEST COUNTER
	JMP NORMT2+1
MT2ER,	CLA OSR		/TEST SW2
	RTL CLL
	RAL
	SZL
	JMS I TPFLAG+4	/PRINT ROUTINE
	CLA OSR		/TEST SE0
	RAL CLL
	SZL
	HLT
	JMP NMTS1
NMTS3,	CLA OSR		/TEST SE3
	RTL CLL
	RTL
	SZL
	JMP NORMT2	/CONTINUE
	JMP I TPFLAG+5
PAT01,	MQNMIX
PAT00,	ACNMIX
SPAT00,	ACNMIN
SPAT01,	MQNMIN
CHKAC,	0
CHKMQ,	0
CHKSCA,	SCASTX
SCANM,	SCAST
	0001
AGAIN,	0
TPFLAG,	0
	0026
	2000
	7776
	PRNMI
	E3A
PATCH,	ISZ TPFLAG
	JMP NORMT2+1
	JMP NMTS3

*5400

E3A,	JMS Z CRLF
	CLA CMA
	AND Z THREE	/3
	JMS Z PRXLOP
	CMA
	AND Z A		/A
	JMS Z PRXLOP
	JMP I .+1

BIGL,	MQLT
$