/PROGRAM BIO A-08-01
/ADDITION OF NEW SUBROUTINES TO 4 WORD F.P. PACKAGE
/FREAD,FSPA,FSZA,FNOP,FJMP,FNEG,FHLT
/FCLA MAY BE SIMULATED BY SETTING FCLA=2044
/
*5760
         FPREAD                   /FREAD=10
         FPSPA                    /FSPA=11
         FPSZA                    /FSZA=12
         EXIT6                    /FNOP=13
         EXIT6
         FPJMP                    /FJMP=15
         6261                     /FNEG=16
         FPHLT                    /FHLT=17
EXIT6=5770
/
/
*5324
FPREAD,  0                        /SUBROUTINE TO READ FIRST
         JMS I 5                  /VALID F.P. NUMBER
         CLA CLL
         TAD 61
         SNA CLA
         JMP .-4
         JMP I FPREAD
/
/
FPSPA,   0                        /SUBROUTINE TO SIMULATE SPA N.
         TAD 45                   /I.E. JUMP N INSTRUCTIONS
         SMA CLA                  /IF F.P. ACC. POSITIVE.
         JMS FPJMP                /N DEFINED IN F.P. JUMP
         JMP I FPSPA
/
/
FPSZA,   0                        /SUBROUTINE TO SIMULATE SZA N.
         TAD 45                   /I.E. JUMP N INSTRUCTIONS
         SNA CLA                  /IF F.P. ACC.=0.
         JMS FPJMP                /N DEFINED IN F.P. JUMP
         JMP I FPSZA
/
/
FPJMP,   0                        /SUBROUTINE TO SIMULATE JMP N
         TAD I INST               /WHERE N=M*20(OCTAL) AND
         AND MASK1                /M IS THE NUMBER OF INSTR.
         SNA CLA                  /TO BE JUMPED. IF BIT 3=0
         CMA                      /JUMP FORWARDS, IF BIT 3=1
         DCA 15                   /JUMP BACKWARDS.
         TAD I INST               /CONTENTS OF LOC. 15 LOST
         CLL RTR
         RTR
         AND MASK
         ISZ 15
         CIA
         TAD I RETADD
         TAD MONE
         DCA I RETADD
         JMP I FPJMP
RETADD,  5661
MASK,    17
MASK1,   400
MONE,    -1
INST,    5657
/
/
FPHLT,   0                        /SUBROUTINE TO SIMULATE A HALT
         CMA                      /WITH ADDR. OF HALT DISPLAYED
         TAD I RETADD             /IN ACC.
         HLT
         CLA CLL
         JMP I FPHLT
$