W ALL
C-8K FOCAL @1969

02.10 T !,!,!,!,!,!
02.30 A "SAMPLE NUMBER",QUIT
02.50 A "DATE         ",QUIT
02.70 A "ANALYST      ",QUIT
02.90 A "PRODUCT      ",QUIT
02.91 A "IS THE PRODUCT DECLARED IN MG OR GR?",UNITS
02.92 IF (UNITS-0MG)2.94,2.93,2.96
02.93 A "HOW MANY MG/TAB DECLARED?",DE;GOTO 3.01
02.94 IF (UNITS-0GR)2.96,2.95,2.96
02.95 A "HOW MANY GR/TAB DECLARED?",DE;GOTO 3.01
02.96 T !,"ERROR, MG OR GR ONLY CORRECT RESPONSE.",!;GOTO 2.91

03.01 A "DILUTION FACTOR?          ",DI
03.04 A "NUMBER OF SAMPLE DETERMINATIONS?",NU; S N1=NU
03.05 S AVG=0
03.10 A "WILL STD. CONCN AND ABS. VALUE BE CONSTANT? TYPE YES OR NO",YES
03.30 T "THE FORMULA USED FOR CALCULATIONS IS AS FOLLOWS:",!,!
03.31 IF (UNITS-0MG)3.32,3.36,3.36
03.32 T "(SA ABS/ST ABS) X (CONC/64.8) X DI FACTOR = GR/TAB"
03.33 T " (CONC IS IN MG/ML)"; GOTO 3.40
03.36 T "(SA ABS/ST ABS) X CONC X DI FACTOR = MG/TAB  (CONC"
03.37 T " IS IN MG/ML)",!; GOTO 3.40
03.40 T !,!
03.41 IF (YES-0YES)3.50,3.60,3.44
03.44 T "ERROR";GOTO 3.10
03.50 T "SPL ABS.    STD ABS.    CONC STD.       FOUND",
03.51 T "         % OF DECLARED",!
03.52 A !,SA,"         ",
03.53 A ST,"      ",
03.54 A CO,"         ";GOTO 3.80
03.60 A "STD CONC IN MG/ML",CO
03.61 A "            STD ABS",ST
03.62 T !,"SPL ABS          FOUND          % OF DECLATED",!
03.63 A !,SA,"          ",
03.64 GOT 3.80
03.80 IF (UNITS-0MG)3.81,3.83,3.93
03.81 S ANS=(SA/ST)*(CO/64.8)*DI;T %8.03,ANS,"   ",%8.03,(ANS/DE)*100
03.82 GOTO 3.91
03.83 S ANS=(SA/ST)*CO*DI;T %8.03,ANS,"     ";T %8.03,(ANS/DE)*100
03.84 GOTO 3.91
03.91 S AVG=AVG+ANS;S NU=NU-1
03.92 IF (NU) 3.93,3.95,3.94
03.93 T !,!,"ERROR";GOTO 2.10
03.94 IF (YES-0YES)3.52,3.63,3.10
03.95 T !,!,"AVG FOUND/TAB", %8.03,(AVG/N1),
03.96 T "    AVG % OF DECLATED", %8.03,(AVG/N1)*(100/DE),!,!,!,!,!,
03.99 T "TO RESTART, TYPE GOTO 2.10",!;QUIT
*