FIELD 0; *0
/Pre-canned Restart vectors
00000 /LA
00000 /LEA GO
00200 /LA
00000 /LEA GO
02000 /LA
00000 /LEA GO
04200 /LA
00000 /LEA GO

/Bootstrap 1: High or low speed paper tape
07737 /LA
00000 /LEA
RELOC 07737
/Start the high speed reader
START1,	RFC		/06014 /DEP
	DCA PTR		/03376 /DEP
/Spin to let reader possibly come ready
LOOP,	CLA CLL CML RTL	/07326 /DEP
	TAD START1	/01337 /DEP
	ISZ PTR		/02376 /DEP
	JMP LOOP	/05341 /DEP
/If it came ready, patch for LSR
KRSF,	RSF		/06011 /DEP
	JMP UKCC	/05356 /DEP
	DCA UKRB	/03361 /DEP
	TAD UKRB	/01361 /DEP
	DCA UKRS	/03371 /DEP
	TAD KRSF	/01345 /DEP
	DCA UKSF1	/03357 /DEP
	TAD KRSF	/01345 /DEP
	DCA UKSF2	/03367 /DEP
/This is just the stock RIM loader. It either runs as is, 
/or was patched above.
UKCC,	KCC		/06032 /DEP
UKSF1,	KSF		/06031 /DEP
	JMP .-1		/05357 /DEP
UKRB,	KRB		/06036 /DEP
	CLL RTL		/07106 /DEP
	RTL		/07006 /DEP
/Ignore if leader/trailer (0200 was punched)
	SPA		/07510 /DEP
	JMP IGNR	/05374 /DEP
/Finish rotate six and get low six
	RTL		/07006 /DEP
UKSF2,	KSF		/06031 /DEP
	JMP .-1		/05367 /DEP
UKRS,	KRS		/06034 /DEP
	SNL		/07420 /DEP
	DCA I PTR	/03776 /DEP
IGNR,	DCA PTR		/03376 /DEP
	JMP UKCC	/05356 /DEP
PTR,
07737 /LA GO

/Bootstrap 2: RK8E
00023 /LA
00000 /LEA
RELOC 00023
DLAG=	6743
DRST=	6745
/Not sure how this helps.
	02200 /DEP
/Read status
START2,	DRST		/06745 /DEP
/Harmless AND instruction.
	START2-1	/00023 /DEP
/Wait for reasonable status.
	SZA CLA		/07640 /DEP
	JMP START2	/05024 /DEP
/Start a read. AC==0, so block zero.
	DLAG		/06743 /DEP
/Hang waiting for read to overlay us.
	JMP .		/05031 /DEP
00024 /LA GO

/Bootstrap 3: RX8E
/This is the hunting bootstrap for single or double density on drive 0 or 1.
/(See XRX01S.PA.)
00024 /LA
00000 /LEA
RELOC 00024
LCD=	6751		/Load Command Register
XDR=	6752		/Transfer Data Register
STR=	6753		/Skip if Transfer Requested
SER=	6754		/Skip if Error
SDN=	6755		/Skip if Done
BEG,	STL RTL		/07126 /DEP
	TAD SELCT	/01060 /DEP
	LCD		/06751 /DEP
	CLA IAC		/07201 /DEP
	JMS XFSUB	/04053 /DEP
	JMS XFSUB	/04053 /DEP
	CLL RAL		/07104 /DEP
/Wait for done
START3,	SDN		/06755 /DEP
	JMP XFSUB+1	/05054 /DEP
	SER		/06754 /DEP
	SNA		/07450 /DEP
	CLA SKP		/07610 /DEP
	JMP UNLOAD	/05046 /DEP
/Move on to the next drive
	TAD SELCT	/01060 /DEP
	CIA		/07041 /DEP
	TAD SELCTD	/01061 /DEP
	DCA SELCT	/03060 /DEP
	JMP BEG		/05024 /DEP
UNLOAD,	LCD		/06751 /DEP
DATLP,	JMS XFSUB	/04053 /DEP
	DCA 2		/03002 /DEP
	ISZ .-1		/02050 /DEP
	JMP DATLP	/05047 /DEP
/Data Transfer Subroutine
XFSUB,	0		/00000 /DEP
	STR		/06753 /DEP
	JMP START3	/05033 /DEP
	XDR		/06752 /DEP
	JMP I XFSUB	/05453 /DEP
SELCT,	7024		/07024 /DEP
SELCTD,	6030		/6030 /DEP
00033 /LA GO

/Bootstrap 4: RF08/DF32
07750 /LA
00000 /LEA
RELOC 07750
DMAR=	6603		/Begin a Read
DFSC=	6622		/Skip if Complete
START4,	CLA 0400	/07600 /DEP
	DMAR		/06603 /DEP
	DFSC		/06622 /DEP
	JMP .-1		/05352 /DEP
	JMP I .-2	/05752 /DEP
07750 /LA GO

/Bootstrap 5: TA8E/DECASSETTE
/This can also be found in bootv4.pa as the bootloader for /CA.
/Source code is in Appendix D of the CAPS Users Manual, DEC-8E-OCASA-B-D.
04000 /LA
00000 /LEA
RELOC 04000
KCLR=	6700		/Clear all
KSDR=	6701		/Skip on data flag
KSEN=	6702		/Skip on error
KSBF=	6703		/Skip on ready flag
KLSA=	6704		/Load status A
KSAF=	6705		/Skip on any flag or error
KGOA=	6706		/Assert status A
KRSB=	6707		/Read status B
LOC=	3602
START5,	TAD M50		/01237 /DEP
CRCCHK,	TAD L260	/01206 /DEP
	KLSA		/06704 /DEP
	KGOA		/06706 /DEP
	KSBF		/06703 /DEP
RDCOD,	JMP .-1		/05204 /DEP
L260,	CML STA RAL	/07264 /DEP
	KSEN		/06702 /DEP
	SKP CLA		/07610 /DEP
	DCA .		/03211 /DEP
	DCA I CPTR	/03636 /DEP
	TAD RDCOD	/01205 /DEP
/Load into status register A
	KLSA		/06704 /DEP
CLOOP,	KGOA		/06706 /DEP
/Wait for data flag
	KSDR		/06701 /DEP
	JMP .-1		/05216 /DEP
	BSW		/07002 /DEP
	SZL		/07430 /DEP
	TAD I CPTR	/01636 /DEP
	CML BSW		/07022 /DEP
	DCA I CPTR	/03636 /DEP
	SNL		/07420 /DEP
	ISZ CPTR	/02236 /DEP
	ISZ KNT		/02235 /DEP
	JMP CLOOP	/05215 /DEP
	STA CLL RTL	/07346 /DEP
	BSW		/07002 /DEP
	DCA KNT		/03235 /DEP
	JMP CRCCHK	/05201 /DEP
KNT,	7737		/07737 /DEP
CPTR,	LOC-23		/03557 /DEP
M50,	-50		/07730 /DEP
04000 /LA GO
$