FIELD 0; *0
/Pre-canned Restart vectors
00000 /LA
00000 /LEA GO
00200 /LA
00000 /LEA GO
02000 /LA
00000 /LEA GO
04200 /LA
00000 /LEA GO

/Bootstrap 1: High or low speed paper tape
07737 /LA
00000 /LEA
RELOC 07737
/Start the high speed reader
START1,	RFC		/06014 /DEP
	DCA PTR		/03376 /DEP
/Spin to let reader possibly come ready
LOOP,	CLA CLL CML RTL	/07326 /DEP
	TAD START1	/01337 /DEP
	ISZ PTR		/02376 /DEP
	JMP LOOP	/05341 /DEP
/If it came ready, patch for LSR
KRSF,	RSF		/06011 /DEP
	JMP UKCC	/05356 /DEP
	DCA UKRB	/03361 /DEP
	TAD UKRB	/01361 /DEP
	DCA UKRS	/03371 /DEP
	TAD KRSF	/01345 /DEP
	DCA UKSF1	/03357 /DEP
	TAD KRSF	/01345 /DEP
	DCA UKSF2	/03367 /DEP
/This is just the stock RIM loader. It either runs as is,
/or was patched above.
UKCC,	KCC		/06032 /DEP
UKSF1,	KSF		/06031 /DEP
	JMP .-1		/05357 /DEP
UKRB,	KRB		/06036 /DEP
	CLL RTL		/07106 /DEP
	RTL		/07006 /DEP
/Ignore if leader/trailer (0200 was punched)
	SPA		/07510 /DEP
	JMP IGNR	/05374 /DEP
/Finish rotate six and get low six
	RTL		/07006 /DEP
UKSF2,	KSF		/06031 /DEP
	JMP .-1		/05367 /DEP
UKRS,	KRS		/06034 /DEP
	SNL		/07420 /DEP
	DCA I PTR	/03776 /DEP
IGNR,	DCA PTR		/03376 /DEP
	JMP UKCC	/05356 /DEP
PTR,
07737 /LA GO

/Bootstrap 2: RK8E
00023 /LA
00000 /LEA
RELOC 00023
DLAG=	6743
DRST=	6745
/Not sure how this helps.
	02200 /DEP
/Read status
START2,	DRST		/06745 /DEP
/Harmless AND instruction.
	START2-1	/00023 /DEP
/Wait for reasonable status.
	SZA CLA		/07640 /DEP
	JMP START2	/05024 /DEP
/Start a read. AC==0, so block zero.
	DLAG		/06743 /DEP
/Hang waiting for read to overlay us.
	JMP .		/05031 /DEP
00024 /LA GO

/Bootstrap 3: RX8E
/This is just the bootstrap from rxsy1.pa.
00020 /LA
00000 /LEA
RELOC 00020
LCD=	6751		/Load Command Register
XDR=	6752		/Transfer Data Register
STR=	6753		/Skip if Transfer Requested
SER=	6754		/Skip if Error
SDN=	6755		/Skip if Done
READ,	TAD UNIT	/01061 /DEP
	TAD CON360	/01046 /DEP
	AND CON420	/00060 /DEP
	DCA UNIT	/03061 /DEP
	CLA STL IAC RTL	/07327 /DEP
	TAD UNIT	/01061 /DEP
	LCD		/06751 /DEP
	CLA CLL IAC	/07301 /DEP
	JMS LOAD	/04053 /DEP
	JMS LOAD	/04053 /DEP
LITRAL,	RAL		/07004 /DEP
START3,	SDN		/06755 /DEP
	JMP LOAD+1	/05054 /DEP
	SER		/06754 /DEP
	SNA		/07450 /DEP
	JMP READ	/05020 /DEP
	TAD UNIT	/01061 /DEP
	LCD		/06751 /DEP
	TAD UNIT	/01061 /DEP
	AND CON360	/00046 /DEP
	TAD LITRAL	/01032 /DEP
	DCA RX1SAV	/03060 /DEP
CON360,	360		/00360 /DEP
	JMS LOAD	/04053 /DEP
	DCA 2		/03002 /DEP
	ISZ .-1		/02050 /DEP
	JMP .-3		/05047 /DEP
LOAD,	0		/00000 /DEP
	STR		/06753 /DEP
	JMP START3	/05033 /DEP
	XDR		/06752 /DEP
	JMP I LOAD	/05453 /DEP
RX1SAV,
CON420,	420		/00420 /DEP
UNIT,	20		/00020 /DEP
00033 /LA GO
00000
00000
00000
00000

/Bootstrap 4: RL8A
/This is the bootstrap from the Device Extensions User Guide (AA-D319A-TA).
/See Appendix B.
00001 /LA
00000 /LEA
RLDC=	6600		/Clear Device
RLSD=	6601		/Skip on Done
RLCA=	6603		/Load Command A
RLCB=	6604		/Load Command B
RLSA=	6605		/Load Sector Address
RLWC=	6607		/Load Word Count
RRSI=	6615		/Read Silo
RLSE=	6617		/Skip on Error
BSW=	7002		/Byte Swap (8/A)
RELOC 1
START4,	RLDC		/06600 /DEP
	CLA IAC		/07201 /DEP
	JMS IO		/04027 /DEP
	TAD .		/01004 /DEP
	JMS IO		/04027 /DEP
	RRSI		/06615 /DEP
	BSW		/07002 /DEP
	RTR		/07012 /DEP
	RRSI		/06615 /DEP
	AND C377	/00025 /DEP
	RAL		/07004 /DEP
	RLCA		/06603 /DEP
	CLA STL IAC RAL	/07325 /DEP
	JMS IO		/04027 /DEP
	CLA STL RTR	/07332 /DEP
	RLSA		/06605 /DEP
	TAD C7600	/01026 /DEP
	RLWC		/06607 /DEP
	CLA STL IAC RTL	/07327 /DEP
	JMS IO		/04027 /DEP
/Reading in secondary bootstrap prevents "IO" from
/returning. Control continues in secondary bootstrap.
C377,	377		/00377 /DEP
C7600,	CLA 7600	/07600 /DEP
IO,	0		/00000 /DEP
	RLCB		/06604 /DEP
	RLSD		/06601 /DEP
	JMP .-1		/05031 /DEP
	RLSE		/06617 /DEP
	JMP I IO	/05427 /DEP
	JMP START4	/05001 /DEP
00001 /LA GO
	00000
	00000
	00000
$