Name     sn7485 ;
PartNo   cpld ;
Date     4/15/2018 ;
Revision 01 ;
Designer  ;
Company   ;
Assembly None ;
Location E1 ;
Device   f1508isptqfp100;

/* Input Pins */
pin  9 = B0I; /* LSB */
pin 10 = A0I;
pin 11 = B1I;
pin 12 = A1I;
pin 13 = A2I;
pin 14 = B2I;
pin 15 = A3I; /* MSB */
pin  1 = B3I;
pin  2 = LTI;
pin  3 = EQI;
pin  4 = GTI;

/* Output Pins */
pin  5 = gto;
pin  6 = eqo;
pin  7 = lto;

node n0e, n1e, n2e, n3e;
n0e = A0I $ B0I;
n1e = A1I $ B1I;
n2e = A2I $ B2I;
n3e = A3I $ B3I;

Field I = [n3e, B3I, n2e, B2I, n1e, B1I, n0e, B0I, GTI, LTI, EQI];
Field O = [gto, lto, eqo];

/*
 * This is straight out of the data sheet.  For bit n, the [n<n>e, B<n>I] 
 * is 10 (not equal, B is zero) "A>B"
 * or 11 (not equal, B is one) "A<B"
 * or 0x (equal, B irrelevant) "A=B"
*/
Table I => O {
  'b'10xxxxxxxxx => 'b'100;
  'b'11xxxxxxxxx => 'b'010;
  'b'0x10xxxxxxx => 'b'100;
  'b'0x11xxxxxxx => 'b'010;
  'b'0x0x10xxxxx => 'b'100;
  'b'0x0x11xxxxx => 'b'010;
  'b'0x0x0x10xxx => 'b'100;
  'b'0x0x0x11xxx => 'b'010;
  'b'0x0x0x0x100 => 'b'100;
  'b'0x0x0x0x010 => 'b'010;
  'b'0x0x0x0xxx1 => 'b'001;
  'b'0x0x0x0x110 => 'b'000;
  'b'0x0x0x0x000 => 'b'110;
}