1            /
   2            / This is essentially rx02boot.pal, with random cruft loaded into
   3            / the don't-care locations.  It does manage to boot the RX01 or
   4            / RX02, provided the drive switch settings happen to match the
   5            / density of the floppy actually inserted.
   6            /
   7            /               MINIMAL PDP-8 BOOTSTRAP PROGRAM (RX)
   8            /
   9            / Taken from a manual for an 8/e disk subsystem built by DSD;
  10            / shorter and easier to toggle in than DECs bootstrap.
  11            
  12            / The following is a minimal length boot program for both
  13            / the RX01 and RX02.  This boot tries only the specified
  14            / drive with the specified density.  Start at location 32 to
  15            / BOOT drive 0.  Start at location 22 to boot drive 1.
  16            / This has been verified to work with an OS/8 diskette.
  17            
  18            / the contents of locations 60 and 61 can be fudged to
  19            / change what disk and what density are used.
  20            
  21            / configuration section
  22            
  23            IOTADR=0750             / default system drive is at IOT 75
  24            
  25            DRIVE0=0000
  26            DRIVE1=0020
  27            DRIVE=DRIVE0            / set to either DRIVE0 or DRIVE1
  28            
  29            SINGLE=0000
  30            DOUBLE=0400
  31            DENSTY=DOUBLE           / set to either SINGLE or DOUBLE
  32            
  33            / RX01 and other opcode definitions
  34            
  35            LCD=6001+IOTADR
  36            XDR=6002+IOTADR
  37            STR=6003+IOTADR
  38            SDN=6005+IOTADR
  39            
  40            NL001=CLA CLL IAC
  41            NL002=CLA CLL IAC RAL
  42            NL006=CLA CLL CML IAC RTL
  43            
  44            / THIS SECTION IS NEEDED ONLY WHEN BOOTING FROM DRIVE 1.
  45            / READS IN SECTOR 1 TRACK 1 ON DRIVE O OR 1.
  46            
  47            / DOES NOT USE LOCATIONS 22-31 WHEN STARTED AT 32
  48            
  49            / START HERE TO BOOT DRIVE 0 (ASSUME MASTER CLEAR HAS
  50            / READ DRIVE 0 TRACK 1 SECTOR 1 FOR YOU).
  51            
  52            *32
  53 00032 7305 BOTDV0, NL002           / MAKE EMPTY BUFFER COMMAND
  54 00033 6755 CHKFLG, SDN             / WAIT FOR DONE FLAG UP
  55 00034 5054         JMP     LOAD+1  / NO - CHECK FOR READY TRANSFER
  56 00035 1061         TAD     UNIT    / YES-PUT IN READ UNIT, DENSITY
  57 00036 6751         LCD             / SEND EMPTY BUFFER COMMAND
  58 00037 5047         JMP     BOTLP   / START TO LOAD SECTOR BUFFER
  59 00040 4053         JMS LOAD        / Not used.
  60 00041 3002         DCA 2           / Not used.
  61 00042 2050         ISZ BOTLP+1     / Not used.
  62 00043 5047         JMP BOTLP       / Not used.
  63 00044 6322         6322            / Not used.
  64 00045 6753         STR             / Not used.
  65 00046 5033         JMP CHKFLG      / Not used.
  66            
  67            *47     /////////////////
  68            
  69 00047 4053 BOTLP,  JMS     LOAD    / READ NEXT WORD FROM SILO
  70 00050 3002         DCA     2       / START LOADING AT LOC. 2
  71 00051 2050         ISZ     .-1     / BUMP LOAD ADDRESS
  72 00052 5047         JMP     BOTLP   / CONTINUE EMPTYING BUFFER
  73            /
  74 00053 3632 LOAD,   3632            / DATA TRANSFER SUBROUTINE
  75 00054 6753         STR             / SKIP IF CONTROLLER WILL SPEAK
  76 00055 5033         JMP     CHKFLG  / NO - CHECK IF FINISHED
  77 00056 6752         XDR             / TRANSFER DATA IN OR OUT
  78 00057 5453         JMP I   LOAD    / RETURN TO CALLER
  79            /
  80 00060 7004         7004+DRIVE      / USED BY SECONDARY BOOT
  81                                    / TO SELECT DRIVE 0 OR DRIVE 1
  82 00061 0400 UNIT,   DENSTY+DRIVE    / WHAT TRANSPORT, WHAT DENSITY?
  83 00062 0401         0401            / Not used.
  84 00063 0400         0400            / Not used.
  85 00064 7777         7777            / Not used.
  86 00065 7777         7777            / Not used.
  87 00066 7777         7777            / Not used.
  88 00067 7777         7777            / Not used.
  89 00070 7777         7777            / Not used.
  90 00071 7777         7777            / Not used.
  91            $