100 REM RT11 OUTPUT PROGRAM
110 DIM A$(80), D$(16)
120 PRINT "RT11 INPUT PROGRAM"
130 PRINT "WHAT IS THE NAME OF THE FILE THAT HAS THE DIRECTORY";
140 INPUT D$
150 REM IF NO EXTENSION, ASSUME .DI
160 IF POS(D$,".",1) <> 0 THEN 180
170 D$ = D$ & ".DI"
180 FILE #1:D$
190 FILEV#2:"RTBAT.TM"
200 PRINT #2:"$JOB RT11 COPY"
210 PRINT #2:".R RTFLOP"
220 PRINT "WHAT DEVICE DO YOU WANT THE FILES COPIED TO";
230 INPUT D$
240 IF POS(D$,":",1) <> 0 THEN 260
250 D$ = D$ & ":"
260 PRINT "WHAT EXTENSION SHOULD THE OS/8 FILES HAVE";
270 INPUT E$
280 IF LEN(E$) > 2 THEN 260
290 INPUT #1:A$
300 IF END #1 THEN 410
310 IF POS(A$,".",1) <> 7 THEN 290
320 A$ = SEG$(A$,1,10)
330 I = POS(A$," ",1)
340 IF I = 0 THEN 370
350 A$ = SEG$(A$,1,I-1) & SEG$(A$,I+1,10)
360 GO TO 320
370 J = POS(A$,".",1)
380 A$ = "*" & D$ & SEG$(A$,1,J) & E$ & "<" & A$ & "/I"
390 PRINT #2:A$
400 GO TO 290
410 PRINT #2:"*$"
420 PRINT #2:".DELETE RTBAT.TM"
430 PRINT #2:"$END"
440 CLOSE #1
450 CLOSE #2
460 PRINT "NOW TYPE 'SUBMIT RTBAT.TM' TO COPY YOUR FILES"
470 END