/ETOS RX01 NON-SYSTEM HANDLER
/ETRX01.PA VERSION 3.2 THURSDAY 2-SEPTEMBER-1976 10:16 AM

	RXVER=	3
	CUF=	6264
	SUF=	6274
	DEVCOD=750	/RX01 DEVICE CODE
	SDN=	6005!DEVCOD
	STR=	6003!DEVCOD
	XDR=	6002!DEVCOD
	LCD=	6001!DEVCOD
	SER=	6004!DEVCOD
	INIT=	6007!DEVCOD

*0
	-2
	DEVICE	ETRX
	DEVICE	RXA0
	4250
	RXA0&177
	0
	0
	DEVICE	ETRX
	DEVICE	RXA1
	4250
	RXA1&177
	0
	0
*200
FN,	0	/0 FOR WRITE, 2 FOR READ
BUF,	0	/USER BUFFER POINTER
REC,	0	/RECORD NUMBER (BEFORE INTERLEAVING)
WC,	0	/WORD COUNT

LDCMD,	0000		/LOAD COMMAND REGISTER
	DCA	TRANS	/SAVE
	SDN		/TEST FOR DONE FLAG
	JMP	.-1
	TAD	TRANS
	LCD		/LOAD COMMAND REGISTER
	JMP I	LDCMD

TRANS,	0000		/TRANSFER A WORD
	STR		/TRANSFER DONE FLAG?
	JMP	.-1
	XDR
	JMP I	TRANS

*230			/KEEP ENTRY POINTS SAME AS IN STAND ALONE

RXA0,	RXVER
	CLA
	JMP	RXCOMN
UNIT,	0		/4 IF UNIT 0, 24 IF UNIT 1

RXA1,	RXVER
	CLA
	TAD	RXA1
	DCA	RXA0
	STL RTL
RXCOMN,	STL RTL
	RAL
	DCA	UNIT
	RDF
	TAD	(CDF CIF 0
	DCA	SRET
	CLA STL RAR	/4000
	TAD I	RXA0	/READ/WRITE IN LINK
	AND	S70
	TAD	(CDF 0
	DCA	BUFCDF
	CML RTL
	DCA	FN
	TAD I	RXA0
	RAL
	AND	S7600
	CIA
	DCA	WC
	ISZ	RXA0
	TAD I	RXA0
	DCA	BUF
	ISZ	RXA0
	TAD I	RXA0
	CLL RTL
	DCA	REC
	ISZ	RXA0
BUFCDF,	.-.
	CUF
	TAD	FN
	SNA CLA
	JMP	STWRIT
WORDLP,	TAD	WC
	AND	S77
	SZA CLA
	JMP	TRANWD
	JMS	DISKIO
	ISZ	REC
STWRIT,	TAD	FN
	JMS	LDCMD
TRANWD,	TAD I	BUF
	JMS	TRANS
	DCA I	BUF
	ISZ	BUF
S70,	70
	ISZ	WC
	JMP	WORDLP
	TAD	FN
	SNA CLA
	JMS	DISKIO
	ISZ	RXA0
S77,	77		/SO WE DON'T BOMB OUT ETOS IF .-1 SKIPED
ERRRET,	SUF
	JMP	SRET
SRET,	.-.
	JMP I	RXA0
DISKIO,	0000
	STA CLL RTL
	DCA	TRYCNT
TRYAGN,	TAD	FN
	TAD	UNIT
	JMS	LDCMD
	DCA	QUO
	STL
	TAD	REC
DIVLP,	SZL
	ISZ	QUO
	TAD	(-15
	SMA
	JMP	DIVLP
	CML RAL
	TAD	(33
	JMS	TRANS
	CLA
	TAD	QUO
	JMS	TRANS
S7600,	7600
	TAD	SLSTAT
	JMS	LDCMD
	SER
	JMP I	DISKIO
	INIT
	ISZ	TRYCNT
	JMP	TRYAGN
SLSTAT,	STL RAR
	JMP	ERRRET

TRYCNT,	0
QUO,	0
/
$