SENDLOC=3400
	TASK=SEND1
	CUR=0
	CHANNL=3
	STEP=57
	PRIME=7723
	FIELD	CUR%10
	*SENDLOC
NODNAM,	TEXT	/RK05/
	INIWT=RUNWT
	CCB=SENDLOC+40	/MAKE ROOM FOR NODE NAMES
	USRAST=	CCBRTN	/NO USER AST
	*CCB+12
	0
	TEXT	/SEND1/
	ZBLOCK	3
	1;2
	*SENDLOC+210

START,	TAD	(NODNAM	/SET UP NODE POINTER
	DCA I	LNODP	/NODE POINTER ON SEPARATE PAGE
	DCA	FIRST
RETRY,	CAL		/FIRST CONNECT TO ECHO TASK
	SENDW
	NSP
	CIMSG
	TAD	CIMSG+3
	SZA CLA
	JMP	RETRY
	DCA	TRMSG+3	/INIT STATUS TO 0
	DCA	MSG	/INIT SEQUENCE CHECKER TO 0
LOOP,	CLL		/PSEUDO RANDOM FOR SIZE
	TAD	PSEUD
	TAD	(STEP
	SZL		/CHECK FOR WRAP AROUND
	TAD	(-PRIME	/MOD A PRIME <4095
	DCA	PSEUD	/NEW POINTER TO CORE
FIRST,	TAD I	PSEUD	/ONE IN 32 OF QUITTING, OTHER 31 SIZE
	TAD	(6
	AND	(37
	SNA
	JMP	DISC	/HIT 1 OF 32, DISCONNECT
	TAD	(40	/SIZE RANGE 33-63
	CIA
	DCA	TRMSG+10 /PLACE SIZE
	TAD	MSG	/GET SEQ CHAR LAST SENT
	TAD	(7401
	SMA
	IAC		/DON'T USE 0 !!
	AND	(377
	DCA	MSG
	CAL
	SENDW		/SEND
	NSP
	TRMSG		/
	TAD	TRMSG+3	/STATUS
	SZA CLA		/SKIP OK
	JMP	OOPS	/ASSUME A DISCONNECT!!
	ISZ	JOBC1
	SKP
	ISZ	JOBC0
	NOP
	TAD	(TAD I PSEUD
	DCA	FIRST
	JMP	LOOP
LPLOP,	ERRTXT+3
L6060,	6060
OOPS,	TAD	L6060
	DCA I	LPLOP
/	CAL
/	SENDW
/	TTY
/	ERRMSG		/PRINT THE ERROR MESSAGE NOW
DISC,	CAL
	SENDW
	NSP
	DIMSG		/DICONNECT
	CAL
	SENDW
	CLOCK
	HOLDIT
	JMP	START	/GO START UP AGAIN
HOLDIT,	ZBLOCK	5
	2

	/MISC DATA

PSEUD,	0
POINTR,	0
COUNTR,	0
JOBC0,	0
JOBC1,	0
LNODP,	NODPTR	/GET TO NEXT PAGE

	PAGE
CIMSG,	ZBLOCK	3
	0
	CONINI
	CHANNL
NODPTR,	0
	ECHONM
	0
	.+1
	ZBLOCK	11
ECHONM,	0
	TEXT	/ECHO1/
	ZBLOCK	3
	0;0
DIMSG,	ZBLOCK	3
	0
	DISCON
	CHANNL
	0
ERRMSG,	ZBLOCK	5	/ERROR MESSAGE FOR TTY
ERRTXT,	TEXT	/SEND> 00 ERROR/


TRMSG,	ZBLOCK	3
	0
	TRNSMT
	CHANNL
	CDF	CUR
	MSG
	0		/SIZE DYNAMIC
MSG,	ZBLOCK	100