/ INITIALIZE FIELD 4				1-SEP-91
/
/
/
/	PPPP   RRRR   EEEEE   SSSS  FFFFF     4
/	P   P  R   R  E      S      F        44
/	P   P  R   R  E      S      F       4 4
/	PPPP   RRRR   EEEE    SSS   FFFF   4  4
/	P      R R    E          S  F      44444
/	P      R  R   E          S  F         4
/	P      R   R  EEEEE  SSSS   F         4
/
/
/
/

/
/EDIT HISTORY:
/
/20-APR-90	(LHN)
/	1)  ADDED CRT TEXT CALL TO TURN OFF VT CURSOR
/25-APR-90	(LHN)
/	1)  DELETED PRESET OF VARIABLES FOR "RANNUM"
/
/
/08-JUL-91	(LHN)		FOR VERSION 4A
/	1)  ADDED VALUES FOR ENBLPT AND ENBCOM
/	2)  HAVE SCREEN DISPLAY NEXT ROLL FIELDS
/
/
/1-SEP-91	(LHN)		FOR VERSION 4B
/	1)  ADDED CONSTT
/


	TASK=	PRESF4
	CUR=	PRES4FLD
	INIWT=	0
	VERS=	4



	TASK2=	SCREEN
	CUR2=	CUR
	INIWT2=	RUNWT
	VERS2=	4



	FIELD PRES4FLD%10
	*PRES4LOC
/
/
/%R	INITIALIZE FIELD 4 AT START UP
/
/
START,  CAL		/TELL POWER FAIL
	SEND
	PWRF
	PWRFMG
	CLB
AGAIN,	CLB
	TAD (PR4TBL-1)
	DCA XR10
	TAD (PR4TBL-PR4END-1)
	STL RAR
	DCA PRES4B
	TAD I XR10
	DCA PRES4A
	TAD I XR10
	DCA I PRES4A
	ISZ PRES4B
	JMP .-5

	TAD (SCREEN)
	CAL
	RUN

	CAL
	SUSPND
	JMP AGAIN

PRES4A, 0
PRES4B, 0

PWRFMG, ZBLOCK 3
	AGAIN-1
/
/
/
/	 SSSS   CCCC  RRRR   EEEEE  EEEEE  N   N
/	S      C      R   R  E      E      N   N
/	S      C      R   R  E      E      NN  N
/	 SSS   C      RRRR   EEEE   EEEE   N N N
/	    S  C      R R    E      E      N  NN
/	    S  C      R  R   E      E      N   N
/	SSSS    CCCC  R   R  EEEEE  EEEEE  N   N
/
/
/

/
/
/%R	REFRESH THE ENTIRE CRT SCREEN
/
/
START2,	CLB
	TAD (CRTREF)
	DCA CRTRFA	/SET POINTER TO TEXT STRING
CRTRF1,	TAD I CRTRFA	/FETCH NEXT POINTER
	ISZ CRTRFA
	SNA		/IS IT THE TERMINATOR?
	JMP CRTRF2	/YES, EXIT
	DCA CRTRFB	/NO, STORE FOR OUTPUT
	CAL
	SENDW		/SEND THIS MESSAGE TO CRT
	CRT
	CRTRTB
	JMP CRTRF1	/TRY NEXT TEXT POINTER
CRTRF2, CLB
	DCA CRTRFB
	CAL
	SENDW
	CRTMSG
	CRTRTB
	CLB
	CAL
	SUSPND
	JMP START2	/GO AGAIN


CRTRFA, 0		/TEXT STRING POINTER

CRTRTB,	ZBLOCK 3	/MESSAGE FOR SCREEN UPDATE
CRTRFB, 0		/TEXT MESSAGE POINTER
/
/
/	CRT MESSAGE LIST FOR REFRESH
/
/
CRTREF,	CRTH00
	CRTH00
	CRTH01
	CRTX11
	CRTH02
	CRTX12
	CRTH03
	CRTX13
	CRTH04
	CRTH05
	CRTH06
	CRTH07
	CRTX06
	CRTX01
	CRTH08
	CRTX07
	CRTX02
	CRTH09
	CRTX08
	CRTX03
	CRTH10
	CRTX09
	CRTX10
	CRTX04
	CRTX05
	CRTH11
	CRTH12
	CRTH13
	CRTH14
	CRTH15
	CRTD01
	CRTH16
	CRTD02
	CRTH17
	CRTD03
	CRTH18
	CRTD04
	CRTH19
	CRTD05
	CRTH20
	CRTD06
	CRTH21
	CRTD07
	CRTV01
	0			/MESSAGE TEXT STRING END
/
/
/%RX	TABLE OF INITIAL VALUES FOR PROGRAM START UP
/
/
PR4TBL,	ENBLPT		/ENABLES TALLEY OUTPUT TO LPT
	1
	ENBCOM		/ENABLES TALLEY OUTPUT TO GATEWAY
	1
	CONSTT		/CONSOLE CRT STATE, 0=> BACKGROUND.
PR4END,	0

	PAGE

	NOPUNCH		/THE CRTTXT FILE FOLLOWS

	XLIST 1		/TURN THE LISTING OFF  !!