/COS DDT				EDITED 10/8/73
/COPYRIGHT 1972, 1973
/DIGITAL EQUIPMENT CORPORATION
/MAYNARD, MASS.  01754
/CREATED BY STEALTH IN THE DEAD OF NIGHT
/BY RFL, SGW, AND SR
/
/THIS SOFTWARE IS FURNISHED TO PURCHASER UNDER A LICENSE FOR USE
/ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH INCLUSION
/OF DEC'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH SYSTEM, EXCEPT
/AS MAY OTHERWISE BE PROVIDED IN WRITING BY DEC.
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT
/NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL
/EQUIPMENT CORPORATION.
/
/DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY
/OF ITS SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.
/

	/COS EQUIVALENCES:
SPLIT=	76
SYS=	77
CDOIO=	27
GETC=	24
TOPFLD=	7775
BREAKP=	7770
TTOCHR=	31
M1=	45
P7=	40
P77=	20
OTOPD=	74
LENGTH=	44
	/RSYS EQUIVALENCES:
BP=	6
SYMTAB=	132
DES1L=	120
PDL=	106
OLDPDL=	5
PUTDL=	130
PUTDF=	131
PUTDES=	126
POPDS1=	4550
GETCH1=	4554
P7770=	BP
SSLIM1=	1574
SSLIM2=	1575
POPDES=	4547
PUTCHI=	4556
ILOOP=	1400

	FIELD 0
	*200
	TAD	(75&17^400
	JMS I	77
	4210
	6400
	75%20
	TAD	(76&17^400
	JMS I	77
	4410
	3400
	76%20
	IOF
	JMP I	(7605

	FIELD 1
	*6400
EDDT,	JMP	DDSWAP
ETRAP,	JMP	DDTRAP
EERROR,	ISZ I	(CTZLOC+3400
DDSWAP,	TAD	(DDT
ECOMN,	DCA	EPT
	RIF
	TAD	(CDF
	DCA	SWCDF
	TAD	(7000
	DCA	P1
	TAD	(3400
	DCA	P0
SWAPLP,	CDF 0
	TAD I	P0
	DCA	S0
SWCDF,	HLT
	TAD I	P1
	DCA	S1
	TAD	S0
	DCA I	P1
	CDF 0
	TAD	S1
	DCA I	P0
	ISZ	P0
	ISZ	P1
	JMP	SWAPLP
	CDF CIF 0
	JMP I	EPT
EPT,	0
DDTRAP,	ISZ	TRPCT
	JMP	DDTJF0
	TAD	(TRAP
	JMP	ECOMN
P0,	0
S0,	0
P1,	0
S1,	0
DDTRET,	JMP	.+3
	CDF CIF 0
	JMP I	(7600
	TAD	(ILOOP
	JMP	ECOMN
DDTJF0,	CDF CIF 0
	JMP I	(ILOOP
TRPCT,	0

	*3400
DDT,	CLA IAC
	JMS I	CDOIO
	DDTMSG-1
	NOP
	JMP	CMDLP
TRAP,	CLA IAC
	JMS I	CDOIO
	TRPMSG-1
	NOP
CMDLP,	TAD	("-
	JMS I	TTOCHR
	TAD	(-60
	DCA	LENGTH
	JMS I	CDOIO
	INPLN-1
	JMP	INPERR
	DCA	CHCT
	JMS	GCH
	TAD	(-5
	SNA
	JMP	BREAK
	TAD	(5-37
	SNA
	JMP	CONT
	TAD	(37-77
	SZA
	JMP I	(NOTTRC
TRCBK,	STA
	TAD	OLDPDL
TRCLP,	DCA	D
	TAD I	D
	SNA
	JMP	CMDLP
	DCA	NUM
	DCA	CHCT
	TAD	NUM
	CLL
	ISZ	CHCT
	TAD	(-144
	SZL
	JMP	.-4
	TAD	K144
	JMS I	OTOPD
	DCA	LO
	STA
	TAD	CHCT
	JMS I	OTOPD
	DCA	HI
	CLA IAC
	JMS I	CDOIO
	LNO-1
K144,	144
	STA CLL RTL
	TAD	D
	JMP	TRCLP

BREAK,	JMS	NUMB
	SZA CLA
	JMP	ERROR
	TAD	NUM
	CIA
	DCA I	BP
	JMP	CMDLP
INPERR,	TAD I	(INPLN
	SMA CLA		/EOF OR LINE TOO LONG?
	JMP	CTLZ	/EOF
ERROR,	CLA IAC
	CDF 0
	JMS I	CDOIO
	ERRMSG-1
	NOP
	JMP	CMDLP
NUMB,	0
	DCA	NUM
	JMS	GCH
	DCA	D
	TAD	D
	TAD	(-33
	CLL
	TAD	(12
	SNL
	JMP	EONUM
	DCA	D
	TAD	NUM
	CLL RTL
	TAD	NUM
	RAL
	TAD	D
	JMP	NUMB+1
EONUM,	TAD	(21
	JMP I	NUMB
NUM,	0
D,	0
GCH,	0
	TAD	(INPLN
	JMS I	GETC
CHCT,	0
ISZ	CHCT
	JMP I	GCH
LNO,	-2
HI,	0
LO,	0

CONT,	JMS	NUMB
	TAD	NUM
	SNA
CTLZ,	CLA IAC
	CIA
	DCA	D
	STL RTL
	TAD I	(TOPFLD
	DCA	.+1
	HLT
	TAD	D
	DCA I	(TRPCT
	JMP I	.+1
CTZLOC,	DDTRET
	PAGE

NOTTRC,	TAD	P77
	DCA	T
	DCA	N1
	TAD	(101
	DCA	N2
	TAD	N2
	DCA	N3
	TAD	(-7
	DCA	NCT
	DCA I	(SS1
	DCA I	(SS2
	TAD	T
	SKP
NAMLP,	JMS I	(GCH
	SNA
	JMP I	(ERROR
	TAD	(-11
	SNA
	JMP	SUBSC
	TAD	(11-36
	SNA
	JMP	EQUAL

	TAD	(36
	DCA	T
	ISZ	NCT
	SKP
	JMP	GT6CHN
	TAD	NCT
	STL RAR
	TAD	(N1+3
	DCA	P
	TAD	T
	SNL
	JMP	RTSIDE
	CLL RTL
	RTL
	RTL
	IAC
	JMP	.+3
RTSIDE,	TAD I	P
	TAD	M1
	DCA I	P
	JMP	NAMLP
GT6CHN,	STA
	DCA	NCT
	JMP	NAMLP
COMMA,	TAD I	(NUM
	DCA I	(SS2
SUBSC,	JMS I	(NUMB
	TAD	(-15
	SNA
	JMP	COMMA
	TAD	(15-12
	SZA CLA
	JMP I	(ERROR
	TAD I	(NUM
	DCA I	(SS1
	JMS I	(GCH
	TAD	(-36
	SZA CLA
	JMP I	(ERROR	/VERIFY = SIGN
EQUAL,	TAD	N1
	SNA CLA
	JMP I	(CALCDS
	TAD I	(YOUBLEWIT
	DCA	P
	CLA IAC
	TAD	SYMTAB
	DCA	T
	TAD I	(TOPFLD
	DCA	.+1
	HLT
E1,	ISZ	P
E2,	ISZ	P
SRCHLP,	TAD I	P
	ISZ	P
	ISZ	T
	ISZ	T
	SNA
	JMP I	(ERROR
	CIA
	TAD	N1
	SZA CLA
	JMP	E1
	TAD I	P
	ISZ	P
	CIA
	TAD	N2
	SZA CLA
	JMP	E2
	TAD I	P
	ISZ	P
	CIA
	TAD	N3
	SZA CLA
	JMP	SRCHLP
	TAD I	T
	DCA	NCT
	ISZ	T
	TAD I	T
	JMP I	(STODSC
N1,	0
N2,	0
N3,	0
P,	0
T,	0
NCT,	0
	PAGE

STODSC,	CDF 0
	DCA	D2
	TAD I	(NCT
	DCA	D1
CALCDS,	CDF 0
	TAD	D1
	SNA
	JMP I	(ERROR
	AND	P7770
	CLL RTR
	RAR
	DCA	C
	TAD	SS2
	SNA
	JMP	SINGLE
	CIA
	TAD	SS1
	IAC
	DCA	C
	TAD	SS2
	TAD	M1
	JMP	SSCOMN
SINGLE,	TAD	SS1
	SNA
	JMP	NOSS
	CIA
	DCA	TMP
	SKP
	TAD	C
	ISZ	TMP
	JMP	.-2
SSCOMN,	CLL
	TAD	D2
	DCA	D2
	SZL
	ISZ	D1
	DCA	TMP
	TAD	C
	TAD	D2
	SZL
	ISZ	TMP
	CLL
	TAD I	(SSLIM2
	CLA RAL
	TAD	TMP
	TAD	D1
	AND	P7
	TAD I	(SSLIM1
	SZL CLA
	JMP I	(ERROR
NOSS,	TAD	D1
	AND	P7
	CLL RTR
	TAD	C
	TAD	C
	RTL
	DCA	D1
	TAD	D1
	DCA I	PDL
	ISZ	PDL
	TAD	D2
	DCA I	PDL
	ISZ	PDL
	JMS I	(GCH
	SNA
	JMP	EXAM
	DCA	TMP
	TAD	(PUTDES-1
	POPDES
	DCA I	PUTDF
	TAD	TMP
PUTLP,	PUTCHI
	JMS I	(GCH
	SNA
	JMP I	(CMDLP
	ISZ	PUTDL
	JMP	PUTLP
	JMP I	(ERROR
EXAM,	POPDS1
EXAMLP,	GETCH1
	TAD	(237
	JMS I	TTOCHR
	ISZ	DES1L
	JMP	EXAMLP
	CLA IAC
	JMS I	CDOIO
	.
	0
	JMP I	(CMDLP
D1,	0
D2,	0
SS1,	0
SS2,	0
C,	0
TMP,	0
	PAGE

DDTMSG,	-10	/COS DDT V 3.07
	4460
	6401
	4545
	6501
	6701	/V
	2417	/3.
	2130	/07
	0000	/PATCH LEVEL
TRPMSG,	-3	/BREAK!
	4363;4642;5402
ERRMSG,	-5	/ERR IN CMD
	4663;6301;5257;0144;5645
INPLN,	ZBLOCK 60
	YOUBLEWIT=4377	/*** KLUDGE, KLUDGE, KLUDGE! ***
	*YOUBLEWIT
	5		/*** RSYS COMPATIBILITY NUMBER ***
	$