/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/

	.TITLE SUBROUTINE INIT

/THIS SUBROUTINE IS THE FIRST TO BE CALLED BY MAIN1 WHEN A NEW BUILD IS
/STARTED. ALL SYSTEM TABLES ARE CLEARED TO PROVIDE FOR PROGRAM 
/RESTART. USR CALLS ARE THEN MADE TO LOAD THE TTY HANDLER. PARAMETERS
/SUCH AS ENTRY POINT ARE SAVED IN THE TABLE AREA FOR FUTURE USE. THE
/BOOTSTRAP SCRIPT IS THEN SENT TO THE TTY DEVICE TO INQUIRE THE USER
/TO INDICATE WHICH MASS STORAGE DEVICE HAS SCRIPT.SV RESIDENT. COLAN
/IS STRIPED IF PRESENT, AND DEVICE NAME STORED IN TABLE AREA AS
/SCRIPT DEVICE. SUFFICIENT ROOM REMAINS IN INIT.MA TO ADD FUTURE 
/INITILIZATION AS REQUIRED.

	.RSECT INIT
	.EXTERNAL TABLE1,PCKPTR,TTYPTR,EPACK,DEV1,DEV2,CLR,TABLE2
	.EXTERNAL TEMP1,TEMP2,TEMP3,TEMP4,TEMP5,ENTR1,TEMP10
	.EXTERNAL QUEPTR,ANSPTR,ASCPTR,NUMPTR,RECPTR,FLDPTR
	.EXTERNAL TSKPTR,SYSPTR,OVRPTR,ETTY,EQUES,EANS
	.EXTERNAL EASCI,ENUM,EREC,EFLD,ETASK,ESYS,EOVER
	.EXTERNAL DEV3,DEV4,DEVNO1,ENTR2,TTTY,UNPAC,UNP1,PACK6,PAC1,PACPTR
	.ENTRY INIT1
	.ENABLE OS8
	.NOLIST ME,MEB
	.NOLIST LN
	XLIST
	.INCLUDE MACLIB.MA
	XLIST
	.MCALL USERV,HANDL,CLEAR



/THIS SECTION CLEARS THE VARIOUS RTSGEN TABLES

	FIELD 1
INIT1,	0
	TAD	(CIF CDF)
	RDF
	CDF	.FLD
	DCA	EXIT2
	TAD	INIT1
	DCA	INIT16
				/GO GET SYSTEM TABLES INTO CORE

	CLEAR	QUEPTR,EQUES,TABLE1,0,SUBR
	CLEAR	ANSPTR,EANS,TABLE1,0,SUBR
	CLEAR	ASCPTR,EASCI,TABLE1,0,SUBR
	CLEAR	NUMPTR,ENUM,TABLE1,0,SUBR
	JMP	INIT10
SUBR,CLR


	PAGE
INIT10,	NOP
	CLEAR	RECPTR,EREC,TABLE1,0,SUBR10
	CLEAR	FLDPTR,EFLD,TABLE1,0,SUBR10
	CLEAR	TSKPTR,ETASK,TABLE1,0,SUBR10

	JMP	INIT2

SUBR10,CLR

	PAGE

INIT2,	NOP

	CLEAR	SYSPTR,ESYS,TABLE1,0,SUBR1
	CLEAR	OVRPTR,EOVER,TABLE1,0,SUBR1
	CLEAR	TTYPTR,ETTY,TABLE1,0,SUBR1

	JMP	INIT3

SUBR1,CLR

/THIS SECTION GETS THE DEVICE TTY HANDLER INTO CORE AT
/LOCATION 6600-7200, AND THEN ASKS SCRIPT LOCATION QUESTION


	PAGE
INIT3,	CDF	TABLE1
					/USR CALL TO INQUIRE DEVICE (TTY)
	USERV	,12,DEV3,DEV4,ZERO,ERR6,DUMMY,DEVNO1
					/LOAD THE TTY DEVICE HANDLER
	USERV	DEVNO1,1,LOCA,,,ERR7,ENTR2,
	CLA
	RIF
	TAD	(4400
	DCA	TTCTLO
					/FORM CONTROL WORD FOR HANDL CALL
	TAD 	ENTR2
	DCA	TTY2
					/SETUP FOR HANDLER CALL (ENTRY)
	HANDL	TTCTLO,QSCRT,ZERO,ERR10,TTY2
					/GO ASK BOOTSTRAP QUESTION
	CDF	TABLE1
	CLA
	RDF
	TAD	(0100
	DCA	TTCTLI
					/SET CONTROL WORD FOR INPUT
	HANDL	TTCTLI,STTY,ZERO,ERR11,TTY2
					/GET UESER'S ANSWER
	JMP	INIT4


TTCTLO,0	/CONTROL WORD FOR TTY HANDLER (OUTPUT)
TTCTLI,0	/CONTROL WORD FOR TTY HANDLER (INPUT)
TTY2,0		/STORAGE FOR TTY ENTRY ADDRESS (MUST BE IN SAME FIELD AS CALL)
LOCA,6601	/LOCATION WHERE HANDLER IS LOADED (PROVISION FOR 2 PAGE IS MADE)
QSCRT,SCRTQ	/POINTER TO SCRTQ, THE BOOTSTRAP SCRIPT QUESTION
STTY,TTTY	/POINTER TO THE BEGINNING OF THE TTY INPUT/OUTPUT BUFFER

/THIS SECTION GETS THE DEVICE ANSWER AND CONVERTS  FROM UNPACKED
/TO SIXBIT FOR SUBSEQUENT CALLS TO USR BY FLDBLD.MA


	PAGE
INIT4,	CDF	TABLE1
	TAD	TTYPTR
	DCA	10
					/POINT TO TTY IN BUFFER
	TAD I	10
	AND	(177
	TAD	(200
	CIA
	TAD	CR
	SNA CLA
					/CHECK FOR CARR. RETURN
	JMP	EXIT2
					/YES, USE "SYS" AS DEFAULT
BAC1,	TAD I	10
	SNA
	JMP	DONE
					/DONE COLAN SEARCH IF ZERO
	AND	(177
	TAD	(200
	TAD	COLAN
	SNA CLA
	JMP	CRFL
					/IF COLAN, REPLACE WITH CR
	JMP	BAC1
					/CONTINUE
CRFL,	STA
	TAD	10
	DCA	10
	TAD	CR
	DCA I	10
					/REPLACE COLAN WITH CR
DONE,	CDF	.FLD
	CIF	PAC1
	JMS I	SUB7
	TTTY-1					/TTY BUFFER CONTAINS INPUT CHARACTERS
					/PACK SIXBIT FOR USR CALLS
	CDF	TABLE1
	TAD	PACPTR
					/PACK6 TABLE CONTAINS PACKED DATA
	DCA	10
	TAD I	10
	DCA	DEV1
	TAD I	10
	DCA	DEV2
EXIT2,	0
	JMP I	INIT16
					/RETURN TO MAIN1.MA

ERR6,HLT	/ERROR ENCOUNTERED WHEN TTY INQUIRE CALL WAS MADE
ERR7,HLT	/ERROR WHEN ATTEMPTING TO LOAD TTY HANDLER
ERR10,HLT	/I/O ERROR ON HANDLER CALL TO TTY DEVICE
ERR11,HLT	/INPUT I/O ERROR FROM TTY DEVICE HANDLER CALL
DUMMY,0		/DUMMY LOCATION FOR UNUSED ARGUMENT FROM USR CALL

SCRTQ,	TEXT	"ON WHAT DEVICE IS SCRIPT.SV LOCATED ? : "<232>
ZERO,0		/ZERO ARGUMENT FOR USR CALLS
CR,215		/CARRIAGE RETURN (SIXBIT)
SUB7,PAC1	/POINTER TO PACK6 ROUTINE
INIT16,0	/LINK FROM PAGE ONE
COLAN,-272	/COLAN CHARACTER (SIXBIT)