/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/
	.TITLE MAIN3-THE MAINLINE PASS3 ROUTINE

/MAIN3 SETS THE PASS3 FLAG, AND CALLS THE VARIOUS
/ROUTINES REQUIRED TO BUILD THE MACREL BATCH FILE,
/THE LINKER BATCH FILE, AND UP TO NINE CONTROL
/FILES FOR THE TTY AND FLOPPY TASKS IF SPECIFIED BY 
/THE USER DURING PASS1.  MAIN 3 CHECKS FOR CHAINING
/TO BATCH AND EITHER RETURNS TO THE MONITOR OR CHAINS 
/TO BATCH BASED ON THE USER'S SPECIFICATION.

	.EXTERNAL PASS3,PBLD,MBLD,LBLD,ANSPTR,DIRLOC,EREC
	.EXTERNAL LOGNUM,CQUES,IFLAG,TYPE,GETR
	.EXTERNAL UQ,TTYIO,ST,TABLE1,PAGEFG

	.ENTRY MAIN13
	.RSECT MAIN3
	.ENABLE OS8


MAIN13,	0
	CLA
			/NO RETURN REQUIRED
	CDF	TABLE1
	ISZ	PASS3
			/SET THE PASS3 FLAG
	CDF	.FLD	/CONTROL FILES AND
	CIF	PBLD	/PARAMETER FILES ARE
	JMS I	SUBP	/BUILT BY THIS SUBROUTINE
			/GO BUILD THE PNAME.MA FILE
	CDF	.FLD	/E OPTION IS INCLUDED IN THE
	CIF	MBLD	/MACREL BATCH FILE.  A RESUBMIT
	JMS I	SUBM	/IF USER DOES NOT HAVE SINGLE MEDIA
			/GO BUILD THE MNAME.BI FILE
			/(MACREL BATCH FILE.
	CDF	.FLD	/OPTIONS /K= AND /M
	CIF	LBLD	/ARE INCLUDED IN THE LINK
	JMS I	SUBL	/BATCH FILE
			/GO BUILD LNAME.BI FILE
	CDF	TABLE1
	CLA
	TAD	ANSPTR
	TAD	(27
			/GET THE ANSWER TO THE
			/"CHAIN TO BATCH QUESTION"
	DCA	10
			/SETUP FOR AUTOINDEX
	TAD I	10
			/GET THE ANSWER
	SZA CLA
	JMP	MAIN23	/ZERO MEANS NO
	JMP	MAIN43
			/GO BACK TO MONITOR
MAIN33,	0
	CLA
	TAD	(200
	DCA	PAGEFG
	TAD	(-1	/BRANCH REQUIRED
	DCA	LOGNUM	/SET PHASE BACK TO ZERO
	ISZ	IFLAG
			/SET THE BRANCH FLAG.

	TAD	MAIN53
	DCA	DIRLOC
			/PREVENT SUCCESSFUL ON-OVERLAY SEARCH
	CDF	.FLD
	CIF	GETR
	JMS I	SUBG
			/GETR BRANCHES TO SCRIPT RECORD
			/IN TREC AND THEN OVERLAYS INTO
	CDF	TABLE1	/TABLE TOVER
	TAD	(322
	DCA	TYPE
			/INDICATE A REMARK TYPE RECORD
	CDF	.FLD
	CIF	UQ
	JMS I	SUBQ
			/GO BLANK SYSTEM INFORMATION
	CDF	.FLD
	CIF	TTYIO
	JMS I	SUBT
			/OUTPUT TO USER.  THE TTY AND
			/SCRIPT DEVICE HANDLERS ARE
			/LEFT IN CORE THROUGHOUT.
	JMP I	MAIN33
			/RETURN TO CALLER

MAIN23,	CLA
	TAD	(5701	/GET CHAINING TO BATCH MESSAGE
	DCA	CQUES
	JMS	MAIN33	/OUTPUT EXIT MESSAGE
	CDF	.FLD	/ARGUMENT 3 CAUSES CHAIN
	CIF	ST	/TO BATCH
	JMS I	SUBS
	3
	HLT		/SHOULD NOT RETURN HERE
MAIN43,	CLA
	TAD	(5700
	DCA	CQUES
	JMS	MAIN33
	CDF	0
	CIF	0
	JMP I	MONT


MAIN53,EREC		/POINTER TO END OF RECORD DIRECTORY
MONT,	7600		/ADDRESS FOR MONITOR RETURN
SUBP,	PBLD		/PARAMETER FILE BUILD ROUTINE
SUBM,	MBLD		/MACREL BATCH FILE BUILD ROUTINE
SUBL,	LBLD		/LINKER BATCH FILE BUILD ROUTINE
SUBG,	GETR		/RECORD FETCHER ROUTINE
SUBQ,	UQ		/USER NUMBER ASSIGNER
SUBT,	TTYIO		/RECORD OUTPUT ROUTINE
SUBS,	ST		/BATCH FILE OUTPUT ROUTINE