/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/
	.TITLE SUBROUTINE MOVE

/MOVE GETS DATA FROM SOURCE BUFFER PASSED BY CALLER AND MOVES
/DATA INTO TABLE POINTED TO BY ARGUMENT TWO PASSED BY CALLER.
/MOVE DELIMITS EACH ENTRY BY A MINUS ONE.  MOVES RETURN
/POINTER TO NEXT ENTRY TO CALLER.

	.FSECT	MOVE
	.ENTRY	MOV
	.EXTERNAL TABLE1,PCKPTR




/CALLING SEQUENCE:
/
/	CDF	.FLD
/	CIF	MOVE
/	JMS I	SUB
/	ARG1
/	ARG2
/	 .
/	 .
/	 .
/SUB,MOV
/
/WHERE:
/	ARG1 - SOURCE BUFFER
/	ARG2 - TARGET BUFFER
/
/CURRENT VALUE OF TARGET BUFFER POINTER IS RETURNED IN ARG2
/
/

MOV,	0
	CLA
	TAD	T1
	RDF
	DCA	MOV1
	TAD I	MOV
	DCA	SAV1
				/MOV1 USED TO CHANGE FIELD FOR
				/PARAMETER PASSING; MOV POINTS
				/TO TARGET TABLE OF CALLER
	ISZ	MOV
				/INCREMENT TO POINT AT ARG2
	TAD I	MOV
				/GET AND SAVE IT
	DCA	SAV5
	TAD	T2
	RDF
	CDF	.FLD
	DCA	MOV20
				/SETUP FOR RETURN
				/INCREMENT PAST PARAMETER
	TAD	10
	DCA	SAV2
	TAD	11
	DCA	SAV3
				/PRESERVE AUTOINDEX
	DCA	MOV17
				/INITIALIZE OS/8 WORD COUNTER
	CDF	TABLE1
				/DATA TO BE MOVED ALWAYS
				/LOCATED IN SYSTEM TABLE AREA
	TAD	SAV1
	DCA	10
	TAD	SAV5
	DCA	11
				/SETUP FOR AUTOINDEX
	TAD	T3
	DCA	MOV17
				/SETUP COUNTER FOR NUMBER OF WORDS TO MOVE
MOV3,	TAD I	10
				/GET FIRST DATUM
	DCA I	11
				/MOVE IT
	ISZ	MOV17
				/NUMBER OF OS/8 PACKED WORDS IS FOUR
	JMP	MOV3
				/CONTINUE MOVING DATA
	CLA
	DCA I	11
				/DELIMIT ENTRY BY A ZERO
	TAD 11
MOV1,	0
				/CACULATED CDF HERE
	DCA I	MOV
				/RETURN THE POINTER TO THE NEXT
				/TABLE ENTRY TO CALLER
	ISZ	MOV
				/INCREMENT PAST ARG2
	TAD	SAV2
	DCA	10
	TAD	SAV3
	DCA	11
				/RESTORE AUTOINDEX
MOV20,	0
	JMP I	MOV
				/RETURN TO CALLER.

SAV1,	0		/STARTING LOCATION MINUS ONE OF SOURCE BUFFER
SAV2,	0		/SAVE LOCATION FOR AUTOINDEX 10
SAV3,	0		/SAVE LOCATION FOR AUTOINDEX 11
SAV4,	0		/TEMPORARY STORAGE FOR MOVED DATUM
SAV5,	0		/STARTING LOCATION MINUS ONE FOR TARGET BUFFER
MOV17,	0		/COUNTER FOR NUMBER OF OS/8 WORDS MOVED
T1,	CDF
T2,	CDF CIF
T3,	-4