/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/
	.TITLE SUBROUTINE TCCON

/THIS SPECIAL ROUTINE HANDLES DEVICE CODE ENTRY FOR TTY
/DEVICES WHERE CONTROL FILES ARE CREATED.  FROM 1 TO FOUR
/CONTROL FILES MAY BE SPECIFIED.  ERROR RETURN IS TAKEN IF
/DEFAULT IS ATTEMPTED WHEN SPECIFYING CONTROL FILES.

	.RSECT	TCCON
	.ENTRY	TD
	.ENTRY	TC
	.EXTERNAL TABLE1,CFLAG,TTALLY,UQ,TTYIO,MAIN12,TTYFLG,ERR1,TQES
	.EXTERNAL TTYPTR,OCTDEC,OCTD,OFLAG,QUES,TYPE,ANSPTR,DIRLOC,IQUES


	FIELD	1
TC,	0
	CLA
	TAD	(CIF CDF)
	RDF
	DCA	TC20
	TAD	TC
	DCA	RET
				/SETUP FOR RETURN
	JMP	TCC
				/ZERO PREVIOUS ENTRIES
TXC,	TAD	(317
	DCA	TYPE
				/SETUP FOR OCTAL TYPE QUESTION
	TAD	TTALLY
	CIA
	DCA	TC2
				/GET NUMBER OF CONTROL FILES
				/REQUIRED AND SETUP COUNTER
	CDF	.FLD
	CIF	UQ
	JMS I	TC21
				/GO ASSIGN USER QUESTION NUMBER
	CDF	.FLD
	CIF	TTYIO
	JMS I	TC22
				/OUTPUT THE TTY QUESTION
	CDF	TABLE1
	TAD	TTYPTR
	DCA	16
	TAD I	16
	TAD	(-277
	SNA
	JMP	TC23
				/USER QUERY, GO OUTPUT REMARK
	TAD	(277-243
	SNA CLA
	JMP	TC23
				/USER # FUNCTION, RETURN TO CHANGE QUESTION
	STA
	TAD	16
	DCA	16
				/BACKUP TO BUFFER START
TC4,	TAD I	16
	SNA
	JMP	ERR100
				/ZERO INDICATES INSUFFICIENT ENTRIES
	TAD	(-254
	SNA
	JMP	TCC5
				/FIND FIRST COMMA
	TAD	(254-215
	SZA CLA
				/OR CR IF ONLY ONE ENTRY
	JMP	TC4
TCC5,	STA
	TAD	16
	DCA	16
	TAD	(215
	DCA I	16
				/REPLACE COMMA WITH CR
	TAD	16
	DCA	TCC4
				/SAVE POINTER TO NEXT ENTRY
	TAD	TTALLY
	SZA CLA
	JMS	TCC6
				/IF ANY CONTROL FILES,DEFAULT NOT ALLOWED
	TAD	QUES
	DCA	TQES
				/FOR T-TYPE ANSWER DISPLACEMENT IN TQES
	JMS	TCST
				/GO STORE FIRST ANSWER IN
				/NORMAL FASHION.
	TAD	TTYFLG
	SNA CLA
	JMP	TC17
				/TTY FLAG RESET, NO CONTROL FILES REQUIRED
	TAD	TCC4
	DCA	16
				/RESTORE AUTOINDEX
TCC16,	TAD	KBFLG
TC16,	TAD	TC10
	DCA	TQES
	ISZ	TC16
	ISZ	TC2
				/CHANGE SYSTEM QUESTION NUMBER
				/FOR ENTRY OF ANSWER POINTER
				/IN CONTROL FILE AREA OF ANSWER
				/TABLE; THEN INCREMENT TO POINT
				/TO NEXT ENTRY
	SKP
	JMP	TC17
				/IF ISZ SKIPS, ALL CONTROL FILE
				/ENTRIES HAVE BEEN MADE
	TAD	TTYPTR
	DCA	15
TC6,	TAD I	16
	SNA
	JMP	ERR100
				/INSUFFICIENT ENTRIES
TC7,	TAD	(-254
				/NEXT COMMA?
	SNA
	JMP	TC5
	TAD	(254-215)
	SNA			/CARRIAGE RETURN?
	JMP	TC5
	TAD	(215
	DCA I	15
	JMP	TC6		/NEITHER COMMA OR CARRIAGE
				/RETURN; MOVE TO HEAD OF BUFFER
TC5,	TAD	(215
	DCA I	15
				/INSERT COMMA AFTER
				/CURRENT ANSWER WHICH WAS
				/MOVED TO HEAD OF BUFFER
	JMS	TCC6
TCC7,	JMS	TCST
				/GO STUFF ANSWER IN TNUM
				/AND POINTER IN CONTROL
				/FILE AREA OF ANSWER TABLE
	JMP	TCC16
				/GO GET NEXT
TC17,	CLA
	DCA	KBFLG
				/RESET THE KBFLG
	TAD	DIRLOC
	TAD	(3
	DCA	DIRLOC
				/BYPASS CORRESPONDING REMARK
TC20,	0
	JMP I	RET






RET,0			/STORAGE FOR RETURNPOINT
TC10,	701		/START OF RESPECTIVE ENTRY FOR CONTROL FILES IN
			/ANSWER TABLE (TANS)
TC11,	716
TC12,	731
TC13,	746
TCC4,0			/TEMP. STORAGE FOR AUTOINDEX
TC21,UQ			/LINK TO UQUES ROUTINE
TC22,TTYIO		/LINK TO TTYDVR ROUTINE

TC2,	0		/NUMBER OF CONTROL FILES SPECIFIED
KBFLG,0			/DISPLACEMENT FOR TTY KEYBOARD DEVICE ENTRY



TC31,	TAD	TC10	/CALCULATED TAD INSTRUCTION

	PAGE

TCST,	0	
	CLA
				/HERE TO STORE OCTAL ANSWER
	ISZ	OFLAG
				/SET THE OCTAL ANSWER FLAG
	CDF	.FLD
	CIF	OCTD
	JMS I	TC14
	CDF	TABLE1
	CLA
	JMP I	TCST
			/RETURN	TO CALLER

TC14,	OCTD		/LINK TO OCTDEC ROUTINE

TD,	0
				/HERE FOR KEYBOARD DEVICE CODE ENTRY
	TAD	(CIF CDF)
	RDF
	CDF	.FLD
	DCA	TC20
				/SETUP FOR COMMON RETURN
	TAD	TD
	DCA	RET
	IAC
	DCA	KBFLG
				/ADD TO DISPLACEMENT IN TTY CONTROL FILES
	JMP	TCC
ERR100,	CLA
			/HERE WHEN DEFAULT ATTEMPTED FOR DEVICE CODE ENTRY
	ISZ	IQUES
	CDF	.FLD
	DCA	KBFLG
			/RESET KEYBOARD DEVICE CODE ENTRY FLAG
	TAD	(100
	CIF	ERR1
	JMS I	RETU
RETU2,	1
			/OUTPUT ERROR MESSAGE AND RETURN TO QUESTION

RETU,ERR1

TC23,	CLA
	CIF	MAIN12
	JMP I	TC30
				/HERE WHEN # OR ? USER RESPONSE


TC30,MAIN12		/ENTRY TO MAIN1 TO AVOID TTY OUTPUT
TCC6,	0
	CLA
	TAD	TTYPTR
	DCA	17
	TAD I	17
	TAD	(-215
	SNA CLA
	JMP	ERR100
	JMP I	TCC6	
				/NO DEFAULTS ALLOWED FOR DEVICE CODES
TCC,	CLA
	TAD	(-4
	DCA	TC26
TC27,	TAD	KBFLG
	CDF	TABLE1
	TAD	ANSPTR
TC25,	TAD	TC40
	DCA	16
	DCA I	16
	TAD	QUES
	DCA	RETU2
				/USE EXCESS THREE FEATURE FOR QUESTION RETURN
	ISZ	TC25
				/INCREMENT CALCULATED TAD TO POINT TO
				/NEXT CONTROL FILE POINTER ENTRY IN TANS
	CDF	.FLD
	ISZ	TC26
				/CHECK FOR FOUR EXECUTIONS
	JMP	TC27
				/DONE WHEN FOUR ARE ZEROED
	TAD	TC31
	DCA	TC16
				/INITIALIZE CALCULATED TAD
	TAD	TC28
	DCA	TC25
				/INITIALIZE CALCULATED TAD INSTRUCTION
				/CLEAR CONTROL FILE ENTRIES FOR POSSIBLE
				/REENTRY FOR # FUNCTION
	CDF	TABLE1
	JMP	TXC
				/RETURN TO CONTINUE

TC40,	701
	716
	731
	746
TC26,0			/COUNTER FOR NUMBER OF CONTROL FILES
TC28,TAD	TC40	/CALCULATED TAD INSTRUCTION FOR TWO LOOPS