/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/
	.TITLE SUBROUTINE TYPET

/TYPET ALLOWS FOR SUBROUTINES WHICH PERFORM NO GENERAL
/FUNCTIONS, SUCH AS TASK ENTRY, CONTROL FILE, OR PRIORITIZATION.
/TYPET IS A CENTRAL CALLING FUNCTION WHICH BRANCHES TO A
/PARTICULAR SUBROUTINE TA THROUGH TZ AS A FUNCTION OF SUBTYPE.
/SPARES MAY BE USED BY INSERTING THE APPROPRIATE ENTRY IN THE
/JUMP TABLE, IN THE CALL TABLE, AND IN THE EXTERNAL STATEMENT

	.RSECT	TYPET
	.ENTRY	T
	.EXTERNAL TABLE1,TTYPTR,UNPACK,UNP1,TTTY,OVRPTR,RECLOC
	.EXTERNAL PCKPTR,TACON,TBCON,TCCON,TGDEFH,TASK,TSWAP
	.EXTERNAL TA,TB,TC,TD,TE,TF,TG,TH,TI,TLTASK,TKTASK,TNCON
	.EXTERNAL TJ,TK,TL,TM,TN,DIRLOC,ERR1,TO,TFG,LIM,TCHK2
	FIELD 1
T,	0
	CLA
	TAD	(CIF CDF)
	RDF
	CDF	.FLD
	DCA	T30
				/SETUP FOR RETURN
	CDF	TABLE1
	TAD	OVRPTR
	TAD	RECLOC
	DCA	T101
				/POINT TO BEGINNING OF T-RECORD
	CDF	.FLD
	CIF	UNP1
	JMS I	UNP
				/GO UNPACK T-RECORD
T101,	0
	UNPACK-1
				/PARAMETERS FOR SOURCE AND TARGET BUFFERS
	1
				/UNPACK THREE CHARACTERS
	CDF	TABLE1
	ISZ	TFG
				/SET THE T SUBROUTINE IN PROGRESS FLAG
	TAD	PCKPTR
	IAC
	DCA	10
				/SET AUTOINDEX TO POINT AT SUBTYPE
	TAD I	10
	AND	(77
				/GET LAST 6 BITS
	TAD	T100
				/CACULATE THE JUMP
	TAD	(200
	DCA	T0
				/STORE TEMPORARILY
	TAD	T300
	TAD	(-1
	AND	(77
	TAD	T0
				/ADD THE PAGE BIT AND
				/DISPLACEMENT
	DCA	T0
				/DEPOSIT CACULATED INSTRUCTION
	CDF	.FLD
T0,	JMP	0
T300,	T200
T200,	JMP	T1		/JUMP TABLE.  INSERT HERE
	JMP	T2		/AND IN CALL TABLE TO USE SPARES
	JMP	T3
	JMP	T4
	JMP	T5
	JMP	T6
	JMP	T7
	JMP	T10
	JMP	T11
	JMP	T12
	JMP	T13
	JMP	T14
	JMP	T15
	JMP	T16
	JMP	T17
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
	JMP	ERR60
				/ERR60 IF PROGRAM NOT INSERTED
T27,	CDF	LIM
	CLA
	DCA	TCHK2
				/RESET MULTIPLE PASS FLAG
	CDF	TABLE1
	DCA	TFG
				/RESET TFG
T30,	0
	JMP I	T

ERR60,	CLA
				/HERE FOR NON-EXISTENT T-TYPE
	TAD	(60
	CDF	.FLD
	CIF	ERR1
	JMS I	RETU
	2
				/OUTPUT ERROR AND RETURN TO MONITOR

RETU,ERR1			/LINK TO ERROR ROUTINE

T100,	JMP	0		/JMP USED FOR CALCULATED INSTRUCTION
UNP,	UNP1


	PAGE
T1,	CIF	TA		/CALL TABLE.  INSERT AS SHOWN
	JMS I	SUBA		/FOR USING SPARES
	JMP	T27
T2,	CIF	TB
	JMS I	SUBB
	JMP	T27
T3,	CIF	TC
	JMS I	SUBC
	JMP	T27
T4,	CIF	TD
	JMS I	SUBD
	JMP	T27
T5,	CIF	TE
	JMS I	SUBE
	JMP	T27
T6,	CIF	TF
	JMS I	SUBF
	JMP	T27
T7,	CIF	TG
	JMS I	SUBG
	JMP	T27
T10,	CIF	TH
	JMS I	SUBH
	JMP	T27
T11,	CIF	TI
	JMS I	SUBI
	JMP	T27
T12,	CIF	TJ
	JMS I	SUBJ
	JMP	T27
T13,	CIF I	TK
	JMS I	SUBK
	JMP	T27
T14,	CIF	TL
	JMS I	SUBL
	JMP	T27
T15,	CIF	TM
	JMS I	SUBM
	JMP	T27
T16,	CIF	TN
	JMS I	SUBN
	JMP	T27
T17,	CIF	TO
	JMS I	SUBO
	JMP	T27

SUBA,	TA
SUBB,	TB
SUBC,	TC
SUBD,	TD
SUBE,	TE
SUBF,	TF
SUBG,	TG
SUBH,	TH
SUBI,	TI
SUBJ,	TJ
SUBK,	TK
SUBL,	TL
SUBM,	TM
SUBN,	TN
SUBO,	TO