/
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)		1978,1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/VERSION=1
/
	.TITLE SUBROUTINE YESNO

/YESNO IS BRANCHED TO IF A YES/NO TYPE QUESTION IS ENCOUNTERED.
/YESNO SETS THE LOCATION OF THE ANSWER TABLE ENTRY CORRESPONDING
/TO THE DISPLACEMENT OF THE RECORD NUMBER TO 1 IF THE ANSWER
/IS YES.  DOES NOTHING IF THE ANSWERS IS NO.  IF CARRIAGE RETURN
/IS ENCOUNTERED, A CALL IS MADE TO DEFAULT WHICH RETURNS WITH A
/POINTER, DFPTR, TO THE DEFAULT ANSWER.  SAME ACTION AS ABOVE
/IS TAKEN FOR THE DEFAULT ANSWER.  IF ANSWER IS NEITHER YES
/OR NO, AN ERROR RETURN IS TAKEN.

	.ENTRY	YESN
	.FSECT YESNO
	.EXTERNAL TTYPTR,TEMP1,TEMP2,TEMP3,TABLE1,DEFLT,DIRLOC,IQUES,ERR1
	.EXTERNAL ANSPTR,DFPTR,DFLT,MAIN11,DIRLOC,QUES,TQES,TFG



YESN,	0
	CLA
	TAD	F1
	RDF
	CDF	.FLD
	DCA	YESNO7
	CDF	TABLE1
				/SETUP FOR RETURN
	TAD I	F6
	DCA	RETU3
				/USE EXCESS THREE FEATURE FOR ERROR CALLS
	TAD I	F13
	SNA CLA
	JMP	Y14
	TAD I	F14
	DCA	F15
	JMP	Y15
				/BYPASS NORMAL PATH (NON-T-TYPE)
				/IF T-TYPE, ANSWER POINTER IS IN TQES
Y14,	TAD I	F6
	DCA	F15
				/NORMAL PATH,DEPOSIT QUES AS ANSWER DISPLACEMENT
Y15,	TAD	10
	DCA I	F2
	TAD	11
	DCA I	F3
				/SAVE AUTOINDEX REGISTERS
	TAD I	F4
	DCA	10
	TAD I	10
				/GET FIRST CHARACTER
	DCA I	F5
				/SAVE IT
YESNO4,	TAD I	F5
	CIA
	TAD	YESNO1
	SNA
	JMP	YES
				/ANSWER IS YES
	CLA
	TAD I	F5
	CIA
	TAD	YESNO2
	SNA
	JMP	NO
				/ANSWER IS NO
	CLA
	TAD I	F5
	CIA
	TAD	YESNO3
	SNA
	JMP	CR
				/DEFAULT DESIRED
	JMP	ERR21
				/NEITHER YES/NO OR DEFAULT IS ERROR
YES,	CLA
	TAD	F15
	TAD I	F7
	DCA	10
				/POINT TO CURRENT ENTRY IN ANSWER TABLE
	IAC
	DCA I	10
				/SET ANSWER TO YES.
	JMP	YESNO6
				/HERE WHEN ANSWER IS NO
NO,	CLA
	TAD	F15
	TAD I	F7
	DCA	10
				/POINT TO CURRENT ENTRY IN ANSWER TABLE
	DCA I	10
				/MUST CLEAR ANSWER, SINCE SOME QUESTIONS
				/CAN BE REUSED.
	JMP	YESNO6
				/LEAVE ANSWER NO.
CR,	CDF	.FLD
	CIF	DFLT
	JMS I	FAULT
				/USE DEFAULT TO GET LOCATION IN
				/RECORD OF THE DEFAULT PARAMETER
	CDF	TABLE1
	CLA
	TAD I	F10
	DCA	11
	TAD I	11
				/GET FIRST CHARACTER OF DEFAULT
	DCA I	F5
				/STORE IN TEMPORARY
	JMP	YESNO4
				/TAKE SAME ACTION AS BEFORE
YESNO6,	CLA
	TAD I	F2
	DCA	10
	TAD I	F3
	DCA	11
YESNO7,	0
	JMP I	YESN

ERR21,	CLA		/NEITHER A YES OR A NO ANSWER
	ISZ I	F11
	TAD	F12
	CDF	.FLD
	CIF	ERR1
	JMS I	RETU
RETU3,	1
			/OUTPUT ERROR, AND RETURN TO QUESTION

RETU,ERR1		/LINK TO ERROR ROUTINE

YESNO1,	331		/ASCII Y
YESNO2,	316		/ASCII N
YESNO3,	215		/ASCII CARRIAGE RETURN
FAULT,	DFLT		/LINK TO DEFAULT ROUTINE
F1,	CIF CDF
F2,	TEMP1
F3,	TEMP3
F4,	TTYPTR
F5,	TEMP2
F6,	QUES
F7,	ANSPTR
F10,	DFPTR
F11,	IQUES
F12,	21
F13,TFG
F14,TQES
F15,0			/STORAGE FOR CURRENT DISPLACEMENT IN TANS