/	DMII SEND PROGRAM

	*200			/AS USUAL

START,	CAF			/CLEAN UP
	TLS			/SET FLAG
	TAD	(-1402)		/SETUP THE
	DCA	BLKCNT		/BLOCK COUNT
	DCA	REC		/INITIALIZE RECORD
LOOP,	JMS I	(7607)		/CALL HANDLER
	2^100			/READ TWO PAGES
	BUFFER			/BUFFER ADDRESS
REC,	.-.			/RECORD
	HLT			/ERROR RETURN
	TAD	("B)		/GET A BLOCK INDICATOR
	JMS	OUT		/PRINT IT
	TAD	REC		/GET LATEST BLOCK
	JMS	OCTOUT		/PRINT IT
	ISZ	REC		/BUMP UP FOR NEXT TIME
	TAD	(BUFFER-1)	/SETUP THE
	DCA	10		/BUFFER POINTER
	TAD	(-400)		/SETUP THE
	DCA	BUFCNT		/BUFFER COUNT
BUFLUP,	TAD I	10		/GET A WORD
	JMS	OCTOUT		/PRINT IT
	ISZ	BUFCNT		/DONE ALL YET?
	JMP	BUFLUP		/NO, KEEP GOING
	ISZ	BLKCNT		/DONE ALL BLOCKS?
	JMP	LOOP		/NO, KEEP GOING
	JMP I	(7600)		/YES, GOODBYE

OCTOUT,	.-.			/OCTAL PRINT ROUTINE
	DCA	OCTEMP		/SAVE IT
	TAD	(-4)		/SETUP THE
	DCA	OCTCNT		/DIGIT COUNT
OCLOOP,	TAD	OCTEMP		/GET THE VALUE
	RTL;RAL			/MOVE UP
	DCA	OCTEMP		/SAVE IT
	TAD	OCTEMP		/GET IT AGAIN
	RAL			/MOVE UP
	AND	(7)		/JUST LATEST DIGIT
	TAD	("0&177)	/MAKE IT ASCII
	JMS	OUT		/PRINT IT
	ISZ	OCTCNT		/DONE FOUR YET?
	JMP	OCLOOP		/NO, KEEP GOING
	TAD	(15)		/GET A <CR>
	JMS	OUT		/PRINT IT
	TAD	(12)		/GET A <LF>
	JMS	OUT		/PRINT IT
	JMP I	OCTOUT		/RETURN
OUT,	.-.			/OUTPUT ROUTINE
	DCA	OUTEMP		/SAVE IT
OUTLUP,	KSF			/FLAG UP?
	JMP	OUTEST		/NO, TEST OUTPUT FLAG
	KRB			/YES, READ IT IN
	AND	(177)		/JUST SEVEN-BIT
	TAD	(-"S!300)	/IS IT <^S>?
	SZA CLA			/SKIP IF SO
	JMP	OUTEST		/ELSE IGNORE IT
QWAIT,	KSF			/WAIT
	JMP	.-1		/FOR THE FLAG
	KRB			/GET THE CHARACTER
	AND	(177)		/JUST SEVEN-BIT
	TAD	(-"Q!300)	/IS IT <^Q>?
	SZA CLA			/SKIP IF SO
	JMP	QWAIT		/ELSE GO BACK
OUTEST,	TSF			/FLAG UP?
	JMP	OUTLUP		/NO, TRY INPUT AGAIN
	TAD	OUTEMP		/GET THE CHARACTER
	TLS			/OUTPUT IT
	CLA			/CLEAN UP
	JMP I	OUT

BLKCNT,	.-.			/TEMPORARY
BUFCNT,	.-.			/TEMPORARY
OCTCNT,	.-.			/TEMPORARY
OCTEMP,	.-.			/TEMPORARY
OUTEMP,	.-.			/TEMPORARY

	PAGE

	BUFFER=	.		/DATA BUFFER