/	COMPARE TWO P?S/8 FILES

/	LAST EDIT	08-DEC-1985	08:00:00	CJL

/	COMPARES TWO P?S/8 FILES PASSED TO IT.
	*200			/START AT THE BEGINNING

START,	TAD I	(7757)		/GET FIRST FILE ARGUMENT
	AND	(7770)		/JUST BLOCK BITS
	DCA	BLOCK1		/STORE IN-LINE
	TAD I	(7757)		/GET IT AGAIN
	AND	(7)		/JUST UNIT BITS
	TAD	(20^100+10)	/ADD ON FUNCTION WORD
	DCA	RDFUN1		/STORE IN-LINE
	TAD I	(7760)		/GET SECOND FILE ARGUMENT
	AND	(7770)		/JUST BLOCK BITS
	DCA	BLOCK2		/STORE IN-LINE
	TAD I	(7760)		/GET IT AGAIN
	AND	(7)		/JUST UNIT BITS
	TAD	(20^100+10)	/ADD ON FUNCTION WORD
	DCA	RDFUN2		/STORE IN-LINE
	JMS I	(7640)		/CALL I/O ROUTINES
	0			/ADDRESS
RDFUN1,	20^100+10+.-.		/UNIT BITS WILL BE FILLED IN
BLOCK1,	.-.			/BLOCK NUMBER WILL BE FILLED IN
	JMS I	(7640)		/CALL I/O ROUTINES
	4000			/ADDRESS
RDFUN2,	20^100+10+.-.		/UNIT BITS WILL BE FILLED IN
BLOCK2,	.-.			/BLOCK NUMBER WILL BE FILLED IN
	CLA CLL CML RAR		/4000
	DCA	CNT		/STORE AS COUNTER
	CLA CMA			/7777
	DCA	10		/STORE AS FIRST FILE POINTER
	CLA CLL CMA RAR		/3777
	DCA	11		/STORE AS SECOND FILE POINTER
CMPLUP,	CDF	10		/GOTO BUFFER FIELD
	TAD I	10		/GET A WORD
	CIA			/INVERT FOR TESTING
	TAD I	11		/GET OTHER WORD
	CDF	00		/BACK TO OUR FIELD
	SZA CLA			/SKIP IF A MATCH
	JMP	BAD		/ELSE FORGET IT
	ISZ	CNT		/DONE YET?
	JMP	CMPLUP		/NO, KEEP GOING
	TAD	("M-"B)		/COUNTER BAD MESSAGE
BAD,	TAD	("B&177)	/GET BAD VALUE
	CIF	70		/GOTO OVERLAY FIELD
	JMS	33		/OUTPUT IT
	JMP	.-2		/WAIT FOR IT
	JMP I	(7600)		/GOODBYE!

CNT,	.-.			/COMPARE COUNTER
	$			/THAT'S ALL FOLK!