/	GRAPHICS TEST PROGRAM

/	TEST ROUTINES FOR DECMATE II GRAPHICS OPTIONS.

/	LAST EDIT:	08-APR-1987	01:00:00	CJL

/	DEFINITIONS.

	GRDR=	6150		/GRAPHICS OPTION DMA READ
	GRDW=	6151		/GRAPHICS OPTION DMA WRITE
	GRGR=	6154		/GRAPHICS OPTION GDC READ
	GRGW=	6155		/GRAPHICS OPTION GDC WRITE
	GRW1=	6156		/GRAPHICS OPTION WRITE REGISTER ONE
	GRW2=	6157		/GRAPHICS OPTION WRITE REGISTER TWO
	SBOOT=	7600		/SYSTEM BOOTSTRAP ADDRESS
	*0			/START AT THE BEGINNING

	*10			/GET TO AUTO-INDEX AREA

	*20			/GET PAST AUTO-INDEX AREA

COUNT,	-20			/DATA WORD COUNT
LODTEMP,.-.			/DATA TEMPORARY STORAGE
WASTE,	.-.			/TIME WASTE COUNTER
W1VAL1,	71			/WRITE REGISTER ONE LOW-ORDER VALUE
W1VAL2,	1400			/WRITE REGISTER ONE HIGH-ORDER VALUE
W2VAL,	3567			/WRITE REGISTER TWO VALUE
	PAGE

START,	CLA CLL			/CLEAN UP

/	DON'T DO CAF HERE, SINCE I DON'T YET KNOW WHAT IT DOES TO THE HARDWARE!

	TAD	(400)		/GET MAGIC VALUE
	GRGW			/WRITE GDC REGISTER
WAIT1,	CLA			/IS THIS NECESSARY?
	GRGR			/READ GDC REGISTER
	AND	(40)		/JUST SOME SORT OF READY BIT PLEASE
	SNA CLA			/SKIP IF IT SET
	JMP	WAIT1		/ELSE WAIT FOREVER
WAIT2,	GRGR			/READ GDC REGISTER AGAIN
	AND	(40)		/JUST THE SAME BIT AS BEFORE
	SZA CLA			/SKIP IF NOW OFF
	JMP	WAIT2		/ELSE WAIT FOR IT TO DISAPPEAR
	JMS I	(WRITE1)	/GO WRITE FIRST REGISTER
	JMS I	(WRITE2)	/GO WRITE SECOND REGISTER
LODLUP,	TAD	(777)		/GET SOME MAGIC VALUE
	JMS I	(LOADATA)	/LOAD IT IN AS DATA
	ISZ	COUNT		/DONE ENOUGH?
	JMP	LODLUP		/NO, KEEP GOING
	JMP I	(SBOOT)		/YES, GO BACK TO THE SYSTEM

	PAGE
WRITE1,	.-.			/LOAD FIRST WRITE CONTROL REGISTER ROUTINE
	JMS	SYNC		/WAIT FOR SYNC CONDITION
	TAD	W1VAL1		/GET LOW-ORDER VALUE
	TAD	W1VAL2		/GET HIGH-ORDER VALUE
	GRW1			/WRITE IT OUT NOW
	CLA			/CLEAN UP
	JMP I	WRITE1		/RETURN

WRITE2,	.-.			/LOAD SECOND WRITE CONTROL REGISTER ROUTINE
	JMS	SYNC		/WAIT FOR SYNC CONDITION
	TAD	W2VAL		/GET VALUE
	GRW2			/WRITE IT OUT NOW
	CLA			/CLEAN UP
	JMP I	WRITE2		/RETURN

SYNC,	.-.			/SYNC ROUTINE
	CLA			/JUST IN CASE
	DCA	WASTE		/CLEAR COUNTER
	ISZ	WASTE		/DONE YET?
	JMP	.-1		/NO, WAIT FOR IT
SYNCLUP,GRGR			/READ THE REGISTER
	AND	(14)		/JUST IMPORTANT BITS
	TAD	(-4)		/COMPARE TO EXPECTED VALUE
	SZA CLA			/SKIP IF IT MATCHES
	JMP	SYNCLUP		/JUMP IF NOT THERE YET
	JMP I	SYNC		/RETURN

LOADATA,.-.			/DATA LOADING ROUTINE
	AND	(777)		/JUST IN CASE
	DCA	LODTEMP		/SAVE FOR NOW
	GRGR			/READ THE REGISTER
	RTR			/MOVE BIT TO LINK
	SZL CLA			/SKIP IF READY TO TAKE DATA
	JMP	.-3		/ELSE KEEP WAITING
	TAD	LODTEMP		/GET THE DATA
	GRGW			/WRITE IT NOW
	CLA			/CLEAN UP
	JMP I	LOADATA		/RETURN

	PAGE