/	PROGRAM TO OUTPUT RAMP WITH A GIVEN SLOPE

/	EQUATED SYMBOLS.

	CLZE=	6130		/ONES CLEAR CLOCK ENABLE REGISTER
	CLSK=	6131		/SKIP ON CLOCK FLAG
	CLOE=	6132		/ONES SET CLOCK ENABLE REGISTER
	CLAB=	6133		/LOAD CLOCK BUFFER, COUNTER
	CLEN=	6134		/CLOCK ENABLE TO AC
	CLSA=	6135		/READ STATUS REGISTER
	CLBA=	6136		/READ BUFFER REGISTER
	CLCA=	6137		/READ CLOCK COUNTER VIA BUFFER REGISTER
	DAL1=	6551		/LOAD X
	DAL2=	6552		/LOAD Y
	NL7777=	CLA CMA		/LOAD AC WITH 7777
	*200			/START AT THE USUAL PLACE

START,	CLA			/CLEAN UP
	DAL1			/CLEARS X
	DAL2			/CLEARS Y
	DCA	DAOUT		/CLEAN UP D/A OUTPUT
	NL7777			/CLEAN UP
	CLZE			/ENABLE REGISTER
	AND	ENABLE		/GET ENABLE VALUE
	CLOE			/LOAD ENABLE REGISTER
	CLA			/CLEAN UP
	TAD	COUNTER		/GET COUNTER
	CLAB			/LOAD BUFFER THEN COUNTER
LUP,	CLSK			/WAIT FOR FLAG
	JMP	.-1		/KEEP WAITING
	CLSA			/READ STATUS AND CLEAR FLAG
	CLA			/CLEAN UP
	TAD	DAOUT		/GET D/A OUTPUT
	DAL1			/OUTPUT IT
	LAS			/READ SWITCHES
	SPA			/SKIP IF >=0
	JMP	GOZERO		/ELSE HEAD TOWARD ZERO
	TAD	DAOUT		/ADD PREVIOUS D/A VALUE
	DCA	DAOUT		/STORE NEW VALUE
	TAD	DAOUT		/GET VALUE BACK
	CIA			/NEGATE
	TAD	VELCOM		/ADD VELOCITY COMMAND
	SMA CLA			/SKIP IF TOO FAR
	JMP	LUP		/KEEP GOING
	TAD	VELCOM		/GET VELOCITY COMMAND
	DCA	DAOUT		/PUT IT INTO D/A OUTPUT
	JMP	LUP		/KEEP GOING

GOZERO,	AND	(3777)		/AND OFF POSITIVE BITS
	CIA			/MAKE NEGATIVE
	TAD	DAOUT		/ADD D/A OUTPUT
	DCA	DAOUT		/STORE IT BACK
	TAD	DAOUT		/GET BACK D/A OUTPUT
	SMA SZA CLA		/SKIP IF ZERO
	JMP	LUP		/KEEP GOING
	DCA	DAOUT		/ELSE ZERO D/A OUTPUT
	JMP	LUP		/KEEP GOING

ENABLE,	5610			/ENABLE VALUE
COUNTER,-3100			/1.6 MSEC SAMPLING
VELCOM,	3777			/100 DEG/SEC
DAOUT,	.-.			/BUFFER FOR D/A OUTPUT

	$			/THAT'S ALL FOLK!