*20			/OFFICIAL LOADING ADDRESS OF THIS BOOTSTRAP

SBREAD,	TAD	SRXU		/GET CURRENT UNIT^20+DENSITY WORD
	TAD	SGDCON/(360)	/UPDATE TO NEXT CANDIDATE
	AND	SBU/(420)	/KEEP ONLY NEW DENSITY AND UNIT BITS
	DCA	SRXU		/STORE BACK
SRBOOT,	NL0006	/TAD S6	/TAD S46/SET AC TO SIX
	TAD	SRXU		/ADD ON DENSITY AND UNIT BITS
	LCD			/LOAD "READ SECTOR" COMMAND
	CLA CLL IAC		/SET AC TO ONE AND CLEAR LINK
	JMS	SLODE		/ASK FOR SECTOR ONE
	JMS	SLODE		/ASK FOR TRACK ONE
SRAL,	RAL			/AC NOW 0002
SHANGG,	SDN			/BOOTSTRAP STARTS HERE; DONE FLAG UP?
	JMP	SLODE1		/NO, TRY TRANSFER FLAG
	SER			/SKIP IF ANY ERRORS
	SNA			/FIRST TIME THROUGH?
	JMP	SBREAD		/JUMP IF FIRST TIME THROUGH OR ERRORS
	TAD	SRXU		/GET CURRENT DENSITY SETTING; UNIT IS IGNORED
	LCD			/LOAD "EMPTY SECTOR" COMMAND
	TAD	SRXU		/GET GOOD DRIVE
S46,	AND	SGDCON/(360)	/REMOVE DENSITY BIT
	TAD	SRAL/(RAL)	/ADD ON "RAL" INSTRUCTION
	DCA	SBU		/STORE FOR COMPATIBILIY WITH RX01 ONLY BOOTSTRAP
SGDCON,	0360			/CONSTANT 0360
SLP,	JMS	SLODE		/GET A WORD
SLPSTR,	DCA	SBOOT&177+2	/PUT A WORD
	ISZ	SLPSTR		/PUT TO NEXT
	JMP	SLP		/KEEP GOING UNTIL OVERLAYED

/	THE FOLLOWING WORDS ARE NEVER OVERLAYED. ALL OPERATING SYSTEMS PRIMARY
/	BOOTSTRAP BLOCKS MUST ASSUME THEIR PRESENCE IN ORDER TO LOAD AT ALL.
/	DEPENDENCE ON THESE WORDS PREVENTS SIGNIFICENT IMPROVEMENT OR ALTERATION
/	OF THE BOOTSTRAP CONVENTION IN THE FUTURE.

SLODE,	.-.			/LOAD A WORD ROUTINE
SLODE1,	STR			/TRANSFER FLAG UP?
	JMP	SHANGG		/NO, BUT DONE FLAG MAY BE UP
	XDR			/DO TRANSFER IN PREVAILING DIRECTION
	JMP I	SLODE		/RETURN

SBU,	0420			/DENSITY AND UNIT MASK
				/WILL BE UNIT^20+7004 ON SUCCESSFULL BOOT
SRXU,	0020			/WILL BE UNIT^20+DENSITY^400 ON SUCCESSFULL BOOT