/SCREEN ALLIGNMENT DISPLAY.
/THIS IS AN IMAGE FILE SO THAT WHEN GRAPHICS BECOMES AVAILABLE IT
/CAN BE MODIFIED TO PUT UP THE PROPER SCREEN ALLIGNMENT PATTERN.
/
CALL=JMS 20
/SCREEN ALLIGNMENT PATTERN FOR COLOR MONITOR
/

PRIM=	200
PRMFLD=	30		/PRIMATIVES IN FIELD 3
/ ----- EQUATES -----
/
CALL=	JMS	20	/LINKS TO EXECUTIVE.

AC0001=	7301
AC0002=	7305
AC0003=	7325
AC0004=	7307
AC0010=	7315
AC0100=	7303
AC3777=	7350
AC7776=	7344
AC7777=	7340
/
R3L=	7014
PR3=	6236
SPF=	6040
/
GRDR=	6150		/GRAPHICS OPTION DMA READ
GRDW=	6151		/GRAPHICS OPTION DMA WRITE
GRGR=	6154		/GRAPHICS OPTION GDC READ
GRGW=	6155		/GRAPHICS OPTION GDC WRITE
GRW1=	6156		/GRAPHICS OPTION WRITE REGISTER ONE
GRW2=	6157		/GRAPHICS OPTION WRITE REGISTER TWO
/
/ ----- END EQUATES -----
DECIMAL
SETUP=	34
OCTAL



*30
DECIMAL

PBLOCK,	1		/POSITION COMMAND
PXPOS,	0		/X POSITION
PYPOS,	0		/Y POSITION

VBLOCK,	4		/VECTOR COMMAND
VXPOS,	0		/X POSITION
VYPOS,	0		/Y POSITION

INIBLK,	29		/INIT COMMAND TO PRIMATIVES.
STCMD,	0

OCTAL

LINCNT,	0
FUNC,	0


*200

START,	DCA	MODE		/SEE WHICH MODE IT IS
	CLL CLA
	TAD	MODE		/FIND OUT WHAT THE MOdE IS
	SNA CLA			/SKIP IF ALIGNMENT MODE
	JMP	SCRN1		/SET UP BLANK SCREEN
	TAD	(400		/
	GRGW
	DCA	10
	ISZ	10
	JMP	.-1
	GRGR
	AND	(7634
	TAD	(-7004
	SNA CLA			/SKIP IF NO GRAPHICS BOARD
	JMP	DOGRPH		/ESTABLISH THE WORKING PARAMETERS FOR THE
				/GRAPHICS BOARD FOR SCREEN ALLIGNMENT.
	
	TAD	(ALIGN
	SKP
SCRN1,	TAD	(CUROFF
	JMS	SNDSCR		/SEND THE PROPER COMMAND TO THE SCREEN
	KSF			/ANY KEY GETS US OUT.
	JMP	.-1		/WAIT FOR A KEY 
	6030			/RESET THE FLAG
SCREXT,	JMS	MESAGE
	RIS			/TO A RESET
	STA			/MARK THE CALL TO EXIT BACK TO FIELD
				/SERVICE MENU.
	CALL
	20			/EXIT
	HLT			/SHOULD NOT GET HERE

MODE,	0			/ZERO FOR BLANK SCREEN
				/NON ZERO FOR NORMAL ALIGNMENT PATTERN

MESAGE,	0
	TAD I	MESAGE		/GET THE MESSAGE POINTER
	DCA	MESTMP		/AND SAVE IT AWAY
	ISZ	MESAGE
MESLP,	TAD I	MESTMP		/GET A CHARACTER
	SNA
	JMP I	MESAGE		/EXIT
	JMS	TYPE		/TYPE IT OUT
	ISZ	MESTMP
	JMP	MESLP		/AND DO IT AGAIN

MESTMP,	0

TYPE,	0
	TLS
	TSF
	JMP	.-1
	CLA
	JMP I	TYPE


PAGE
/
/A GRAPHICS BOARD IS PRESENT. DISPLAY THE MENU AND DETERMINE THE FUNCTION.
/

DOGRPH,	TAD	(STCMD		/START THE PRIMATIVES

	CIF	PRMFLD		/TO THE PRIMATIVES FOR INIT
	JMS	PRIM		/START THE CODE
	TAD	(INIBLK		/INIT COMMAND TO PRIMATIVES. RESET TO DEFAULT
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	TAD	(TXTON		/TEXT TO COLOR AND MONCHROME
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	
	CALL
	2
	ALLIGN			/DISPLAY THE ALLIGNMENT MENU FOR FIELD SERVICE
	SZA CLA			/SKIP IF NO ERROR ON READ. 
	HLT			/FOR NOW
	CALL
	12			/DISPLAY MENU AND GET A REPSONSE
	SNA			/SKIP IF VALID RESPONSE
	HLT			/SHOULD NEVER GET HERE
	TAD	(FNCTAB		/FUNCTION TABLE
	DCA	FUNC		/SAVE THE FUNCTION
	TAD I	FUNC
	DCA	FUNC
	JMS I	FUNC		/PERFORM THE DESIRED FUNCTION
	JMP	DOGRPH		/AND DO IT ALL OVER AGAIN.

EXALGN,	0
	JMS	CLR241
	TAD	(TXTON		/TEXT TO BOTH
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	JMP	SCREXT		/EXIT BACK TO EXECUTIVE.
		
/
/SEND A STREAM OF DATA TO THE FIRMWARE
/

SNDSCR,	0
	DCA	SCRPAT		/SAVE THE SCREEN PATTERN
	CALL
	5
	SCREEN			/READ THE SCREEN ALLIGNMENT INSTRUCTIONS
	SZA CLA			/SKIP IF NO ERROR.
	JMP	SCREXT		/SCREEN ALLINMENT EXIT
	JMS	MESAGE		/PUT UP THE SCREEN ALLIGNMENT
SCRPAT,	ALIGN			/REVERSE SCREEN AND PATTERN
	JMP I	SNDSCR		/EXIT ROUTINE AND DIPSLAY MENU IF NEED BE.

FNCTAB,	0
	DOCOLR			/COLOR SELECTIONS MENU
	DOALGN			/ALLIGNMENT PATTERN
	EXALGN			/EXIT THIS PORTION OF THE STUFF AND GO
				/BACK TO THE PREVIOUS MENU.
/
/DO THE SCREEN ALIGNMENT PATTERN
/

DOALGN,	0
	TAD	(TXTOFF		/TEXT TO MONCHROME ONLY
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	TAD	(ALIGN
	JMS	SNDSCR		/VR201 PATTERN
	JMS	VR241		/AND THE VR241 PATTERN
	KSF
	JMP	.-1
	KRB			/WAIT FOR THE KEYBOARD.
	JMS	CLR241		/CLEAR GRAPHICS BOARD.
	JMS	MESAGE
	RIS			/TO A RESET
	TAD	(TXTON		/TEXT TO BOTH
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	JMP I	DOALGN		/AND EXIT

/
/COLOR SELECTIONS MENU.
/

DOCOLR,	0
	CALL
	2
	COLOR			/READ COLOR SELECTIONS MENU
	SZA CLA			/SKIP IF NO ERROR ON READ. 
	HLT			/FOR NOW
DOCOL1,	CALL
	12			/DISPLAY MENU AND GET A REPSONSE
	SNA			/SKIP IF VALID RESPONSE
	HLT			/SHOULD NEVER GET HERE
	TAD	(CLRTAB		/COLOR TABLE ADDRESS
	DCA	FUNC
	TAD I	FUNC		/COLOR SELECTIONS FUNCTION
	DCA	FUNC
	TAD	(TXTOFF		/TEXT TO MONCHROME ONLY
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	JMS I	FUNC
	KSF
	JMP	.-1		/WAIT FOR A KEY TO BE STRUCK
	KRB
	CLA
	JMS	CLR241
	TAD	(TXTON		/TEXT TO BOTH
	CIF	PRMFLD
	JMS	PRIM		/DO IT.
	JMP	DOCOL1		/AND DO IT AGAIN

ENDCLR,	0
	CLL CLA			/RESET TO BLACK
	JMS	SETBAC		/SET BACKGROUND COLOR
	JMP I	DOCOLR		/AND EXIT BACK TO WHERE YOU CAME FROM


PAGE

/
/COLOR DISPLAY ROUTINES
/
/
/CLEAR THE VR241 MONITOR
/

DARK,	0
	JMS	SETBAC		/BACKGROUND OT BLACK
	JMP I	DARK

BLUE,	0
	TAD	(1		/BACKGROUND TO BLUE
	JMS	SETBAC
	JMP I	BLUE

	
RED,	0
	TAD	(2		/BACKGROUND TO RED
	JMS	SETBAC
	JMP I	RED

MAGENT,	0
	TAD	(3		/BACKGROUND TO MAGENTA
	JMS	SETBAC
	JMP I	MAGENT

GREEN,	0
	TAD	(4		/BACKGORUND TO GREEN
	JMS	SETBAC
	JMP I	GREEN

CYAN,	0
	TAD	(5		/BACKGROUND TO CYAN
	JMS	SETBAC
	JMP I	CYAN

YELLOW,	0
	TAD	(6		/BACKGROUND TO YELLOW
	JMS	SETBAC
	JMP I	YELLOW

WHITE,	0
	TAD	(7
	JMS	SETBAC
	JMP I	WHITE

COLBAR,	0			/DISPLAY COLOR BARS ON THE VR241
	CLL CLA
	JMS	SETBAC		/BACKGROUND TO BLACK
	DCA	PXPOS
	DCA	PYPOS
	TAD	(144		/START VECTOR TO 100
	DCA	VXPOS
	DCA	VYPOS		/AND 0 FOR Y
	TAD	(PBLOCK		/POSITION TO HOME
	CIF	PRMFLD
	JMS	PRIM
	TAD	(10		/TURN ON THE INTENSITY PLANE
	DCA	BARCLR		/STARTING BAR COLOR.
	TAD	(-10		/FOR 8 COLORS.
	DCA	LINCNT		/NUMBER OF BARS TO DO
	TAD	(SHADE		/SHADING ON
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM

COLBR1,	TAD	(CLRBLK
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM
	TAD	(VBLOCK		/VECTOR BLOCK
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM
	TAD	VXPOS
	TAD	(144
	DCA	VXPOS
	ISZ	BARCLR
	ISZ	LINCNT		/LOOP COUNTER
	JMP	COLBR1
	TAD	(SHDOFF
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM
	JMP I	COLBAR		/AND EXIT


/
/SET UP THE BACKGROUND COLOR DEFINED BY AC.
/

SETBAC,	0
	TAD	(10		/AND THE INTENSITY PLANE
	AND	(17
	DCA	BACCLR		/SET BACKGROUND COLOR
	TAD	(BACSET		/COMMAND TO PRIMATIVES.
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM
	TAD	(SCRERA		/SCREEN ERASE TO PRIMATIVES.
	CIF	PRMFLD		/SET FOREGROUND COLOR
	JMS	PRIM
	JMP I	SETBAC		/AND EXIT


CLR241,	0
	TAD	(10		/NORMAL BACKGROUND COLOR.
	JMS	SETBAC		/BACKGROUND OT BLACK
	JMP I	CLR241

/
/PRIMATIVE FUNCTION CALLS
/

DECIMAL
SHDOFF,	13

SHADE,	12
	479
	0
	
BACSET,	8
BACCLR,	0

SCRERA,	6
			

CLRBLK,	9
BARCLR,	0
OCTAL

TXTON,	SETUP
	4

TXTOFF,	SETUP
	0

PAGE

VR241,	0
	CLL CLA
	DCA	PXPOS
	DCA	PYPOS
	TAD	(PBLOCK
	CIF	PRMFLD
	JMS	PRIM		/HOME THE CURSOR
	TAD	(BORDER-1	/SET UP THE BOARDER OF DISPLAY
	DCA	10
BRD1,	TAD I	10		/LOOP UNTIL VALUE IN AC IS NEGATIVE
	SPA			/SKIP IF NOT DONE
	JMP	HATCH		/GO DO THE CROSS HATCH PATTERN
	DCA	VXPOS
	TAD I	10
	DCA	VYPOS		
	TAD	(VBLOCK		/VECTOR COMMAND
	CIF	PRMFLD
	JMS	PRIM		/GO DO IT
	JMP	BRD1

HATCH,	CLL CLA
	TAD	(62		/START AT 52
	DCA	PXPOS
	TAD	(54		/44
	DCA	PYPOS
	TAD	(1353		/ENDING POSITION
	DCA	VXPOS
	TAD	(54		/44
	DCA	VYPOS
	TAD	(-23		/NEED 19 LINES
	DCA	LINCNT		/NUMBER OF LINES TO DO.

HATCH1,	TAD	(PBLOCK
	CIF	PRMFLD
	JMS	PRIM		/STARTING POSITION
	TAD	(VBLOCK
	CIF	PRMFLD
	JMS	PRIM
	TAD	(26		/+22
	TAD	PYPOS
	DCA	PYPOS
	TAD	(26
	TAD	VYPOS
	DCA	VYPOS
	ISZ	LINCNT
	JMP	HATCH1
/
/NOW PUT UP THE VERTICLE LINES.
/
HATCH2,	CLL CLA
	TAD	(62		/START AT 
	DCA	PXPOS
	TAD	(54		/44
	DCA	PYPOS
	TAD	(62		/ENDING POSITION
	DCA	VXPOS
	TAD	(664		/
	DCA	VYPOS
	TAD	(-36		/NEED 30 LINES
	DCA	LINCNT		/NUMBER OF LINES TO DO.

HATCH3,	TAD	(PBLOCK
	CIF	PRMFLD
	JMS	PRIM		/STARTING POSITION
	TAD	(VBLOCK
	CIF	PRMFLD
	JMS	PRIM
	TAD	(30
	TAD	PXPOS
	DCA	PXPOS
	TAD	(30
	TAD	VXPOS
	DCA	VXPOS
	ISZ	LINCNT
	JMP	HATCH3

DOCIR,	TAD	(CIRCLE-1
	DCA	10
DOCIR2,	TAD I	10
	SPA
	JMP	DOCIR3
	CIF	PRMFLD
	JMS	PRIM
	JMP	DOCIR2

DOCIR3,	CLL CLA
	JMP I	VR241


PAGE

DECIMAL
BORDER,	799
	0
	799
	479
	0
	479
	0
	0
	-1


CIR1,	1
	400
	430

CIR2,	12
	240		/LINE SPECIFIER
	0

CIR3,	15
	400
	242
	360

CIR4,	1
	400
	240

CIR5,	13

CIR6,	9
	0

CIR7,	1
	260
	138

CIR8,	4
	540
	138

CIR9,	4
	540
	343

CIR10,	4
	260
	343

CIR11,	4
	260
	138

CIR12,	1
	356
	200

CIR13,	12
	280
	0

CIR14,	4
	444
	200

CIR15,	13
OCTAL

CIRCLE,	CIR1
	CIR2
	CIR3
	CIR4
	CIR5
	CIR6
	CIR7
	CIR8
	CIR9
	CIR10
	CIR11
	CIR12
	CIR13
	CIR14
	CIR15
	-1


SCREEN,	FILENAME SCREEN.IN
ALLIGN,	FILENAME ALIGN.MU
COLOR,	FILENAME COLOR.MU

RIS,	33; 143; 0
ALIGN,	33; 133; 77; 65; 150; 33; "#&177; 70; 0
CUROFF,	33; 133; 77; 62; 65; 154; 33; 133; 77; 65; 154; 33; 133; 62; "J&177; 0

CLRTAB,	0
	DARK
	BLUE
	RED
	MAGENT
	GREEN
	CYAN
	YELLOW
	WHITE
	COLBAR		/COLOR BARS.

	ENDCLR		/ALL DONE