100 PFFPTR,	.-.				/FIXED FILE INSERTION POINTER
 110 FLSMSG,	TEXT	" ^F^ILES^"
 120 
 130 	PAGE
 140 	EJECT
 150 /	INITIALIZATION STARTS HERE.
 160 
 170 INITIAL,TAD I	(SBTFUN)	/GET BOOTSTRAP FUNCTION WORD
 180 	AND	[7]		/JUST UNIT BITS
 190 	TAD	[DOLBLK]	/ADD ON "$" BLOCK NUMBER
 200 	DCA I	(PFFDOLLAR)	/STORE IN INITIALIZE CODE
 210 	TAD I	[SBOOT]		/GET BOOTSTRAP INSTRUCTION
 220 	TAD	(-JMSSYSIO)	/COMPARE TO POSSIBLE VALUE
 230 	SNA CLA			/SKIP IF DIFFERENT
 240 	JMP	CHKCOVERLAY	/JUMP IF IT MATCHES
 250 	ISZ	CHKKRS		/TURN "KRSIOT"
 260 	ISZ	CHKKRS		/INTO "KRBIOT"
 270 	DCA	CHKKCC		/DESTROY "KCCIOT"
 280 CHKCOVR,NL0002			/SETUP "C" BIT MASK
 290 	AND I	[SCRSIZE]	/GET THE "C" BIT
 300 	SNA CLA			/SKIP IF CONSOLE OVERLAY PRESENT
 310 	JMP	ANNOUNCE	/JUMP IF NOT
 320 	TAD I	[SCRSIZE]	/GET THE CORE SIZE WORD
 330 	RTR;RAR			/MOVE OVER AND
 340 	AND	(70)		/ISOLATE MCS BITS
 350 	TAD	(CIF	10)	/TURN INTO CIF MCS+10
 360 	DCA	P7TSF		/STORE OVER "TSFIOT"
 370 	TAD	P7JMP		/GET "JMP P7AGN"
 380 	DCA	P7TLS		/STORE OVER "TLSIOT"
 390 	TAD	(JMS	OUTCON)	/GET OUTPUT CALL INSTRUCTION
 400 	DCA	P7JMP		/STORE OVER "JMP P7AGN"
 410 	TAD	P7TSF		/GET "CIF MCS+10" AGAIN
 420 	DCA	CHKKSF		/STORE OVER "KSFIOT"
 430 	TAD	CHKJMP		/GET "JMP I CTLCTST"
 440 	DCA	CHKKRS		/STORE OVER "KRSIOT" (OR "KRBIOT")
 450 	TAD	(JMS	INCON)	/GET INPUT CALL INSTRUCTION
 460 	DCA	CHKJMP		/STORE OVER "JMP I CTLCTST"
 470 	DCA	CHKKCC		/DESTROY "KCCIOT"
 480 ANNOUNC,JMS I	[SCRIBE]	/TELL THEM
 490 	ANNMSG			/WE HAVE ARRIVED
 500 	TAD I	FILPTR		/GET FIRST FILE ARGUMENT
 510 	SNA CLA			/SKIP IF SOMETHING THERE
 520 	JMP	NOFILES		/ELSE COMPLAIN
 530 	TAD I	(SOUTFLS)	/GET OUTPUT FILE COUNT
 540 	SNA			/SKIP IF SOME OUTPUT FILES PASSED
 550 	JMP 	NOOUTFILES	/JUMP IF NOT
 560 	TAD	FILPTR		/POINT AT END OF OUTPUT LIST
 570 	DCA	P7TEMP		/STASH THE POINTER
 580 	TAD I	P7TEMP		/GET THE DELIMITER
 590 	SZA CLA			/SKIP IF ACTUAL END OF LIST
 600 	JMP	MIXFILES	/ELSE COMPLAIN OF MIXED FILES
 610 	EJECT
 620 	TAD I	(SWMX)		/GET /M-/X SWITCHES
 630 	AND	(10)		/JUST /U BIT
 640 	SNA CLA			/SKIP IF SET
 650 	JMP I	(MEMIN)		/ELSE GO START IT UP
 660 	TAD	L7600/[CLA!400]	/GET A "CLA" INSTRUCTION
 670 	DCA I	(CASZP1)	/PREVENT CASE CHANGE
 680 	TAD	L7600/[CLA!400]	/GET A "CLA" INSTRUCTION
 690 	DCA I	(CASZP2)	/PREVENT CASE CHANGE
 700 	JMP I	(MEMIN)		/GO START IT UP
 710 
 720 MIXFILE,JMS I	[SCRIBE]	/TELL THEM
 730 	MFLMSG			/OF MIXED FILES
 740 	JMP I	[CREPORT]	/GOODBYE!
 750 
 760 NOFILES,JMS I	[SCRIBE]	/TELL THEM
 770 	NFLMSG			/THEY GOOFED
 780 	JMP I	[CREPORT]	/GOODBYE!
 790 
 800 NOOUTFI,JMS I	[SCRIBE]	/TELL THEM
 810 	NOFMSG			/THEY GOOFED
 820 	JMP I	[CREPORT]	/GOODBYE
 830 
 840 	PAGE
 850 	EJECT
 860 /	ONCE-ONLY TEXT MESSAGES.
 870 
 880 ANNMSG,	TEXT	"^N^ICOLET ^A^VERAGER ^D^ATA ^C^ONVERSION"
 890 CRLF,	TEXT	"%"
 900 MFLMSG,	TEXT	"%^C^ANNOT ^P^ROCESS ^M^IXED ^I^NPUT AND ^O^UTPUT ^F^ILES!%^"
 910 	EJECT
 920 NFLMSG,	TEXT	"%^N^O ^P?S/8 F^ILES ^G^IVEN!%"
 930 NOFMSG,	TEXT	"%^N^O ^P?S/8 O^UTPUT ^F^ILES ^G^IVEN!%^"
 940 
 950 	$			/THAT'S ALL FOLK!