100 /TERMINAL SETUP LOADER
 110 
 120 /TERMINAL SETUP PROGRAM FOR DS-120.
 130 
 140 /	LAST EDIT:	05-MAY-1984	18:00:00	CJL
 150 
 160 /	DEFINITIONS.
 170 
 180 	SBOOT=	7600		/MONITOR EXIT HERE
 190 	TLSIOT=	6046		/OUTPUT TO TTY:
 200 	TSFIOT=	6041		/SKIP ON TTY: DONE FLAG
 210 	XR1=	10		/AUTO-INDEX REGISTER
 220 
 230 	*200			/AS USUAL
 240 
 250 TABLOD,	TSFIOT			/FLAG UP?
 260 	TLSIOT			/NO, SET IT
 270 	JMS	CRLF		/DO A <CR>, <LF>
 280 	TAD	("H&177)	/GET AN "H"
 290 	JMS	ESCSEND		/SEND <ESC> H
 300 	TAD	(-20)		/SETUP THE
 310 	DCA	TABCNT		/TAB COUNTER
 320 TABLUP,	TAD	(-10)		/SETUP THE
 330 	DCA	SPCNTR		/SPACE COUNTER
 340 SPCLUP,	TAD	(" &177)	/GET A SPACE
 350 	JMS	OUTPUT		/SEND IT
 360 	ISZ	SPCNTR		/DONE A COMPLETE TAB ZONE?
 370 	JMP	SPCLUP		/NO, KEEP GOING
 380 	TAD	("1&177)	/GET A "1"
 390 	JMS	ESCSEND		/SEND <ESC> 1
 400 	ISZ	TABCNT		/DONE ALL TAB ZONES?
 410 	JMP	TABLUP		/NO, KEEP GOING
 420 	TAD	("O&177)	/GET AN "O"
 430 	JMS	ESCSEND		/SEND <ESC> O
 440 	TAD	("3&177)	/GET A "3"
 450 	JMS	OUTPUT		/OUTPUT IT
 460 	TAD	("4&177)	/GET A "4"
 470 	JMS	OUTPUT		/OUTPUT IT
 480 	TAD	("G&177)	/GET A "G"
 490 	JMS	ESCSEND		/SEND <ESC> G
 500 	TAD	("C&177)	/GET A "C"
 510 	JMS	ESCSEND		/SEND <ESC> C
 520 	TAD	("1&177)	/GET A "1"
 530 	JMS	OUTPUT		/OUTPUT IT
 540 	TAD	(TABL1-1)	/GET LIST POINTER
 550 	JMS	STSEND		/SEND BIT STRING
 560 	TAD	("C&177)	/GET A "C"
 570 	JMS	ESCSEND		/SEND <ESC> C
 580 	TAD	("A-1&177)	/GET AN <AT-SIGN>
 590 	JMS	OUTPUT		/OUTPUT IT
 600 	TAD	(TABL2-1)	/GET LIST POINTER
 610 	JMS	STSEND		/SEND BIT STRING
 620 	TAD	("I&177)	/GET AN "I"
 630 	JMS	ESCSEND		/SEND <ESC> I
 640 	JMP I	(SBOOT)		/EXIT TO MONITOR
 650 	EJECT
 660 CRLF,	.-.			/<CR>, <LF> ROUTINE
 670 	TAD	(15)		/GET A <CR>
 680 	JMS	OUTPUT		/OUTPUT IT
 690 	TAD	(12)		/GET A <LF>
 700 	JMS	OUTPUT		/OUTPUT IT
 710 	JMP I	CRLF		/RETURN
 720 
 730 OUTPUT,	.-.			/OUTPUT ROUTINE
 740 	TSFIOT			/FLAG UP?
 750 	JMP	.-1		/NO, WAIT FOR IT
 760 	TLSIOT			/YES, SEND NEXT CHARACTER
 770 	CLA			/CLEAN UP
 780 	JMP I	OUTPUT		/RETURN
 790 
 800 ESCSEND,.-.			/SEND <ESC> AND PASSED CHARACTER ROUTINE
 810 	DCA	ESCTMP		/SAVE PASSED CHARACTER
 820 	TAD	(33)		/GET AN <ESC>
 830 	JMS	OUTPUT		/OUTPUT IT
 840 	TAD	ESCTMP		/GET THE PASSED CHARACTER
 850 	JMS	OUTPUT		/OUTPUT IT
 860 	JMP I	ESCSEND		/RETURN
 870 
 880 STSEND,	.-.			/STRING SEND ROUTINE
 890 	DCA	XR1		/SAVE PASSED POINTER
 900 STLOOP,	TAD I	XR1		/GET A CHARACTER
 910 	SPA			/SKIP IF STILL IN MESSAGE
 920 	JMP	STEXIT		/JUMP IF DELIMITER
 930 	TAD	("0&177)	/CONVERT TO ASCII
 940 	JMS	OUTPUT		/OUTPUT THE CHARACTER
 950 	JMP	STLOOP		/KEEP GOING
 960 
 970 STEXIT,	CLA			/CLEAN UP
 980 	JMP I	STSEND		/RETURN
 990 
1000 ESCTMP,	.-.			/TEMPORARY
1010 SPCNTR,	.-.			/TEMPORARY
1020 TABCNT,	.-.			/TEMPORARY
1030 
1040 	PAGE
1050 	EJECT
1060 /	CHARACTER PATTERN TABLES.
1070 
1080 	DECIMAL
1090 
1100 TABL1,	0;8;1;4;2;2;4;1;5;5;4;1;4;1;-1
1110 TABL2,	1;4;2;2;4;5;4;9;5;1;2;2;1;4;-1