100 PRFREQ,	TAD	BEGINX		/GET BEGIN X VALUE
 110 	JMS I	[EVLPRT]	/PRINT IT
 120 	TAD	BEGINY		/GET BEGIN Y VALUE
 130 	JMS I	[EVLPRT]	/PRINT IT
 140 	TAD	ENDX		/GET END X VALUE
 150 	JMS I	[EVLPRT]	/PRINT IT
 160 	TAD	ENDY		/GET END Y VALUE
 170 	JMS I	[EVLPRT]	/PRINT IT
 180 	PRTIME;	MENPTR;MBGPTR	/PRINT MOVEMENT LENGTH
 190 	JMS I	[TABPRT]	/PRINT A <TAB>
 200 	XLIST	OFF
 210 	IFNZRO	BLKPRT	<
 220 	XLIST	ON
 230 	TAD	BVALUE		/GET BLINK VALUE
 240 	AND	[BLINK]		/JUST BLINK BIT
 250 	CLL RTL			/MOVE TO
 260 	RTL			/AC[11]
 270 	TAD	["0&77]		/MAKE IT ASCII
 280 	JMS I	[P6CH]		/PRINT IT
 290 	XLIST	OFF	>
 300 	XLIST	ON
 310 	JMS I	[P6CH]		/PRINT A <CR>, <LF>
 320 	STA			/INDICATE FRACTIONAL CORRECTION
 330 	PRTIME;	OFPTR2;OLFPTR	/PRINT BURST LENGTH
 340 	JMS I	[TABPRT]	/AND A <TAB>
 350 	TAD	SPKCNT		/GET SPIKE COUNT
 360 	JMS I	[PRTVAL]	/GO PRINT IT
 370 	JMS I	[TABPRT]	/PRINT A <TAB>
 380 	PRTIME;	MBGPTR;OLFPTR	/PRINT BURST-MOVEMENT TIME
 390 	JMS I	[P6CH]		/PRINT A <CR>, <LF>
 400 	JMP I	(NEXT)		/GO GET ANOTHER SET
 410 	XLIST	OFF		>
 420 	EJECT
 430 	XLIST	ON
 440 
 450 	PAGE
 460 	EJECT
 470 XMOVE,	.-.			/MOVE ROUTINE
 480 	CLA			/CLEAN UP
 490 	TAD I	XMOVE		/GET "FROM" ADDRESS
 500 	DCA	.+6		/SAVE IT INLINE
 510 	ISZ	XMOVE		/BUMP TO NEXT
 520 	TAD I	XMOVE		/GET "TO" ADDRESS
 530 	DCA	.+5		/SAVE INLINE
 540 	ISZ	XMOVE		/BUMP TO RETURN
 550 	DLD;	.-.		/GET A PAIR
 560 	DST;	.-.		/PUT A PAIR
 570 	CAM			/CLEAR OUT
 580 	JMP I	XMOVE		/RETURN
 590 
 600 XLOAD,	.-.			/LOAD A WORD ROUTINE
 610 	CLA			/CLEAN UP
 620 	TAD I	XLOAD		/GET PASSED ARGUMENT
 630 	ISZ	XLOAD		/BUMP AROUND IT
 640 	DCA	TEMP2		/SAVE AS POINTER TO WORD POINTERS
 650 	TAD I	TEMP2		/GET WORD ADDRESS
 660 	DCA	TEMP1		/SAVE IT
 670 	ISZ	TEMP2		/BUMP TO GROUP WORD
 680 	TAD I	TEMP2		/GET GROUP
 690 	CLL RTL			/MAKE INTO
 700 	RTL			/BLOCK
 710 	RAL			/NUMBER
 720 	DCA	TEMP2		/SAVE IT
 730 	TAD	CORGRP		/\
 740 	CIA			/ >COMPARE DESIRED GROUP TO CURRENT GROUP
 750 	TAD	TEMP2		//
 760 	SNA			/SKIP IF DIFFERENT
 770 	JMP	INCORE		/JUMP IF SAME
 780 	TAD	CORGRP		/UPDATE
 790 	DCA	CORGRP		/IN CORE GROUP
 800 	CLL			/CLEAR LINK FOR TEST
 810 	TAD	CORGRP		/GET REQUESTED GROUP
 820 	TAD	BLIMIT		/COMPARE TO LIMIT
 830 	SZL CLA			/SKIP IF OK
 840 	XLIST	OFF
 850 	IFNZRO	FILE	<
 860 	XLIST	ON
 870 	JMP I	[FLCLOS]	/FORGET IT
 880 	XLIST	OFF	>
 890 	IFZERO FILE	<
 900 	XLIST	ON
 910 	JMP I	[FILXT2]	/FORGET IT
 920 	XLIST	OFF	>
 930 	XLIST	ON
 940 	JMS I	[SYSIO]		/\
 950 	0			/ \READ IN
 960 	10+UNIT			/ /NEW GROUP
 970 CORGRP,	0			//
 980 INCORE,	CDF	10		/\
 990 	TAD I	TEMP1		/ >GET THE WORD
1000 	CDF	00		//
1010 	JMP I	XLOAD		/RETURN
1020 	EJECT
1030 TIMPRT,	.-.			/PRINT TIME DIFFERENCES
1040 	DCA	FIND1		/SAVE EXACTNESS INDICATOR
1050 	TAD I	TIMPRT		/GET FIRST ARGUMENT
1060 	DCA	TIM1		/SAVE AS POINTER
1070 	ISZ	TIMPRT		/BUMP TO NEXT
1080 	TAD I	TIMPRT		/GET SECOND ARGUMENT
1090 	DCA	TIM2		/SAVE AS POINTER
1100 	ISZ	TIMPRT		/BUMP PAST
1110 	MQL			/CLEAR MQ NOW
1120 	ISZ	FIND1		/EXACT PRINTOUT REQUIRED?
1130 	JMP	REGPRT		/NO
1140 	NL0002			/GET OFFSET
1150 	TAD	TIM1		/NOW HAVE FIRST FRACTION ADDRESS
1160 	DCA	TIM3		/STASH IT
1170 	NL0002			/GET OFFSET
1180 	TAD	TIM2		/NOW HAVE SECOND FRACTION ADDRESS
1190 	DCA	TIM4		/STASH IT
1200 	DLD;	TIM4,	.-.	/GET SECOND FRACTION
1210 	DCM			/INVERT
1220 	DAD;	TIM3,	.-.	/NOW HAVE DIFFERENCE
1230 REGPRT,	DST;	TIMTMP		/SAVE FRACTIONAL DIFFERENCE
1240 	DLD;	TIM2,	.-.	/GET SECOND MAJOR PORTION
1250 	DCM			/INVERT
1260 	DAD;	TIM1,	.-.	/ADD ON FIRST MAJOR PORTION
1270 	XLIST	OFF
1280 	IFNZRO	CHAN		<
1290 	IFZERO	EAESET	<
1300 	XLIST	ON
1310 	SHL;	3-1		/*8
1320 	XLIST	OFF	>
1330 	IFNZRO	EAESET	<
1340 	XLIST	ON
1350 	SHL;	3		/*8
1360 	XLIST	OFF	>	>
1370 	IFZERO	CHAN		<
1380 	IFZERO	EAESET	<
1390 	XLIST	ON
1400 	SHL;	2-1		/*4