100 GETSY,	JMS	MODNXT		/GET THE NEXT CHARACTER
 110 	AND	(300)		/JUST RANGE BITS
 120 	TAD	(-100)		/COMPARE TO DESIRED COMBINATION
 130 	SZA CLA			/SKIP IF OK
 140 	JMP	GOTBAD		/BARF
 150 	TAD	MTEMP		/GET THE CHARACTER
 160 	TAD	(-124)		/COMPARE TO LEGAL VALUE
 170 	SMA CLA			/SKIP IF OK
 180 	JMP	GOTBAD		/BARF
 190 	TAD	MTEMP		/GET THE CHARACTER
 200 	AND	(77)		/JUST POSITION BITS
 210 	DCA	YPOS2		/SAVE AS SECOND "Y" POSITION
 220 	TAD	XTEMP		/GET PREVIOUS POSITION
 230 	DCA	XPOS2		/SAVE AS SECOND "X" POSITION
 240 	JMP I	(GETTX)		/CONTINUE THERE
 250 
 260 TM1,	.-.			/TIME
 270 TM2,	.-.			/VALUE
 280 TM3,	.-.			/TEMPORARIES
 290 
 300 	PAGE
 310 	EJECT
 320 GETTX,	JMS	CHK4		/CHECK FOR 300, 242, 210, 220
 330 	SZA CLA			/SKIP IF OK
 340 	JMP I	(GOTBAD)	/BARF
 350 	TAD	MTEMP		/GET THE CHARACTER
 360 	AND	(77)		/JUST POSITION BITS
 370 	DCA	XTEMP		/SAVE FOR LATER
 380 GETTY,	JMS	MODNXT		/GET NEXT CHARACTER
 390 	AND	(300)		/JUST RANGE BITS
 400 	TAD	(-100)		/COMPARE TO DESIRED COMBINATION
 410 	SZA CLA			/SKIP IF IT MATCHES
 420 	JMP I	(GOTBAD)	/BARF
 430 	TAD	MTEMP		/GET THE CHARACTER
 440 	TAD	(-124)		/COMPARE TO LEGAL RANGE
 450 	SMA CLA			/SKIP IF OK
 460 	JMP I	(GOTBAD)	/BARF
 470 	TAD	MTEMP		/GET THE CHARACTER
 480 	AND	(77)		/JUST POSITION BITS
 490 	DCA	YPOS1		/SAVE AS LATEST "Y" POSITION
 500 	TAD	XTEMP		/GET THE PREVIOUS POSITION
 510 	DCA	XPOS1		/SAVE AS LATEST "X" POSITION
 520 	ISZ	POS3SW		/INDICATE THIRD X, Y PRESENT
 530 GETEND,	JMS	CHK4		/CHECK FOR 300, 242, 210, 220
 540 	JMP I	(GOTBAD)	/BARF ON ANYTHING ELSE
 550 
 560 GOT300,	DCA	INTENS		/LIGHT IS DIM NOW
 570 	JMS	MODNXT		/GET NEXT CHARACTER
 580 	TAD	(-204)		/COMPARE TO 204 CODE
 590 	SNA			/SKIP IF DIFFERENT
 600 	JMP I	(GOT204)	/JUMP IF IT MATCHES
 610 	IAC			/COMPARE TO 203 CODE
 620 	SZA CLA			/SKIP IF IT MATCHES
 630 	JMP I	(GOTBAD)	/BARF ON ANY OTHER
 640 GOT203,	ISZ	SUCCESS		/INDICATE SUCCESSFUL TRIAL
 650 	NL4000			/FUDGE TO PREVENT
 660 	DCA	MTEMP		/INVALIDATION
 670 	JMP I	(GOODIN)	/FINISH IT THERE
 680 	EJECT
 690 CHK4,	.-.			/CHECK FOR FOUR CODES ROUTINE
 700 	JMS	MODNXT		/GET NEXT CHARACTER
 710 	TAD	(-300)		/COMPARE TO 300 CODE
 720 	SNA			/SKIP IF DIFFERENT
 730 	JMP	GOT300		/JUMP IF A MATCH
 740 	TAD	(-242+300)	/COMPARE TO 242
 750 	SNA			/SKIP IF DIFFERENT
 760 	JMP I	(GOT242)	/JUMP IF A MATCH
 770 	TAD	(-210+242)	/COMPARE TO 210
 780 	SNA			/SKIP IF DIFFERENT
 790 	JMP I	(GOT210)	/JUMP IF A MATCH
 800 	TAD	(-220+210)	/COMPARE TO 220
 810 	SNA			/SKIP IF DIFFERENT
 820 	JMP I	(GOT220)	/JUMP IF A MATCH
 830 	TAD	(220)		/RESTORE THE CHARACTER
 840 	AND	(300)		/JUST RANGE BITS
 850 	TAD	(-100)		/COMPARE TO DESIRED COMBINATION
 860 	JMP I	CHK4		/LET CALLER CARE ABOUT IT
 870 
 880 	PAGE
 890 	EJECT
 900 /HERE COME THE PAGE ZERO LITERALS!