100 	JMP	MAIN		/GO DO IT AGAIN
 110 
 120 	PAGE
 130 	EJECT
 140 DODISP,	.-.			/DISPLAY INSERTION ROUTINE
 150 	SHL;	2		/LOSE JUNK BITS
 160 	ASR;S,	5		/SCALE TO PROPER RANGE
 170 /	TAD	CORRECT		/BIAS TO PROPER POSITION
 180 	CMA			/INVERT FOR SCREEN SENSE
 190 	TAD	L100		/CENTER THE DISPLAY
 200 	TAD	XYFACTOR	/ADD ON X-Y BIAS
 210 	CLL RTL			/*4
 220 	RTL			/*20 FOR ROW ADDRESS
 230 	JMS	DSPLA		/DISPLAY THE POINT
 240 	JMP I	DODISP		/RETURN
 250 
 260 DSPLA,	.-.			/DISPLAY SUB-ROUTINE
 270 	TAD	DSPADR		/ADD ON COLUMN ADDRESS
 280 	DCA	TEMP		/STASH IT
 290 ORINST,	TAD	L4000+.-.	/GET PARTICULAR BIT
 300 	MQL			/STASH IN MQ FOR LATER
 310 	JMS	DINSRT		/INSERT THE BIT
 320 	JMP I	DSPLA		/RETURN
 330 
 340 DINSRT,	.-.			/DISPLAY BIT INSERTION ROUTINE
 350 	CDF	DSPFLD		/GOTO DISPLAY FIELD
 360 	TAD I	TEMP		/GET THE WORD
 370 	MQA			/OR IN THE PARTICULAR BIT
 380 	DCA I	TEMP		/STORE THE WORD
 390 	CDF	00		/BACK TO FIELD 0
 400 INST,	JMP I	DINSRT		/OR TAD TEMP
 410 	CDF	ADRFLD		/GOTO BUFFER FIELD
 420 	CMA			/INVERT FOR STORAGE
 430 	DCA I	XR2		/STORE IN CLEARING BUFFER
 440 	CDF	00		/BACK TO FIELD 0
 450 	JMP I	DINSRT		/RETURN
 460 
 470 	FOO=	TAD	TEMP	/INSTRUCTION CONSTANT
 480 	FOOBAR=	JMP I	DINSRT	/INSTRUCTION CONSTANT
 490 	EJECT
 500 DOBEND,	.-.			/PROCESS BEGINNING OR END
 510 	TAD	XWORD		/GET X-WORD
 520 	SPA CLA			/SKIP IF NOT A BEGINNING
 530 	JMS	DOBEG		/PROCESS BEGINNING
 540 	TAD	YWORD		/GET Y-WORD
 550 	SPA CLA			/SKIP IF NOT AN ENDING
 560 	JMS I	(DOEND)		/PROCESS ENDING
 570 	JMP I	DOBEND		/RETURN
 580 
 590 DOBEG,	.-.			/PROCESS BEGINNING
 600 	TAD	M4		/SETUP
 610 	DCA	CNT		/DISPLAY COUNTER
 620 BEGLUP,	TAD	TEMP		/GET CURRENT POINTER
 630 	TAD	[-20]		/BACKUP TO PREVIOUS
 640 	DCA	TEMP		/UPDATE
 650 	JMS	DINSRT		/INSERT THE BIT
 660 	ISZ	CNT		/DONE YET?
 670 	JMP	BEGLUP		/NO, GO BACK
 680 	NL2000			/SET BLINK BIT
 690 	AND	XWORD		/GET BLINK BIT
 700 	SNA CLA			/SKIP IF A BLINK
 710 	JMP	NXT		/JUMP IF NOT
 720 	TAD	M4		/SETUP THE
 730 	DCA	CNT		/BLINK COUNT
 740 	CAM			/CLEAN UP
 750 	JMP	NXTIN		/FINISH THERE
 760 
 770 NXT,	NL2000			/SET "EXAMINED" BIT
 780 	AND	MDWORD		/TEST IF WE WERE HERE BEFORE
 790 	SNA CLA			/SKIP IF SO
 800 	JMP	CHKBGD		/CHECK FURTHER IF NOT
 810 	TAD	MDWORD		/GET WORD AGAIN
 820 	AND	L1000		/JUST "ON-TARGET" BIT
 830 	SZA CLA			/SKIP IF OFF
 840 GDBGIN,	TAD	[-5]		/MAKE -11
 850 	TAD	M4		/OR -4
 860 	DCA	CNT		/SAVE COUNT
 870 	DLD;	M4		/BACKUP TO FOUR BEFORE
 880 NXTIN,	DAD;	TAILTMP		/GET HORIZONTAL POSITION
 890 	DST;	DBLTMP		/SETUP SUB-ROUTINE
 900 	JMS I	(DOTAIL)	/PUT ON A TAIL
 910 	JMP I	DOBEG		/RETURN
 920 	EJECT
 930 CHKBGD,	TAD	MDWORD		/GET MODEM WORD
 940 	AND	L1000		/JUST GUIDE BIT
 950 	SNA CLA			/SKIP IF SET
 960 	JMP I	DOBEG		/RETURN IF NOT
 970 	TAD	[-11]		/SETUP THE
 980 	DCA	CNT		/COUNT
 990 	TAD	TEMP		/\
1000 	TAD	[2^20]		/ >MOVE DOWN TWO LINES
1010 	DCA	TEMP		//
1020 	DLD;	M4		/GET BACKUP FACTOR
1030 	DAD;	TAILTMP		/ADD ON POSITION
1040 	DST;	DBLTMP		/STORE FOR TAIL-WRITING
1050 	JMS I	(DOTAIL)	/DRAW INNER TAIL
1060 	TAD	TEMP		/\
1070 	TAD	(-2^20)		/ >RESTORE POSITION
1080 	DCA	TEMP		//
1090 	JMP	GDBGIN		/FINISH IT THERE
1100 
1110 	PAGE
1120 	EJECT
1130 DOEND,	.-.			/PROCESS ENDING
1140 	TAD	M4		/SETUP
1150 	DCA	CNT		/DISPLAY COUNTER
1160 ENDLUP,	TAD	TEMP		/GET CURRENT POINTER
1170 	TAD	[20]		/BUMP TO NEXT LINE
1180 	DCA	TEMP		/UPDATE
1190 	JMS I	(DINSRT)	/INSERT THE BIT
1200 	ISZ	CNT		/DONE YET?
1210 	JMP	ENDLUP		/NO, GO BACK
1220 	TAD	M4		/SETUP THE
1230 	DCA	CNT		/DEFAULT COUNT
1240 	NL2000			/SET BLINK BIT
1250 	AND	XWORD		/GET BLINK BIT
1260 	SNA CLA			/SKIP IF SET
1270 	JMP	NXTT		/JUMP IF NOT
1280 NXT2IN,	DLD;	M4		/BACKUP TO FOUR BEFORE
1290 NXTTIN,	DAD;	TAILTMP		/GET HORIZONTAL POSITION
1300 	DST;	DBLTMP		/SETUP SUB-ROUTINE