100 BEGGD,	NL6000			/SETUP GUIDED BIT
 110 BEGON,	TAD	L1000		/GET ON-TARGET BIT
 120 BEGREJE,DCA	TEMP		/SAVE IT
 130 	TAD I	CNT		/GET X-WORD
 140 	AND	[1777]		/REMOVE OLD BITS
 150 	TAD	L4000		/MAKE INTO REGULAR BEGIN
 160 	DCA I	CNT		/STORE IT BACK
 170 	ISZ	CNT		/BUMP TO Y-WORD
 180 	NL3777			/SETUP MASK
 190 	AND I	CNT		/REMOVE END BIT
 200 	DCA I	CNT		/STORE IT BACK
 210 	ISZ	CNT		/BUMP TO TIME WORD
 220 	ISZ	CNT		/BUMP TO MODEM WORD
 230 	NOP			/JUST IN CASE
 240 	TAD I	CNT		/GET MODEM WORD
 250 	AND	[4777]		/REMOVE OLD BITS
 260 	TAD	L2000		/SET EXAMINED BIT
 270 	TAD	TEMP		/ADD ON POTENTIAL ON-TARGET BIT
 280 	JMP	OTHEND		/FINISH IT THERE
 290 
 300 	PAGE
 310 	EJECT
 320 ENDO,	JMS I	(LOCATE)	/SETUP THE ADDRESS
 330 	JMS	VALINP		/GET VALID INPUT
 340 	SNA			/SKIP IF NOT NORMAL
 350 	JMP	ENDNORM		/JUMP IF NORMAL
 360 	IAC			/TEST FOR BLINK
 370 	SNA			/SKIP IF NOT
 380 	JMP	ENDBLNK		/JUMP IF BLINK
 390 	IAC			/TEST FOR REJECT (OFF-TARGET)
 400 	SNA			/SKIP IF NOT
 410 	JMP	ENDREJECT	/JUMP IF REJECT
 420 	IAC			/TEST FOR ON-TARGET
 430 	SNA			/SKIP IF NOT
 440 	JMP	ENDON		/JUMP IF ON-TARGET
 450 	IAC			/TEST FOR GUIDED
 460 	SNA			/SKIP IF NOT
 470 	JMP	ENDGD		/JUMP IF GUIDED
 480 	HLT			/FOR FUTURE EXPANSION
 490 
 500 ENDNORM,TAD I	CNT		/GET X-WORD
 510 	AND	[1777]		/REMOVE BEGIN, BLINK BITS
 520 EBLNKIN,DCA I	CNT		/STORE BACK
 530 	ISZ	CNT		/BUMP TO Y-WORD
 540 	NL3777			/SET MASK
 550 	AND I	CNT		/REMOVE OLD END BIT
 560 	TAD	L4000		/FORCE ON NEW ONE
 570 	DCA I	CNT		/STORE IT BACK
 580 	ISZ	CNT		/BUMP TO TIME WORD
 590 	ISZ	CNT		/BUMP TO MODEM WORD
 600 	NOP			/JUST IN CASE
 610 	JMP I	(REGEND)	/FINISH IT THERE
 620 
 630 ENDBLNK,TAD I	CNT		/GET X-WORD
 640 	AND	[1777]		/REMOVE BEGIN, BLINK BITS
 650 	TAD	L2000		/FORCE ON BLINK BIT
 660 	JMP	EBLNKIN		/FINISH THERE
 670 
 680 ENDGD,	NL6000			/SETUP GUIDE BIT
 690 ENDON,	TAD	L1000		/SET OR
 700 ENDREJE,DCA	TEMP		/CLEAR ON-TARGET BIT FOR LATER
 710 	TAD I	CNT		/GET X-WORD
 720 	AND	[1777]		/REMOVE BEGIN, BLINK BITS
 730 	DCA I	CNT		/STORE BACK
 740 	ISZ	CNT		/BUMP TO Y-WORD
 750 	NL3777			/SET MASK
 760 	AND I	CNT		/REMOVE OLD END BIT
 770 	TAD	L4000		/FORCE ON NEW ONE
 780 	DCA I	CNT		/STORE BACK
 790 	ISZ	CNT		/BUMP TO TIME WORD
 800 	ISZ	CNT		/BUMP TO MODEM WORD
 810 	NOP			/JUST IN CASE
 820 	TAD I	CNT		/GET MODEM WORD
 830 	AND	[4777]		/REMOVE EXAMINED, ON-TARGET BITS
 840 	TAD	L2000		/SET EXAMINED BIT
 850 	TAD	TEMP		/ADD ON POTENTIAL ON-TARGET BIT
 860 	JMP I	(OTHEND)	/FINISH IT THERE
 870 	EJECT
 880 VALINP,	.-.			/GET VALID INPUT ROUTINE
 890 VALAGN,	JMS I	[INPUT]		/GET A CHARACTER
 900 	SNA			/GOT ANYTHING?
 910 	JMP	VALAGN		/NO, TRY AGAIN
 920 	TAD	(-"U!300)	/IS IT <^U>?
 930 	SNA			/SKIP IF NOT
 940 	JMP I	[TSTXIT]	/JUMP IF SO
 950 	TAD	(-"O!200+25)	/IS IT "O"?
 960 	SNA			/SKIP IF NOT
 970 	JMP	GOTO		/JUMP IF SO
 980 	IAC			/IS IT "N"?
 990 	SNA			/SKIP IF NOT
1000 	JMP	GOTN		/JUMP IF SO
1010 	TAD	(-"R+"N)	/IS IT "R"?
1020 	SNA			/SKIP IF NOT
1030 	JMP	GOTR		/JUMP IF SO
1040 	TAD	(-"B+"R)	/IS IT "B"?
1050 	SNA			/SKIP IF NOT
1060 	JMP	GOTB		/JUMP IF SO
1070 	TAD	(-"G+"B)	/IS IT "G"?
1080 	SNA CLA			/SKIP IF NOT
1090 	JMP	GOTG		/JUMP IF SO
1100 	DPBL			/COMPLAIN OF BAD INPUT
1110 	JMP	VALAGN		/TRY AGAIN
1120 
1130 GOTG,	IAC			/INDICATE "G"
1140 GOTO,	IAC			/INDICATE "O"
1150 GOTR,	IAC			/INDICATE "R"
1160 GOTB,	IAC			/INDICATE "B"
1170 	CIA			/INVERT
1180 GOTN,	CDF	BUFFLD		/GOTO BUFFER FIELD
1190 	JMP I	VALINP		/RETURN
1200 
1210 	PAGE
1220 	EJECT