/IPB SYSTEM MANUAL BOOTSTRAP

	*7555			/WHERE TO START TOGGLING

	XMIT=	.-1		/NEED NOT BE LOADED

	TSKF			/FLAG UP ?
	JMP	.-1		/NO, WAIT
	TBLS			/YES, SEND IT
	RRBS			/CLEAR RECEIVE FLAG NOW
BUTPTR,	7600			/CLEAN UP
	JMP I	XMIT		/RETURN
 
MANBUT,	TBLS			/START HERE FROM A PWR CLEAR
	STA			/-1
	JMS	XMIT		/SEND IT
	JMS	XMIT		/ASK FOR 40 BLOCKS
	JMS	XMIT		/DOUBLE UP CALL
	JMS	XMIT		/STARTING FROM BLOCK 0
	JMS	XMIT		/DOUBLE UP CALL
	RSKF			/ANYTHING IN ?
	JMP	.-1		/NO, WAIT
	RRBC			/YES, READ IT IN
	DCA I	BUTPTR		/PUT INTO CORE
	ISZ	BUTPTR		/BUMP TO NEXT
	JMP	.-5		/GO BACK
/WILL FALL INTO OTHER BOOT HERE AT 7600
/TO MAKE IT EASIER ON US:

	*7400

START,	CAF			/CLEAN UP NOW
	TBLS			/SEND A ZERO
	STA			/-1
	JMS	XMIT		/SEND REQUEST
	JMS	XMIT		/ASK FOR
	JMS	XMIT		/40 BLOCKS
	JMS	XMIT		/ASK FOR
	JMS	XMIT		/BLOCK 0
	KSF			/FLAG UP ?
	JMP	.-1		/NO, WAIT FOR IT
	KCC			/THROW IT AWAY
	TSKF			/FLAG UP ?
	JMP	.-1		/NO, WAIT FOR IT
	JMP	MANBUT		/NOW GO DO IT FOR REAL

/INTERPROCESSOR DEFINITIONS
 
	DEVCOD=	62^10		/DEVICE CODE FOR BUFFER
	RSKF=	6001+DEVCOD	/SKIP ON RECEIVE
	RTIE=	6002+DEVCOD	/INT ENABLE/DISABLE
	RRBS=	6004+DEVCOD	/READ REC STATIC, CLEAR REC FLAG
	RRBC=	RRBS RTIE	/READ REC, CLEAR REC FLAG, SET OTHER XMIT FLAG
	TSKF=	RSKF+10		/SKIP ON XMIT FLAG
	TCLF=	RTIE+10		/CLEAR XMIT BUFF, FLAG
	TLBC=	RRBS+10		/OR AC, XMIT BUFF
	TBLS=	TCLF TLBC	/LOAD XMIT BUFF, CLEAR XMIT FLAG, SET OTHER REC FLAG