/	TC08 DECTAPE GENASYS HELPER

/	LAST EDIT:	05-APR-1986	05:00:00	CJL

/	MAY BE ASSEMBLED WITH '/J' SWITCH SET.

/	THIS ROUTINE IS MEANT TO BE USED TO GENERATE 'ALIEN' SYSTEMS ON A MACHINE
/	EQUIPPED WITH TC01/TC08 DECTAPE, BUT LACKING THE 'ALIEN' TARGET HARDWARE.

/	THE NORMAL METHOD OF SYSTEM GENERATION ALLOWS FOR THE CONCEPT OF EITHER
/	STAND-ALONE GENERATION, OR GENERATION BY THE CURRENT P?S/8 SYSTEM (IF ANY).

/	SETTING THE SWITCHES TO 7777 BEFORE GENERATING THE SYSTEM WILL USE THE
/	CURRENT P?S/8 I/O ROUTINES TO GENERATE THE (NEW) SYSTEM. BY USING THIS
/	ROUTINE FIRST, A PRE-EXISTING P?S/8 TC01/TC08 DECTAPE SYSTEM'S I/O ROUTINES
/	CAN BE READ INTO 007600 TO ALLOW THIS POSSIBILITY TO EXIST.

/	GENERATION INSTRUCTIONS.

/	TO GENERATE AN 'ALIEN' TARGET SYSTEM ON A DECTAPE, FIRST LOAD ALL NORMAL
/	P?S/8 INITIAL GENERATION FILES. HOWEVER, INSTEAD OF STARTING AT 000200,
/	START AT 030200 (IN THIS ROUTINE) WHICH WILL THEN HALT.

/	AFTER THE FIRST HALT, MOUNT A PRE-EXISTING P?S/8 TC08 DECTAPE SYSTEM TAPE
/	ON DRIVE ZERO AND PRESS CONTINUE. THE TAPE SHOULD REWIND AND READ IN BLOCK
/	ZERO AND THEN HALT AGAIN WITHOUT ERRORS. ANY ERRORS WILL BE INDICATED
/	IN THE TC01/TC08 "B" REGISTER DISPLAY AND ALSO THE AC. SHOULD ANY ERROR
/	OCCUR, THE PROGRAM CAN BE RESTARTED AT 030200 TO TRY AGAIN.

/	AFTER THE SECOND HALT, CHANGE THE TAPE TO THE TARGET DECTAPE INTENDED FOR
/	SYSTEM GENERATION ON DRIVE ZERO. HITTING CONTINUE WILL START THE NORMAL
/	P?S/8 SYSTEM GENERATION ROUTINES (WILL BEEP AND HALT WITH 7777 IN AC, ETC.).

/	DON'T FORGET TO SET THE SWITCHES TO 7777 BEFORE CONTINUING AGAIN, OR THIS
/	EXTRA ROUTINE SERVES NO PURPOSE!

/	DEFINITIONS.

	DTLA=	6766		/LOAD "A" REGISTER
	DTLB=	6774		/LOAD "B" REGISTER
	DTRB=	6772		/READ "B" REGISTER
	DTXA=	6764		/XOR "A" REGISTER
	DTSF=	6771		/SKIP ON DECTAPE OR ERROR FLAG
	SYSGEN=	0200		/NORMAL SYSTEM GENERATION ADDRESS
	FIELD	3		/GENASYS HELPER FIELD

	*200			/GENASYS HELPER ADDRESS

START,	CLA CLL			/CLEAN UP
	DTLB			/ENSURE CLEAR "B" REGISTER
	HLT			/WAIT FOR A P?S/8 TAPE TO BE MOUNTED
	CDF	00		/ALL IN FIELD 0
	TAD	(7600-7754)	/SETUP
	DCA I	(7754)		/WORD COUNT
	TAD	(7600-1)	/SETUP
	DCA I	(7755)		/CURRENT ADDRESS
	TAD	(600)		/REWIND
	DTLA			/THE TAPE
	DTSF			/WAIT FOR IT
	JMP	.-1		/TO FINISH
	TAD	(220)		/READ FORWARD
	DTLA			/MOST OF BLOCK ZERO
	DTSF			/WAIT FOR IT
	JMP	.-1		/TO FINISH
	TAD	(202)		/GET A MOTION BIT AND PRESERVE ERRORS
	DTXA			/STOP THE TAPE
	DTRB			/GET "B" REGISTER
	HLT			/WAIT FOR NEW TAPE MOUNT
	SZA CLA			/SKIP IF OK
	JMP	START		/ELSE GO TRY AGAIN
	CIF CDF	00		/GOING TO FIELD ZERO
	JMP	SYSGEN		/CONTINUE THERE

	PAGE

	$			/THAT'S ALL FOLK!