100 
 110 	ZBLOCK	7		/FOR EXTRA DEVICE SKIPS
 120 
 130 	0000			/THIS ENDS THE LIST
 140 
 150 /	CONSOLE TURNOFF ROUTINE.
 160 
 170 OFFCON,	IOF			/PREVENT PROBLEMS
 180 	NL0002			/SET CIF BIT
 190 	RDF			/GET CALLING FIELD
 200 	TAD	[CDF]		/TURN INTO CIF CDF CALLING FIELD
 210 	DCA	OFFRET		/STORE IN-LINE
 220 	JMP	OFFRET		/FINISH IT THERE
 230 	EJECT
 240 /	ERROR BLURBS.
 250 
 260 REDBLB,	"R&177			/READ BLURB
 270 	"E&177+40
 280 	"A&177+40
 290 	"D&177+40
 300 
 310 WRIBLB,	"W&177			/WRITE BLURB
 320 	"R&177+40
 330 	"I&177+40
 340 	"T&177+40
 350 
 360 FRMBLB,	"F&177+40		/FROM BLURB
 370 	"R&177+40
 380 	"O&177+40
 390 	"M&177+40
 400 
 410 TOBLB,	"I&177+40		/TO BLURB
 420 	"N&177+40
 430 	"T&177+40
 440 	"O&177+40
 450 
 460 	PAGE
 470 
 480 	ENDROM=	.		/END OF "ROM" AREA
 490 	EJECT
 500 /	ERROR BLURB HANDLING ROUTINES.
 510 
 520 BLBFILL,.-.			/FORMAT ERROR BLURB ROUTINE
 530 	CLA			/CLEAN UP
 540 	TAD	CALFLD		/GET CDF CALLING FIELD
 550 	DCA	EBLOCK		/STORE IN-LINE
 560 EBLOCK,	.-.			/WILL BE CDF CALLING FIELD
 570 	TAD	CALADR		/GET CALLING ADDRESS
 580 	DCA	EBLOCK		/STASH IT
 590 	TAD I	EBLOCK		/GET TRANSFER ADDRESS
 600 	DCA	EADDR		/STASH IT
 610 	ISZ	EBLOCK		/BUMP TO FUNCTION WORD
 620 	TAD I	EBLOCK		/GET FUNCTION WORD
 630 	DCA	EFUN		/STASH IT
 640 	ISZ	EBLOCK		/BUMP TO BLOCK NUMBER
 650 	TAD I	EBLOCK		/GET BLOCK NUMBER
 660 	DCA	EBLOCK		/STASH IT
 670 	JMS I	[SETFLD]	/SET OUR FIELD
 680 	TAD	EFUN		/GET FUNCTION WORD
 690 	SPA CLA			/SKIP IF READING
 700 	JMP	EWRITE		/JUMP IF WRITING
 710 	JMS I	(MOV4)		/MOVE IN
 720 	REDBLB-1		/THE READ
 730 	FUNBLB-1		/BLURB
 740 	JMS I	(MOV4)		/MOVE IN
 750 	TOBLB-1			/THE "TO"
 760 	FTBLB-1			/BLURB
 770 	JMP	ECOMMON		/CONTINUE THERE
 780 
 790 EWRITE,	JMS I	(MOV4)		/MOVE IN
 800 	WRIBLB-1		/THE WRITE
 810 	FUNBLB-1		/BLURB
 820 	JMS I	(MOV4)		/MOVE IN
 830 	FRMBLB-1		/THE "FROM"
 840 	FTBLB-1			/BLURB
 850 ECOMMON,TAD	EFUN		/GET THE FUNCTION WORD
 860 	AND	[7]		/JUST UNIT BITS
 870 	TAD	["0&177]	/MAKE IT ASCII
 880 	DCA I	(UNTBLB)	/STORE IN MESSAGE
 890 	TAD	EFUN		/GET FUNCTION WORD AGAIN
 900 	RTR;RAR			/MOVE OVER
 910 	AND	[7]		/ISOLATE FIELD BITS
 920 	TAD	["0&177]	/MAKE IT ASCII
 930 	DCA I	(FLDBLB)	/STORE IN MESSAGE
 940 	TAD	EBLOCK		/GET BLOCK NUMBER
 950 	JMS I	(OCTMOVE)	/PRINT IT
 960 	BLKBLB-1		/IN MESSAGE
 970 	TAD	EADDR		/GET TRANSFER ADDRESS
 980 	JMS I	(OCTMOVE)	/PRINT IT
 990 	ADDBLB-1		/IN MESSAGE
1000 	TAD	ESTATUS		/GET ERROR STATUS
1010 	JMS I	(OCTMOVE)	/PRINT IT
1020 	STATBLB-1		/IN MESSAGE
1030 	JMP I	BLBFILL		/RETURN
1040 	EJECT
1050 BLBMOVE,.-.			/BLURB MOVE ROUTINE
1060 	DCA	EFUN		/SAVE BLURB ADDRESS
1070 	IOF			/PREVENT PROBLEMS!
1080 	JMS I	[SETFLD]	/SETUP OUR FIELD
1090 	TAD I	BLBMOVE		/GET MOVE LENGTH
1100 	DCA	EADDR		/SAVE IT
1110 	ISZ	BLBMOVE		/BUMP PAST ARGUMENT
1120 	TAD	EADDR		/GET THE LENGTH
1130 	CLL RAL			/*2
1140 	TAD	(ERRBLB-1)	/POINT TO BEGINNING OF BLURB REGION
1150 	DCA	CXR1		/STASH THE POINTER
1160 	DCA	CXR2		/CLEAR <NUL> FLAG
1170 BLMVLUP,TAD I	EFUN		/GET A PAIR
1180 	RTR;RTR;RTR		/LEFT ONE FIRST
1190 	JMS I	(BLBCHAR)	/PUT IT IN MESSAGE
1200 	TAD I	EFUN		/GET PAIR AGAIN
1210 	JMS I	(BLBCHAR)	/PUT IT IN MESSAGE
1220 	ISZ	EFUN		/BUMP TO NEXT PAIR
1230 	ISZ	EADDR		/DONE ALL PAIRS YET?
1240 	JMP	BLMVLUP		/NO, KEEP GOING
1250 	JMP I	BLBMOVE		/YES, RETURN
1260 
1270 BLBDISP,.-.			/BLURB DISPLAY AND REPLY ROUTINE
1280 	CLA			/CLEAN UP
1290 	TAD	INCHAR		/GET FORMER INPUT CHARACTER
1300 	DCA	EADDR		/SAVE IT
1310 	TAD	(BLURB)		/POINT TO MESSAGE
1320 	DCA	EFUN		/SET IT UP
1330 	JMS I	[SETFLD]	/SETUP OUR FIELD
1340 PLOOP,	TAD I	EFUN		/GET A CHARACTER
1350 	SNA			/END OF LIST?
1360 	JMP	PEND		/YES
1370 	SPA			/PRINTABLE?
1380 	JMP	NOPRNT		/NO, FORGET THIS ONE
1390 	JMS	OUTCON		/PRINT IT
1400 	JMP	.-1		/WAIT FOR IT
1410 NOPRNT,	CLA			/CLEAN UP
1420 	ISZ	EFUN		/BUMP TO NEXT