/SERIAL-BASED DISK SERVER SHUTDOWN ROUTINE
/SENDS THE SERVER A 'Q' TO COMMAND IT TO SHUTDOWN CLEANLY

/BOB ADAMSON	20/NOV/2015	- ORIGINAL

BASER=6400		/USING DEVICE 40/41
BASET=6410

SKCF=BASER
SKSF=BASER+1
SKCC=BASER+2
SKRS=BASER+4
SKIE=BASER+5
SKRB=BASER+6

STFL=BASET
STSF=BASET+1
STCF=BASET+2
STPC=BASET+4
STSK=BASET+5
STLS=BASET+6

KRB=6036

	*200
	CLA CLL
	TLS
	TAD TX1
	JMS TEXOUT	/ASK FOR CONFIRMATION
	KCF
	KSF
	JMP .-1		/WAIT FOR IT
	KRB		/AND GET THE RESPONSE
	DCA TEMP
	TAD TEMP
	JMS TTYOUT
	TAD TX2
	JMS TEXOUT
	TAD TEMP
	TAD (-"Y
	SZA CLA		/CHECK FOR A 'Y'
	JMP I (7600	/ANYTHING ELSE ABORTS
	TAD ("Q
	STLS		/SEND THE SERVER A 'Q'
	CLA
	TAD TX3		/DON'T WAIT FOR IT NOW
	JMS TEXOUT	/TELL HIM IT'S DONE
	HLT		/AND STOP
	JMP .-1		/DON'T RESTART
TEXOUT,	0		/TYPE A STRING
	DCA PNTR
TEX1,	ISZ PNTR
	TAD I PNTR	/GET NEXT CHARACTER
	SNA		/EXIT ON A NULL
	JMP I TEXOUT
	JMS TTYOUT
	JMP TEX1
TTYOUT,	0
	TSF
	JMP .-1
	TLS
	CLA
	JMP I TTYOUT
TX1,	.
	"D;"O;240;"Y;"O;"U;240;"R;"E;"A;"L;"L;"Y;240;"W;"A;"N;"T;240;"T;"O
	240;"S;"T;"O;"P;240;"T;"H;"E;240;"S;"E;"R;"V;"E;"R;240;"(;"N;");"?;240;0
TX2,	.;215;212;0
TX3,	.;"S;"E;"R;"V;"E;"R;240;"H;"A;"L;"T;"E;"D;215;212
	"P;"R;"O;"C;"E;"S;"S;"O;"R;240;"H;"A;"L;"T;"E;"D;215;212;0
PNTR,	0
TEMP,	0
$$$$$$