#!/usr/bin/expect -f

spawn pdp8
set timeout -1

# Initialize the SIMH device configuration.
expect -re {\nsim> $}
send "set dt disable\r"
expect -re {\nsim> $}
send "set td enable\r"
expect -re {\nsim> $}
send "att td dms.td8e\r"
expect -re {\nsim> $}
send "set df disable\r"
expect -re {\nsim> $}
send "set rf disable\r"
# The "real" driver must be loaded into field one.
expect -re {\nsim> $}
send "load dta0.bin\r"
# Now load builder and the TD8E patch.
expect -re {\nsim> $}
send "load dec-d8-sbaf-pb\r"
expect -re {\nsim> $}
send "load td8e.bin\r"
expect -re {\nsim> $}

# Run the BUILDER to initialize the empty system.
send "run 0200\r"
expect -re {CORE\? $}
send "8\r"
expect -re {TAPE\? $}
send "Y"
expect -re {RF08\? $}
send "N"
expect -re {DF32\? $}
send "N"
# Doesn't ask about DECtape when there is no other choice.
#expect -re {DECTAPE\? $}
#send "Y"
expect -re {\n\.$}

# Load and run TMOD to set up the OS/8 style bootstrap.
send "\005"
expect -re {\nsim> $}
send "load tmod.bin\r"
expect -re {\nsim> $}
send "run 0200\r"
expect -re {\n\.$}

# Load the specified module and save it.
proc LoadSave {load save} {
  send "\005"
  expect -re {\nsim> $}
  send "att ptr $load\r"
  expect -re {\nsim> $}
  send "c\r"
  expect "\012"
  send "LOAD\r"
  expect -re {IN-$}
  send "R:\r"
  expect -re {ST=$}
  send "7600\r"
  expect -re {\^$}
  send "\220"
  expect -re {\^$}
  send "\220"
  expect -re {\n\.$}
  send "SAVE $save\r"
  expect -re {\n\.$}
}

# Load PIP, etc..
LoadSave "dec-d8-pdad-pb" "PIP!0-5177;1000"
# Load PIP patch
LoadSave "pipb.bin" "PIP!0-5177;1000"
# Load the rest of the system as for TC01/TC08.
#LoadSave "dec-d8-pdze-pb" "PIP!0-5177;1000"
LoadSave "dec-d8-esad-pb" "EDIT!0-3377;2600"
LoadSave "dec-d8-asac-pb" "PALD!0-7577;6200"
LoadSave "dec-d8-afa1-pb" "FORT!0-1777;200"
LoadSave "dec-d8-afa2-pb" ".FT.!200-7377;0"
LoadSave "dec-d8-afa3-pb" "FOSL!0-1777;200"
LoadSave "dec-d8-afa4-pb" ".OS.!0-5177;0"
LoadSave "dec-d8-afa5-pb" "STBL!600-777;600"
LoadSave "dec-d8-afa6-pb" "DIAG!200-1177;200"
#LoadSave "dec-d8-cdd1-pb" "DDT!7200-7577;7200"
#LoadSave "dec-d8-cdd2-pb" ".DDT:200-4577;0"
#LoadSave "dec-d8-cdd2-pb" ".SYM:200-4577;0"
LoadSave "dec-d8-cde1-pb" "DDT!7200-7577;7200"
LoadSave "dec-d8-cde2-pb" ".DDT:200-4577;0"
LoadSave "dec-d8-cde2-pb" ".SYM:200-4577;0"
LoadSave "dec-d8-rwda-pb" "REST!200-377;200"

# Wrap up and exit.
send "PIP\r"
expect -re {OPT-$}
send "L"
expect -re {IN-$}
send "S:\r"
expect -re {OPT-$}
send "\003"
expect -re {\n\.$}
send "\005"
expect -re {\nsim> $}
send "q\r"
expect -re {\n}
close
exit 0