/ FLBOOT.PA    BOOT FOR PACKED SYKES
/FLOPPY DISK -- CF. HANDLER FLOPSY.PA

	HLT
	JMP BSTART

	SYOP=6321
	SYSK=6322
	SYIN=6324

	BAUTO=10
	BCOUN=7
	BHIGH=6
	BLOW=5
	BCLAX=7600

/DISK RESIDENT BOOT
	*7400
	ZBLOCK 10	 / OFFSET
BIN,	0
	SYSK
	JMP .-1
	SYIN
BLAST,	JMP I BIN
/SET UP CONSTANTS
M100,	7700
K7400,	7400
A7605,	7605
K406,	406

BSTART,	CLA		/ENTRY, THIS LOCATION, MUST BE 7421
	TAD BCLA
	SYOP		/RESET
	CLA CLL
	TAD K601
	SYOP		/SELECT UNIT 1 (LOWER DDRIVE)
	CLA CLL		/WAS A LAS BEFORE
	TAD K607
	SYOP		/"READ TRACK 0"


	JMS BINPUT	 /GARBAGE FIRST TIME
	JMS BINPUT	 /READ F0 76-77
	TAD BCLA	 /0600 SIGNIFICANT IN AC
	SYOP		 /RESET
BCLA,	BCLAX
	TAD K406
	SYOP
	IAC
	SYOP		 /BLOCK 66
	CDF 10
	JMS BINPUT	 /READ F1 76-77
	CDF 20
	JMS BINPUT	 /READ F2 76-77
	JMP I A7605	 /AND OFF WE GO!
/
BINPUT,	0		/READS ONE PAGE
	CLA STL CMA	 / -1 IN AC
	TAD BCLA
	DCA BAUTO	 /7577 IN AUTO INDEX
	TAD M100	 / NO. WORDS/2
	DCA BCOUN	 / IN COUNTER
BREAD,	JMS BIN
	RTL
	DCA BHIGH
	JMS BIN
	DCA BLOW
	TAD BHIGH
	RTL
	AND K7400
	TAD BLOW
	DCA I BAUTO
	JMS BIN
	DCA BLOW
	TAD BHIGH
	BSW
	AND K7400
	TAD BLOW
	DCA I BAUTO
	ISZ BCOUN
	JMP BREAD
	JMP I BINPUT	 /EXIT SUBROUTINE
K601,	601
K607,	607