/ O/S-8 DRIVER TTO:  *BR*
/
/ TELETYPE OUTPUT DOING FORMATTING
/
*0
/
-1		/ JUST ONE ENTRY
/
	DEVICE LA30;DEVICE LPT;1040;0;0;0
/
/ DEVICE CODES
/
TSF1=	6661
TLS1=	6666
/
*200
/
TTO,	0
	STL CLA RAR	/ 4000
	TAD I TTO
	AND TT7700
	CMA
	DCA TTOWC
	TAD TTOCIF
TTO214,	RDF
	DCA TTOXIT
TTO16,	16
TTO70,	70
TTO177,	177
	TAD I TTO
TTO212,	AND TTO70
	TAD TTCDF0
TTO226,	DCA TTOCDF
	ISZ TTO
	TAD I TTO
	DCA TTOCA
	ISZ TTO
	TAD I TTO
	ISZ TTO
TTOCDF,	HLT
	SNL		/ READ OR WRITE
	JMP TTOERR	/ READ !
	SZA CLA		/ BLOCK=0 ?
	JMP TTOGO	/ NO
	TAD TTOEMP
	CMA
	DCA LINCNT	/ DUMMY FORM FEED
	KSF
	JMP .-1
	TAD TTO214	/ FORM FEED
	JMP TTOGO
/
TTCDF0,	CDF 0
TTOPTR,	0
/
TTOGET,	0
	TAD I TTOCA
	JMS TTOCH
	TAD I TTOCA
	AND TT7400
	ISZ TTOCA
TT7400,	7400		/ NOP
	JMP I TTOGET
/
TTOLP,	JMS TTOGET
	DCA TTOCDF
TTOMPG,
TT7700,	7700		/ SMA CLA = NOP
	JMS TTOGET
	CLL RTR
	RTR
	TAD TTOCDF
	RTR
	RTR
TTOGO,	JMS TTOCH
	ISZ TTOWC
	JMP TTOLP
TTORET,	ISZ TTO
TTOXIT,	HLT		/ CDF CIF CALL
	JMP I TTO
/
TTOERR,	STL CLA RAR
	JMP TTOXIT
/
TTOWC,	0
TTOCA,	0
/
TTOOUT,	0
TTO215,	TAD TTO212
	TLS1
TT7600,	7600		/ CLA
	TSF1
	JMP .-1
TTOAND,	KRS
	TAD TTMCTC
	SZA CLA		/ ^C ?
	JMP I TTOOUT
TTOCIF,	CDF CIF 0
	JMP I TT7600	/ ^C, MONITOR
/
TTOCH,	0
	IAC
	AND TTO177
	SNA
	JMP I TTOCH	/ IGNORE RUBOUT
	TAD TTOM33
	SNA		/ ^Z ?
	JMP TTOCTZ	/ YES
	TAD TTO16
	SNA		/ ^L ?
	JMP TTOFF	/ YES, FORM FEED
	IAC
	IAC
	SNA		/ LF ?
	JMP TTOLFO	/ YES
	IAC
	SNA		/ TABULATE ?
	JMP TTOTAB	/ YES
	ISZ TTOPTR
	TAD TTO177
	JMS TTOOUT
	JMP I TTOCH
/
TTOTAB,	TAD TTO226
	JMS TTOOUT
	ISZ TTOPTR
	TAD TTOPTR
	AND TTO7
	SZA CLA
	JMP TTOTAB
	JMP I TTOCH
/
TTOLFO,	JMS TTOOUT
	TAD TTOAND	/ 6034 AND (1207 = 4
	DCA TTOPTR
	ISZ LINCNT
	JMP TTOTAB	/ MARGIN 4 SPACES
TTOFF,	TAD LINCNT
	TAD TTOEMP
	DCA TTOPTR
	TAD TTOCIF	/ START WITH CR
	JMS TTOOUT
	ISZ TTOPTR
	JMP .-2
	TAD TTOMPG
	DCA LINCNT
	TAD TTOCIF	/ CR = 6203+212 = 6415 = 15
	JMP TTOLFO
/
TTOEMP,	-12		/ AMERIKANSK FORMAT: -10
/
TTO7,
TTOCTZ,	TAD TTO214
	JMS TTOCH
	JMP TTORET
/
LINCNT,	-100
/
TTMCTC,	-3
TTOM33,	-33
/
/
$