/
/	COPYRIGHT 1968, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/	UTILITY SUBROUTINE PACKAGE
/		VERSION UTILTY.V07 (JANUARY 7, 1969)
/
	ENTRY	OPEN	     /INITIALIZING AND FLAG SETTING ROUTINE
	ENTRY	CKIO	     /ROUTINE TO DELAY UNTIL I/O IS COMPLETE
	ENTRY	TTYIN	     /TELETYPE INPUT (KEYBOARD)
	ENTRY	TTYOUT	     /TELETYPE OUTPUT
	ENTRY	HSIN	     /HIGH SPEED PAPER TAPE INPUT
	ENTRY	HSOUT	     /HIGH SPEED PUNCH OUTPUT
	ENTRY	EXIT		/EXIT TO DISK MONITOR SYSTEM
	OPDEF	KCC	6032
/
/	TELETYPE KEYBOARD INPUT
/
TTYIN,	BLOCK	2
	CLA
KW,	KSF		     /WAIT FOR KEYBOARD FLAG
	JMP	KW
	KRB		     /READ THE KEYBOARD
	DCA	HSIN
	TAD	HSIN
	TAD	(-212
	SNA CLA		     /LINE FEED?
	JMP	TTY1
	TAD	HSIN
	JMS	TYPE	     /NO, ECHO THE CHAR ...
	TAD	HSIN
	TAD	(-215
	SNA CLA		     /WAS IT A CAR-RETURN?
	JMP	TTY2
TTY1,	TAD	HSIN
	RETRN	TTYIN	     /RETURN THE CHAR
TTY2,	TAD	(212	     /HAD A CAR-RETURN ...
	JMS	TYPE	     /ECHO A LINE FEED
	JMP	TTY1
/
/	TELETYPE OUTPUT
/
TTYOUT,	BLOCK	2	     /ENTRY TO TELETYPE OUTPUT
	SNA		     /TEST FOR CARRIAGE RETURN
	JMP	CR	     /IT WAS ONE
	JMS	TRIMUP
	JMS	TYPE	     /PUT OUT THE CHAR
	RETRN	TTYOUT
CR,	TAD	(215	     /PUT OUR A CR
	JMS	TYPE
	TAD	(212
	JMS	TYPE
	RETRN	TTYOUT
/
/	HIGH SPEED READER INPUT
/
HSIN,	BLOCK	2
HI,	RSF
	JMP	HI
	CLA
	RRB RFC
	RETRN	HSIN
/
/	HIGH SPEED PAPER TAPE PUNCH OUTPUT
/
HSOUT,	BLOCK	2	     /ENTRY TO HIGH SPEED PAPER OUTPUT
	SNA		     /TEST FOR CRLF
	JMP	CRLF
	JMS	TRIMUP
	JMS	PUNH	     /PUNCH THE CHAR
	RETRN	HSOUT
CRLF,	TAD	(215	     /PUT OUT CR
	JMS	PUNH
	TAD	(212	     /PUT OUT LINE FEED
	JMS	PUNH
	RETRN	HSOUT
TYPE,	0		     /TYPE C(AC)
TW,	TSF		     /WAIT FOR FREE
	JMP	TW
	TLS		     /TRANSMIT THE CHAR
	CLA
	JMP I	TYPE
PUNH,	0		     /PUNCH C(AC)
PW,	PSF
	JMP	PW
	PLS		     /TRANSMIT THE CHAR
	CLA
	JMP I	PUNH
TRIMUP, 0		     /ADD ASCII BITS
	AND	(77	     /MASK TO MAKE SURE
	TAD	(-40
	SPA		     /TEST WHICH GROUP
	TAD	(100	     /300-337 GROUP, ADD 100
	TAD	(240
	JMP I	TRIMUP
/
/	DUMMY DELAY UNTIL BUFFERS EMPTY
/	(IN CASE YOU WANT TO INTERRUPT I/O)
/
CKIO,	BLOCK	2
	RETRN	CKIO
/
/	INITIALIZING SUBROUTINE CALLED BY FORTRAN
/	CLEARS FLOATING AC AND SETS FLAGS
/
OPEN,	BLOCK	2
	KCC
	TLS
	PLS
	RFC
	CLA
	CALL	0,TTYOUT     /TYPE A CR-LF
	CALL	0,CLEAR
	RETRN	OPEN

/
/EXIT TO DISK MONITOR SYSTEM
/
EXIT,	BLOCK	2
	CALL	0,CKIO
	TAD I	MONIT	/DUMMY ADD TO PREVENT 6201 ON JMP I MONIT
	CLA
	6203		    /CDF 0, CIF 0
	JMP I	MONIT
MONIT,	7600
	END