/PAGE 33
ERROR1,	JMS ETYPO 	/TYPE ERROR CODE
	DCA TEM2 		/SAVE SYMBOL ADDRESS AS A POINTER
	TAD I TEM2 	/GET FIRST WORD OF SYMBOL
	AND MASK 		/GET RID OF UNDEFINED BIT
	DCA I TEM2 	/SYMBOL IS DEFINED FOR FUTURE REFERENCE
	TAD I TEM2 	/GET IT BACK IN THE AC
	JMS I EEE 	/TYPE OUT THE FIRST WORD OF THE SYMBOL
	ISZ TEM2 		/INCREMENT THE POINTER TO THE 2ND WORD
	TAD I TEM2 	/PICK UP THE 2ND WORD
	JMS I EEE 	/TYPE IT OUT
	ISZ TEM2 		/MOVE THE POINTER TO THE THIRD WORD
	TAD I TEM2 	/PICK UP THE THIRD WORD
	JMS I EEE 	/TYPE IT OUT
ECOMON,	JMS I EEE 	/TYPE TWO SPACES
	TAD ATCODE 	/GET "AT"
	JMS I EEE 	/TYPE IT
	JMS I EEE 	/TYPE TWO SPACES
	TAD AACT 		/GET THE ABSOLUTE ADDRESS COUNTER
	JMS I OCTI 	/TYPE IT OUT
	TAD C377 		/TYPE A RUBOUT
	JMS I DDD
	JMP I TEM1 	/EXIT
ERROR2,	JMS ETYPO 	/TYPE THE ERROR CODE
	JMS I OCTI 	/TYPE THE VALUE OF IC, PO, OR PU
	JMP ECOMON 	/TYPE "AT" AND AACT

ETYPO,	0 		/SUBROUTINE TO TYPE ERROR CODE
	TAD TBLEAD 	/ADD ERROR CODE TO TABLE POINTER
	DCA TEM2 		/SAVE POINTER TO CODE IN TEMP
	POP 		/GET EXIT ADDRESS FROM PDL
	DCA TEM1 		/SAVE IT, ERROR ADDRESS NOW AVAILABLE
	TAD PF 		/WHICH PASS IS THIS?
	SZA CLA 		/ERROR PRINTOUTS ONLY ON PASS1
	JMP ERROUT 	/OTHERWISE, EXIT FROM ERROR ROUTINE
	TAD C377 		/TYPE A RUBOUT IN CASE OF IR
	JMS I DDD
	TAD CRLF	/CARRIAGE RETURN, LINE FEED
	JMS I EEE
	TAD I TEM2 	/GET THE ERROR CODE LETTERS
	JMS I EEE 	/TYPE THE ERROR CODE
	JMS I EEE 	/TYPE TWO SPACES
	POP 		/GET SYMBOL ADDRESS OR IC, IL, IO VALUE
	JMP I ETYPO 	/EXIT WITH IT IN THE AC

ERROUT,	POP 		/CLEAR JUNK OFF THE PUSHDOWN LIST
	CLA
	JMP I TEM1 	/EXIT




/PAGE 34
/PASS3 ROUTINE
/ASSEMBLY LISTING ON ASR33 IF SW11 DOWN, 75A IF UP
/LENGTH: 80 REGISTERS

POUT,	CLA OSR 		/GET SWITCH REGISTER
	CLL RAR 		/WAS BIT 11 SET?
	SNL CLA
	JMP PART1 	/NO
	TAD BBB 		/YES, RESET PRINT POINTER
	DCA DDD 		/FOR 75A PUNCH
	DCA TCNT		/ZERO CHARACTER COUNTER
PART1,	TAD CRLF	/CARRIAGE RETURN, LINE FEED
	JMS I EEE
	TAD INFO 		/ANY INFORMATION ON THIS LINE?
	SZA CLA
	JMP PART2 	/YES
	TAD M6 		/NO, TYPE 12 SPACES
	DCA TEM3
	JMS I EEE
	ISZ TEM3
	JMP .-2
	JMP .+7 		/DON'T TYPE AACT
PART2,	TAD AACT 		/VALID INFO, TYPE AACT
	JMS I OCTI
	JMS I EEE 	/TYPE 2 SPACES
	TAD BINW 		/TYPE ASSEMBLED VALUE
	JMS I OCTI
	JMS I EEE 	/TYPE TWO SPACES
	TAD CHAR 		/WAS IT A CR?
	TAD M215
	SZA
	TAD M56		/IS IT ;??
	SZA CLA
	JMP I TABIT-1 	/NO: RETURN
	CLA CMA 		/YES: PUT STATEMENT
	DCA I AUTOC 	/DELIMITER IN BUFFER
PART3,	TAD TBUF 		/SET BUFFER
	DCA AUTOC
PART4,	TAD I AUTOC 	/GET CHARACTER
	TAD M211 		/TAB?
	SNA
	JMP I TABIT 	/YES, TYPE TAB RUBOUT OR TAB STOP
	TAD M1 		/LINE FEED?
	SNA
	JMP PART4 	/YES, IGNORE IT
	TAD M2 		/FORM FEED?
	SNA
	JMP FFEED 	/YES, TYPE FORM FEED
	TAD M1 		/CARRIAGE RETURN?
	SZA
	JMP .+3
	DCA TCNT	/ZERO COUNTER FOR NUMBER OF CHARACTERS
	JMP PART4 	/YES


/PAGE 35
	TAD C215		/RESTORE ORIGINAL CHARACTER
	SPA		/RUBOUT
	JMP PART5	/YES, ALL DONE
	SZA		/IGNORE CHARRIAGE RETURN
	JMS I DDD	/NO, TYPE OR PUNCH CHARACTER
	ISZ TCNT	/COUNT A CHARACTER
	JMP PART4

PART5,	CLA 		/ALL DONE 
	TAD TBUF 		/RESET BUFFER
	DCA AUTOC
	TAD LOPUNI 	/RESET PUNCH POINTER
	DCA DDD
	JMP I .+1
	MOUT 		/RETURN TO MAIN
TABIT,	TAB
TCNT,	0
M56,	-56

FFEED,	TAD M6 		/TYPE SIX BLANK LINES
	DCA TEM3
	TAD CRLF
	JMS I EEE
	ISZ TEM3
	JMP .-3
	TAD C214 		/TYPE FORM FEED
	JMS I DDD
	TAD M6 		/TYPE SIX MORE BLANK LINES
	DCA TEM3
	TAD CRLF
	JMS I EEE
	ISZ TEM3
	JMP .-3
	JMP PART4 	/RETURN


TBLEAD,	TABLE-1		/POINTER FOR ERROR CODES
ATCODE,	0124 		/AT


L16,	






/PAGE 36
*2000


/ROUTINE TO HANDLE ORIGINS
/LENGTH:  13 REGISTERS

STAR,	PUSHJ 		/ORIGIN SETTING, GO ASSEMBLE EXPRESSION
	CSYM 		/ADDRESS FOR PUSHJ HANDLER
	TAD BINW 		/PICK UP ASSEMBLED BINARY WORD
	DCA AACT 		/RESET ABSOLUTE ADDRESS COUNTER
	DCA INFO 		/SAY NO TO MAIN
	CMA 		/WHICH PASS IS THIS?
	TAD PF 		/DO NOT PUNCH ON PASS1 OR PASS3
	SZA CLA
	POPJ 		/EXIT ON PASS1 OR PASS3
	CLL CML 		/SET LINK FOR ORIGIN PUNCH IN BINP
	TAD AACT 		/PICK UP ORIGIN
	JMS I PUNI 	/GO PUNCH IT
	POPJ 		/EXIT


PSHLST,	0 		/PUSH DOWN LIST
*.+13



/PAGE 37
/CHECK ROUTINE

/DISTINGUISHES BETWEEN NUMBERS, LETTERS, SPECIAL CHARACTERS
/NUMBERS HAVE CODES BETWEEN 260 AND 271
/LETTERS HAVE CODES BETWEEN 301 AND 332
/ANY CHARACTER NOT A NUMBER OR A LETTER IS A SPECIAL CHARACTER
/HOWEVER, SPECIAL CHARACTERS ARE MEANT TO INCLUDE ONLY
/PLUS, MINUS, COMMA, EQUAL, STAR, PERIOD, SPACE, RETURN, DOLLAR

/EXIT TO SPSHUL IF CHAR IS A SPECIAL CHARACTER
/EXIT TO CALLING ADDRESS+1 IF CHAR IS NUMBER
/EXIT TO CALLING ADDRESS +2 IF CHAR IS LETTER

/LENGTH: 23 REGISTERS

NCHEK,	0
	TAD CHAR 		/IS CHAR < 260?
	TAD M260 		/GET CHAR-260
	SPA
	JMP I SPECI 	/CHAR<260,SPECIAL CHARACTER
	TAD M12 		/IS CHAR<272?
	SPA 		/FORM CHAR-272
	JMP NUMBEX 	/YES, 260<CHAR<272
	TAD M7 		/IS CHAR<301?
	SPA
	JMP I SPECI 	/NO,CHAR IS A SPECIAL CHARACTER
	TAD M32 		/IS CHAR<333?
	SMA
	JMP I SPECI 	/NO, CHAR IS A SPECIAL CHARACTER
LETREX,	ISZ NCHEK 	/EXIT FOR LETTERS
NUMBEX,	CLA
	TAD CHAR 		/TRIM CHAR TO SIX BITS
	AND SL6
	DCA CHAR 		/PUT IT BACK
	JMP I NCHEK 	/EXIT
M260,	-0260
M7,	-0007
M32,	-0032




/PAGE 38
/SYMBOL TABLE SEARCH ROUTINE
/EXITS TO CALLING ADDRESS+1 IF SYMBOL NOT IN TABLE
/EXITS TO CALLING ADDRESS+2 IF SYMBOL IN TABLE
/ENTRY ADDRESS IS RETURNED IN AC IF NOT IN TABLE
/ADDRESS OF VALUE IN AC IF IN TABLE
/LENGTH: 41 REGISTERS
SYMGET,	0
	TAD SATAB
	DCA SORT2
	TAD SORT2
	IAC
	DCA TEM3
LOOP,	TAD SPNT 		/END OF SYMBOLS YET?
	CLL CMA IAC
	TAD SORT2
	SNA CLA 		/SKIP IF NOT TESTED ALL
	JMP NITBL 	/TERMINATE SEARCH, TABLE FULL
	TAD SYMPNT 	/GET ADDRESS-1 OF SYM1
	DCA SORT1 	/IN AN INDEX REGISTER
	JMS I SYMCMI 	/COMPARE TWO SYMBOLS
	JMP INTABL 	/THEY MATCH IF RETURN IS HERE
	NOP 		/THEY DON'T MATCH
	ISZ SORT2 	/INDEX TO NEXT SYMBOL
	JMP LOOP-3
NITBL,	TAD TEM3 		/CHECK TABLE OVERFLOW
	CIA CLL 		/COMPARE AGAINST PAGE
	TAD RBGN 		/SYMBOLS STOP AT 6600
	SZL CLA
	JMP NTEXIT 	/OK, ROOM FOR THIS SYMBOL
	TAD SYMPNT
	IAC 		/ADDRESS OF SYMBOL
	PUSH
	TAD C3 		/CODE FOR ST IS 3
	PUSHJ 		/GO TO ERROR ROUTINE
	ERROR1
	HLT 		/HALT ON S.T. ERROR
	JMP .-1 		/NO RECOVERY
NTEXIT,	TAD TEM3 		/ADDRESS TO STORE IN
	JMP I SYMGET 	/EXIT
INTABL,	TAD I SORT2
	DCA SYMVAL 	/PUT IT IN SYMVAL
	TAD TEM3 		/RETURN WITH ADDRESS
	TAD C3
	ISZ SYMGET
	JMP I SYMGET 	/EXIT

SYMPNT,	SYM1-1
SATAB,	OPTABL-1

/PAGE 39
/ROUTINE TO HANDLE COMMAS

/LENGTH: 22 REGISTERS

SYMSTO,	TAD PF 		/WHICH PASS IS THIS?
	SZA CLA
	JMP EXIT 		/IGNORE SYMBOL DEFINITIONS, PAS2
	TAD I TEM3 	/PICK UP THE FIRST WORD OF SYMBOL
	SPA CLA 		/HAS IT ALREADY BEEN DEFINED?
	JMP DEFIN 	/NO, GO PROCESS IT
	TAD TEM3 		/YES, COMPLAIN ABOUT A DOUBLE TAG
	PUSH 		/SAVE ENTRY ADDRESS OF SYMBOL
	TAD C2 		/CODE FOR D.T. IS 2
	PUSHJ
	ERROR1 		/ERROR ROUTINE
	JMP EXIT 		/DON'T PROCESS IT
DEFIN,	TAD I TEM3 	/MAKE THE SYMBOL DEFINED
	AND MASK
	DCA I TEM3 	/PUT IT BACK
	ISZ TEM3 		/INCREMENT POINTER TO VALUE
	ISZ TEM3
	ISZ TEM3
	TAD AACT 		/GET THE CURRENT LOCATION
	DCA I TEM3 	/STORE IT AS THE VALUE OF THE WORD
EXIT,	DCA INFO 		/CLEAR INFO
	JMP I FFF 	/BACK TO CSYM

/THE FIELD PSEUDO-OP
/PUNCHES A WORD IN THE FORM
/11 XXX 000
/LENGTH: 17 REGISTERS

FLD,	PUSHJ 		/EVALUATE EXPRESSION
	CSYM 		/ADDRESS
	TAD PF 		/WHICH PASS IS THIS?
	SPA SNA CLA
	JMP .+7 		/NOT PASS 2
	TAD BINW 		/IT IS PASS 2
	AND SL3 		/JUST THREE BITS
	CLL RTL 		/MOVE LEFT 3 PLACES
	RAL
	TAD KON6 		/BITS FOR LOADER
	JMS I BBB 	/PUNCH IT
	TAD C200		/RESET ORIGIN TO 200
	PUSHJ			/ IN NEW FIELD
	STAR+3
	DCA INFO
	POPJ
KON6,	0300 		/BITS FOR LOADER

L20,	




*2200
/PAGE 40

/ROUTINE TO FIX MEMORY REFERENCE INSTRUCTIONS
/LENGTH: 11 REGISTERS
/CAN BE GIVEN ONLY AFTER EXPUN

FIXY,	PUSHJ 		/RECURSIVE CALL TO MAIN PROCESSOR
	CSYM 		/ADDRESS FOR PUSHJ HANDLER
	DCA INFO
	TAD PF 		/WHICH PASS IS THIS?
	SZA CLA 		/IGNORE FIX ON PASS2 OR PASS3
	POPJ 		/EXIT
	TAD I MCRIPA	/ONE MORE MEMORY
	TAD M4 		/REFERENCE INSTRUCTION
	DCA I MCRIPA
	POPJ 		/EXIT
MCRIPA,	MICRP
/ROUTINE TO HANDLE PARAMETER ASSIGNMENTS
/ALLOWS FOR MULTIPLE DEFINITIONS OF THE TYPE A=B=C=...=1
/LENGTH: 28 REGISTERS

EQUAL,	TAD TEM3 		/GET ENTRY ADDRESS OF SYMBOL
	DCA TEM5 		/SAVE IT IN A SPECIAL TEMP REGISTER
	TAD I TEM5 	/MAKE THE SYMBOL DEFINED
	CLL
	SMA
	CML 		/ALREADY DEFINED C(L)=1
	AND MASK
	DCA I TEM5 	/PUT IT BACK
	SZL
	JMP EQERR 	/REDEFINING
DEFGO,	TAD C3
	TAD TEM5
	PUSH 		/PUSH IT DOWN FOR POSSIBLE RECURSION
	PUSHJ 		/RECURSIVE CALL TO PROCESSOR
	CSYM 		/ADDRESS FOR PUSHJ ROUTINE
	POP 		/GET THE LATEST SYMBOL VALUE ADDRESS
	DCA TEM5 		/PUT IT BACK IN TEM5
	TAD BINW 		/PICK UP THE BINARY VALUE
	DCA I TEM5 	/STORE IT AS THE VALUE OF THE SYMBOL
	DCA INFO 		/NO PUNCHING
	POPJ 		/EXIT
EQERR,	TAD TEM5 		/ADDRESS OF SYMBOL
	PUSH
	TAD P10
	PUSHJ 		/RD CODE=10
	ERROR1 		/ERROR TYPE 1
	JMP DEFGO 	/NOW DEFINE IT
P10,	0010





/PAGE 41

/ERROR MESSAGE TABLE
TABLE,	2501 		/UA
	0424 		/DT
	2324 		/ST
	1103 		/IC
	1122 		/IR
	2017 		/PO
	2025 		/PU
	2204 		/RD

/INCLUSIVE OR ROUTINE
/ENTER WITH ONE ARGUMENT IN C(AC);
/AND WITH THE OTHER IN SYMVAL
/SYMVAL IS UNCAHNGED; ANSWER IN C(AC)
/LENGTH: 7 REGISTERS

IOR,	0
	DCA ITEM		/SAVE C(AC)
	TAD SYMVAL		/PICK UP ARGUMENT
	CMA
	AND ITEM		/PERFORM OPERATION
	TAD SYMVAL
	JMP I IOR		/EXIT

/ROUTINE TO OUTPUT TABS OR TABSTOPS
/DEPENDING ON SET OF BIT 10
/BIT 10=0, OUTPUT TAB RUBOUT FOR TAB
/BIT 10=1, OUTPUT SPACES TO NEXT TAB STOP
/LENGTH:23 REGISTERS

TAB,	OSR		/CHECK TABSTOP SWITCH
	RTR		/BIT 10
	SZL CLA
	JMP TABSTP	/OUTPUT SPACES FOR TABS
	TAD C211	/TAB
	JMS I DDD
	TAD C377	/RUBOUT
	JMS I DDD
	JMP I BACK	/RETURN
TABSTP,	TAD I CNT	/OUTPUT 8 SPACES MINUS NUMBER OF CHARACTERS
	TAD MTABS
	SMA
	JMP .-2
	DCA I CNT
	TAD SP		/OUTPUT ONE SPACE
	JMS I DDD
	ISZ I CNT
	JMP .-3
	JMP I BACK	/RETURN

MTABS,	-10
BACK,	PART4
CNT,	TCNT
SP,	240

BINPUN,	CLL		/CLEAR LINK FOR BIN PUNCH
	TAD CKSM		/PUNCH CHECKSUM
	JMS I PUNI
	JMS I LDTI	/PUNCH LEADER TRAILER
	JMP I NEXI	/GO TO NEXT PASS


L22,			/END OF PAGE




/SYMBOL TABLE

/PSEUDO-OPS
OPTABL,	0611 		/FIELD
	0514
	0400
	FLD

	0530		/EXPUNGE
	2025
	1607
	EXPN

	0611 		/FIXMRI
	3015
	2211
	FIXY

	2001 		/PAUSE
	2523
	0500
	STOP

	0611 		/FIXTAB
	3024
	0102
	FIXT

	0405		/DECIMAL
	0311
	1501
	DECMA

	1703 		/OCTAL
	2401
	1400
	OCTALP

	1100 		/I
	0000
	0000
	INDI

	3200 		/Z
	0000
	0000
	ZPAGE







/MEMORY REFERENCE INSTRUCTIONS

OPCD,	0116 		/AND
	0400
	0000
	0000

	2401 		/TAD
	0400
	0000
	1000

	1123 		/ISZ
	3200
	0000
	2000

	0403 		/DCA
	0100
	0000
	3000

	1215 		/JMS
	2300
	0000
	4000

	1215 		/JMP
	2000
	0000
	5000

	0605 		/FEXT
	3024
	0000
	0000

	0601 		/FADD
	0404
	0000
	1000

	0623 		/FSUB
	2502
	0000
	2000

	0615 		/FMPY
	2031
	0000
	3000

	0604 		/FDIV
	1126
	0000
	4000

	0607 		/FGET
	0524
	0000
	5000

	0620 		/FPUT
	2524
	0000
	6000

	0616 		/FNOR
	1722
	0000
	7000

/INTERNAL IOT'S

MICR,	1117 		/ION
	1600
	0000
	6001

	1117 		/IOF
	0600
	0000
	6002

	2313		/SKON
	1716
	0000
	6000

	2322		/SRQ
	2100
	0000
	6003

	0724		/GTF
	0600
	0000
	6004

	2224		/RTF
	0600
	0000
	6005

	2307		/SGT
	2400
	0000
	6006

	0301		/CAF
	0600
	0000
	6007

/HIGH SPEED PERFORATED TAPE READER AND CONTROL 
	2223 		/RSF
	0600
	0000
	6011

	2222		/RRB
	0200
	0000
	6012

	2206 		/RFC
	0300
	0000
	6014

	2203		/RCC
	0300
	0000
	6016

/HIGH SPEED READER/PUNCH COMBINATION
	2220		/RPE
	0500
	0000
	6010

	2003		/PCE
	0500
	0000
	6020


/HIGH SPEED PERFORATED TAPE PUNCH AND CONTROL
	2023 		/PSF
	0600
	0000
	6021

	2003 		/PCF
	0600
	0000
	6022

	2020 		/PPC
	0300
	0000
	6024

	2014 		/PLS
	2300
	0000
	6026

/TELETYPE KEYBOARD/READER
	1323 		/KSF
	0600
	0000
	6031

	1303 		/KCC
	0300
	0000
	6032

	1322 		/KRS
	2300
	0000
	6034

	1322 		/KRB
	0200
	0000
	6036

	1303		/KCF
	0600
	0000
	6030

	1311		/KIE
	0500
	0000
	6035

/TELETYPE TELPRINTER/PUNCH
	2423 		/TSF
	0600
	0000
	6041

	2403 		/TCF
	0600
	0000
	6042

	2414 		/TLS
	2300
	0000
	6046

	2420		/TPC
	0300
	0000
	6044

	2406		/TFL
	1400
	0000
	6040

	2423		/TSK
	1300
	0000
	6045




/GROUP 1 OPERATE MICROINSTRUCTIONS
	1617 		/NOP
	2000
	0000
	7000
	1101 		/IAC
	0300
	0000
	7001
	2201 		/RAL
	1400
	0000
	7004
	2224 		/RTL
	1400
	0000
	7006
	2201 		/RAR
	2200
	0000
	7010
	2224 		/RTR
	2200
	0000
	7012
	0315 		/CML
	1400
	0000
	7020
	0315 		/CMA
	0100
	0000
	7040
	0314 		/CLL
	1400
	0000
	7100
	0314 		/CLA
	0100
	0000
	7200

	0223		/BSW
	2700
	0000
	7002




/GROUP 2 OPERATE MICRO INSTRUCTIONS
	1014 		/HLT
	2400
	0000
	7402
	1723 		/OSR
	2200
	0000
	7404
	2313 		/SKP
	2000
	0000
	7410
	2316 		/SNL
	1400
	0000
	7420
	2332 		/SZL
	1400
	0000
	7430
	2332 		/SZA
	0100
	0000
	7440
	2316 		/SNA
	0100
	0000
	7450
	2315 		/SMA
	0100
	0000
	7500
	2320 		/SPA
	0100
	0000
	7510





/COMBINED MICROINSTRUCTIONS
	0311 		/CIA
	0100
	0000
	7041

	1401 		/LAS
	2300
	0000
	7604

	2324 		/STL
	1400
	0000
	7120

	0714 		/GLK
	1300
	0000
	7204

	2324 		/STA
	0100
	0000
	7240

/MQ MICROINSTRUCTIONS
	1521		/MQL
	1400
	0000
	7421

	1521		/MQA
	0100
	0000
	7501

	0301		/CAM
	1500
	0000
	7621

	2327		/SWP
	2000
	0000
	7521

	0103		/ACL
	1400
	0000
	7701
	/MEMORY EXTENSION CONTROL TYPE MC8/I,MC8/L

	0304	/CDF
	0600
	0000
	6201

	0311	/CIF
	0600
	0000
	6202

	2204	/RDF
	0600
	0000
	6214

	2211	/RIF
	0600
	0000
	6224

	2211	/RIB
	0200
	0000
	6234

	2215	/RMF
	0600
	0000
	6244

	0304	/CDI
	1100
	0000
	6203





/END OF PROGRAM

SYTA,	0 		/BEGINNING OF USER SYMBOLS
	$