/BASIC.L8E
/			L A B - 8 \ E   B A S I C
/
/		COPYRIGHT 1971, DIGITAL EQUIPMENT CORPORATION
/		MAYNARD, MASS. (01754)
/
/		WRITTEN BY JACK BURNESS
/			THIS BASIC IS A COMBINATION OF LAB-8/E BASIC
/			AND 8K-BASIC FOR THE PDP-8. TO CREATE IT
/			FOR THE LAB-8/E SET "MACHINE=1", TO CREATE IT FOR
/			THE PDP-8 SET "MACHINE=0".
	MACHINE=0
/			THIS CODE OVERLAYS THE BINARY LOADER IN FIELD
/			ONE TO MAKE LAB-8/E BASIC SELF STARTING.
/BASIC4.52
	FIELD	0		/TO HELP BINARY LOADER IN CASE HE BLOWS IT.
/00000	+----------+
/	!  SYSTEM  !
/11000	+----------+
/	!  ARRAY   !
/	!  SPACE   !
/	+----------+
/	!  FREE    !
/	+----------+
/	! CODIFIED !
/	!  BASIC   !
/	+----------+
/	!  SYMBOL  !
/	!  TABLE   !
/	+----------+
/	!  LINEBUF !
/	+----------+
/	!  STACK   !
/	+----------+
/	!  FORLIST !
/	+----------+
/	!  GOLIST  !
/17756	+----------+
/	!   RIM    !
/	!  LOADER  !
/17777	+----------+
/4200	+
/4201	-
/4302	*
/4303	/
/4404	^
/4105	=
/4106	<
/4107	>
/4110	<=
/4110	=<
/4111	>=
/4111	=>
/4112	<>
/4213	(UMINUS)
/4014	(DONE)
/4015	,
/4016	;
/4017	)
/4021	TO
/4022	STEP
/4023	(
/4024	FN
/4025	COS
/4026	TAN
/4027	ATN
/4030	LOG
/4031	EXP
/4032	SQR
/4033	ABS
/4034	SGN
/4035	INT
/4036	RND
/4037	SIN
/6000	(CRLF)
/6000	\
/6001	END
/6002	FOR
/6003	GOSUB
/6004	GOTO
/6004	THEN
/6005	IF
/6006	INPUT
/6007	LET
/6010	NEXT
/6011	PRINT
/6012	RETURN
/6013	STOP
/6014	DIM
/6015	RESTORE
/6017	DEF
/6020	READ
/6021	DATA
/6022	(EXIT)
/6023	(EOF)
FEXIT=0000
FSNE=0040
FSEQ=0050
FSGE=0100
FSLT=0110
FSGT=0140
FSLE=0150
FJMP=1000
FJMPI=1400
FST=2000
FSTI=2400
FLD=3000
FLDI=3400
FAD=4000
FADI=4400
FSB=5000
FSBI=5400
FMP=6000
FMPI=6400
FDV=7000
FDVI=7400
FWD=200
BKWD=600
ADCL=6530
ADLM=6531
ADST=6532
ADRB=6533
ADSK=6534
ADSE=6535
ADLE=6536
ADRS=6537
DILC=6050
DICD=6051
DISD=6052
DILX=6053
DILY=6054
DIXY=6055
DILE=6056
DIRE=6057
CLEN=6134
CLAB=6133
CLOE=6132
CLZE=6130
CLSK=6131
CLCA=6137
CLSA=6135
CLBA=6136
*0
	0			/INTERUPT ROUTINES.
	JMP I	.+1		/UP, UP AND AWAY.
	INTER
ARRLOC,	0
CODELOC,0
PSYMTAB,0
NSYMTAB,0
O215,	215
O212,	212
O260,	260
OV,	0
INDEX1,	0
INDEX2,	0
DISAUTO,0
AC3,	0
AC2,	0
AC1,	0
OP3,	0
OP2,	0
OP1,	0
ACS,	0
ACE,	0
OPS,	0
O177,	177
OPE,	0
TMP,	0
PGETCH,	GETCH
PPUTCH,	PUTCH
DIMFLAG,0
FENTER=JMS I .;FPT
PDL,	0
PLINBUF,LINBUF
MLINBUF,-LINBUF
MENDLIN,-ENDLIN
PRTEMP,	0
DECEXP,	0
PNUMBUF,NUMBUF
LOCCTR,	0
READLOC,0
PARGERR,ARGERR
WORD,	0
O240,	240
LINENO,	0
GOTEMP,	0
O7740,	7740
O7770,	7770
EPTR,	0
FPTR,	0
GPTR,	0
HPTR,	0
O2,	2
FORCT,	0
SNUMFLG,0
O12,	12
OLDOP,	0
ADDRESS,0
O77,	77
O377,	377
O7,	7
OPERAND,0;0;0
PTEXT,	XXTEXT
PERROR,	ERROR
PSXERR,	SXERR
PEVAL,	EVAL
PGETADD,GETADDR
PEXECUT,EXECUTE
PPUSH,	PUSH
PPOP,	POP
PFIX,	FIX
PGOTOPR,GOTOPR
PPASSCR,PASSCR
PGETOPR,GETOPR
PSTOVAR,STOVAR
PGETVAR,GETVAR
PPRINTX,PRINTXT
PGETBLK,GETBLK
PSLOOP,	SLOOP
POUTNUM,OUTNUM
PEDIT,	EDIT
PSTICKI,STICKIT
PNONBLN,NONBLNK
PPRINUM,PRINUM
PGETLIN,GETLIN
PPDLIST,PDLIST
COLUMN,	0
INDEV,	0
OUTD2,	0
OUTDEV,	0
ODEV,	0
CNTLO,	0
NOINT,	0			/THIS PREVENTS INTERUPTS DURING CRITICAL TIMES.
RBSWCH,	0
DISB,	0
PRESET,	RESET1
SPECINT,CCINTK
PCOWT,	COWT
DELOUT,	OUTDEL
CNCLR,	CLRCNT
SPLEFT,	RMLEFT
PTEN,	TEN
PANORM,	ANORM
PAR1,	AR1
PAL1,	AL1
ONE,	2014
ZERO,	0;0;0
O200,	200
FPFLAG,	0
POADD,	OADD
O4,	4
PLINFIX,LINFIX
O7745,	7745
PCHKFIT,CHKFIT
PGOLIST,GOLIST
GSBPTR,	0
GET=1
ISIT=JMS I .;XISIT;XGISIT
MUSTBE=JMS I .;XMUST;XGMUST
PLBEGIN,LBEGIN
MLBEGIN,-LBEGIN-1
MLEND,	-ENDPDL
PISITLI,ISITLIT
	PAGE
	*.-1
GETWD,	0
	TAD I	LOCCTR
	DCA	WORD
	ISZ	LOCCTR
	JMP I	GETWD
PLETDO,	LETDO
LETDO,	MUSTBE		/'='
	3673
	JMS I	PEVAL
	MUSTBE		/(CR) OR '\'
	2000
	JMS	STOVAR
EXECUTE,JMS	GETWD
	TAD	PLETDO
	DCA	GETVAR
	TAD I	WORD
	SPA
	JMP	KEYWD
	SZA CLA		/IS IT A LINENO
	JMP	NOTKWD	/NO
	TAD	WORD
	DCA	LINENO
	JMS	GETWD
	TAD I	WORD
	SMA CLA
	JMP	NOTKWD
KEYWD,	CLA CLL CML RTR
	TAD I	WORD
	SNL		/IS IT A STATEMENT WORD
	JMP I	PSXERR	/NO
	TAD	SJUMP
	DCA	.+1
	HLT
SJUMP,	JMP I	.+1
	EXECUTE
	END
	FOR
	GOSUB
	GOTO
	IF
	INPUT
	LET
	NEXT
	PRINT
	RETURN
	STOP
	DIM
	RESTORE
	SKIPIT
	DEF
	READ
	SKIPIT
	EXIT
	STOP
	TTYIN
	TTYOUT
	LPTOUT
	PTPOUT
	PTRIN
	SXERR			/THIS SLOT IS NOW FREE. (6031)
	RUBO
	NORUBO
	IFNZRO	MACHINE<
	CLEAR
	DELAY
	USE
	PLOT
	REALTIME
	SETRATE
	SETCLOCK
	WAITC
	WAIT
	SXERR			/"UCOM" --- USER COMMAND.
	ACCEPT
	REJECT>
	IFZERO	MACHINE<
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
	SXERR
		>
GETVAR,	0
LET,	JMS	GETWD
NOTKWD,	MUSTBE		/A VARIABLE
	7000
	TAD	WORD
	DCA	VAR
	DCA	SSONE
	DCA	SSTWO
	GET+ISIT		/'('
	3755
	JMP I	GETVAR	/NO
	JMS I	PEVAL
	JMS I	PFIX
	DCA	SSONE
	ISIT		/','
	3763
	JMP	NOCOMMA	/NO
	JMS I	PEVAL
	JMS I	PFIX
	DCA	SSTWO
NOCOMMA,MUSTBE		/')'
	3761
	JMS	GETWD
	JMP I	GETVAR
STOVAR,	0
	JMS I	PGETADDR
VAR,	0
SSONE,	0
SSTWO,	0
	FENTER
	FSTI	ADDRESS
	FEXIT
	JMP I	STOVAR
FNERR,	JMS I	PERROR
	TEXT 'FUNCTION'
CLRCNT,	0			/ROUTINE WHICH CHECKS STATUS OF CONTROL C FLAG.
	CLA IAC
	TAD	NOINT		/WAS IT SET TO -1?
	SNA CLA
	JMP I	PBOMB		/YEP. GIVE STOP MESSAGE.
	DCA	NOINT		/NOPE. RESET IT.
	JMP I	CLRCNT		/AND EXIT
PBOMB,	CNTLCR
SPACERR,JMS I	PERROR
	TEXT 'TOO-BIG'
IF,	JMS I	PEVAL
	FENTER
	FST	OPERAND
	FEXIT
	MUSTBE		/'THEN'
	1774
	TAD	OPERAND
	SPA SNA CLA
	JMP	SKIPIT
	GET+ISIT	/A LINENO
	0000
	JMP I	XEXECU
	JMP	GOTO+1
XEXECU,	EXECUTE+1
FOR,	GET+MUSTBE	/A VARIABLE
	7000
	JMS	FINDIT
	JMP	NOTHERE
	CLA IAC
	TAD	INDEX1
	DCA	INDEX2
	CLA CMA
	TAD	INDEX1
	DCA	INDEX1
	JMP	INLUPF
LUPF,	TAD I	INDEX2
	DCA I	INDEX1
	TAD I	INDEX2
	DCA I	INDEX1
INLUPF,	ISZ	GOTEMP
	JMP	LUPF
	ISZ	FORCT
NOTHERE,TAD	FORCT
	TAD	O11
	SPA SNA CLA		/CAN'T FIT 9 IN FORLIST
	JMP	FORERR
	TAD	WORD
	CIA
	DCA I	INDEX1
	TAD	WORD
	DCA	FORVAR
	GET+MUSTBE	/'='
	3673
	JMS I	PEVAL
	JMS I	PGETADDR
FORVAR,	0
	0
	0
	FENTER
	FSTI	ADDRESS
	FEXIT
	MUSTBE		/'TO'
	3757
	TAD	LOCCTR
	DCA I	INDEX1
	CLA CMA
	TAD	FORCT
	DCA	FORCT
SKIPIT,	JMS I	PIGNORE		/LOOK FOR "\" OR C.R.
	JMP I	PEXECUTE	/AND EXECUTEPTHE NEXT STATEMENT.
PIGNORE,IGNORE
PASSCR,	0			/THIS LOOKS FOR A REAL C.R.
	JMS I	PIGNORE		/LOOK FOR "\" OR C.R.
	ISZ	WORD
	ISIT
	4100			/A REAL C.R. ?
	JMP	.-4		/NOPE. A SLASH.
	JMP I	PASSCR		/AND RETURN TO CALLER.
FORERR,	JMS I	PERROR
	TEXT 'FOR'
O11,	11
GOSUB,	JMS	GETWD
	JMS	GOBOTH
	TAD	GSBPTR
	TAD	MGSBEND
	SNA CLA
	JMP	DEEPERR
	TAD	LOCCTR
	DCA I	GSBPTR
	ISZ	GSBPTR
	JMP	GOTO+2
GOTO,	JMS	GETWD
	JMS	GOBOTH
	ISZ	GOTEMP
	TAD I	GOTEMP
	DCA	LOCCTR
	JMP I	PEXECUTE
MGSBEND,-GSBEND
DEEPERR,JMS I	PERROR
	TEXT 'GOSUB'
GOBOTH,	0
	MUSTBE		/A LINENO
	0000
	TAD	WORD
	DCA	GOTEMP
	ISZ	WORD
	ISIT		/DEFINED
	0000
	JMP	ISITDF
	JMS I	PERROR
	TEXT 'LINENO'
ISITDF,	GET+MUSTBE	/(CR) OR '\'
	2000
	JMP I	GOBOTH
VARTEMP,0;0;0
PXFORLI,FORLIST-1
FINDIT,	0
	TAD	FORCT
	DCA	GOTEMP
	TAD	PXFORLIST
	DCA	INDEX1
	JMP	INLOOP
FINDLUP,TAD I	INDEX1
	TAD	WORD
	SNA CLA
	JMP	FOUND
	ISZ	INDEX1
INLOOP,	ISZ	GOTEMP
	JMP	FINDLUP
	JMP I	FINDIT
FOUND,	ISZ	FINDIT
	JMP I	FINDIT
	PAGE
NEXT,	GET+MUSTBE	/A VARIABLE
	7000
	JMS I	PFINDIT
	JMP	NEXTERR
	TAD	WORD
	DCA	NEXTVAR
	GET+MUSTBE	/(CR) OR '\'
	2000
	TAD	LOCCTR
	DCA	LOCTEMP
	TAD I	INDEX1
	DCA	LOCCTR
	JMS I	PEVAL
	FENTER
	FST+FWD+FORLIM-.
	FEXIT
	ISIT		/(CR) OR '\'
	2000
	JMP	TRYSTEP	/NO
	FENTER
	FLD	ONE
	FJMP+FWD+GOTSTEP-.
TRYSTEP,MUSTBE		/'STEP'
	3756
	JMS I	PEVAL
	MUSTBE		/(CR) OR '\'
	2000
	FENTER
GOTSTEP,FST+FWD+FORSTEP-.
	FEXIT
	JMS I	PGETADDR
NEXTVAR,0
	0
	0
	FENTER
	FLDI	ADDRESS
	FAD+FWD+FORSTEP-.
	FST+BKWD+.-VARTEMP
	FSB+FWD+FORLIM-.
	FEXIT
	TAD	ACS
	TAD	FORSTEP
	SMA CLA
	TAD	AC1
	SZA CLA
	JMP	FORDONE
	FENTER
	FLD+BKWD+.-VARTEMP
	FSTI	ADDRESS
	FEXIT
	JMP I	PEXECUTE
FORDONE,TAD	LOCTEMP
	DCA	LOCCTR
	ISZ	FORCT
	ISZ	GOTEMP
	JMP	.-2
	JMP I	PEXECUTE
LOCTEMP,0
PFINDIT,FINDIT
NEXTERR,JMS I	PERROR
	TEXT 'NEXT'
RETURN,	GET+MUSTBE	/(CR) OR '\'
	2000
	TAD	GSBPTR
	TAD	MGOLIST
	SNA CLA
	JMP	RETNERR
	CLA CMA
	TAD	GSBPTR
	DCA	GSBPTR
	TAD I	GSBPTR
	DCA	LOCCTR
	JMP I	PEXECUTE
RETNERR,JMS I	PERROR
	TEXT 'RETURN'
MGOLIST,-GOLIST
FORLIM,	0;0;0
FORSTEP,0;0
SGN,	0
	FENTER
	FSGE
	FLD+FWD+MNSONE-.
	FSLE
	FLD	ONE
	FEXIT
	JMP I	SGN
MNSONE,	6014;0;0
PUTCH,	0
	DCA	SGN
	TAD	SGN
PCCUNT,	AND	O177
	TAD	O7763A
	SZA CLA			/IS IT A C.R.
	JMP	PNOCR		/NOPE.
	TAD	PCCUNT		/ADD IN EXTRA PLACES FOR GOOD LUCK.
	TAD	COLUMN		/SAVE COLUMN POSITION
	DCA	NEXTVAR
	DCA	COLUMN
	TAD	NEXTVAR		/REGET WHERE WE WERE.
	AND	PUTXRA		/ARE WE INSERTING NULL CHARACTERS?
	CLL RAR			/NOW DIVIDE BY 2.
PNOCR,	CLL CML CMA RAR		/AND NOW INVERT AND DIVIDE BY 2 AGAIN.
	DCA	NEXTVAR		/SAVE FOR LATER USE. THIS IS NULL COUNTER.
	TAD	SGN		/RECALL THE CHARACTER.
	AND	O140A
	SZA
	TAD	O7640A
O7640A,	SZA CLA
	ISZ	COLUMN
	TAD	SGN
	JMS I	JPUTCH
	ISZ	NEXTVAR		/INCREMENT THE COUNTER
	JMP	.-2		/GIVE NULLS UNTIL IT'S SATISFIED.
	JMP I	PUTCH
O7763A,	7763
O140A,	140
PUTXRA,	0			/NULL AFTER C.R. WORD.
JPUTCH,	PUTER
	PAGE
START,	JMS I	XRESTA		/REST FLAGS AND DEVICES.
	JMP I	.+1
	SCRATCH
XRESTA,	ISET
EVAL,	0
	JMS	GETWD
	TAD	EVAL
EVALGO,	JMS I	PPUSH
	TAD	O4014
	JMS I	PPUSH
	JMP	GETOPR+1
ISUMIN,	TAD	O4213
	JMS I	PPUSH
GETOPR,	JMS	GETWD
	ISIT		/'-'
	3577
	SKP
	JMP	ISUMIN
	ISIT		/'+'
	3600
	SKP
	JMP	GETOPR
	ISIT		/'('
	3755
	JMP	NOPAREN	/NO
	JMS	EVAL
	MUSTBE		/')'
	3761
	JMP I	PGOTOPR
NOPAREN,ISIT		/A VARIABLE
	7000
	JMP	NOTVAR	/NO
	DCA	ONESS
	DCA	TWOSS
	TAD	WORD
	DCA	WDTEMP
	GET+ISIT	/'('
	3755
	JMP	GOTSS	/NO
	TAD	WDTEMP
	JMS I	PPUSH
	JMS	EVAL
	ISIT		/','
	3763
	JMP	ONEDIM
	JMS I	PFIX
	JMS I	PPUSH
	JMS	EVAL
	JMS I	PFIX
	DCA	TWOSS
	JMS I	PPOP
	JMP	.+3
ONEDIM,	DCA	TWOSS
	JMS I	PFIX
	DCA	ONESS
	MUSTBE		/')'
	3761
	JMS I	PPOP
	DCA	WDTEMP
	JMS	GETWD
GOTSS,	JMS I	PGETADDR
WDTEMP,	0
ONESS,	0
TWOSS,	0
	FENTER
	FLDI	ADDRESS
	FEXIT
	JMP I	.+1
	OPDONE
NOTVAR,	JMS I	PISITLIT /ISIT A LITERAL
	JMP	ISITFUN	/NO
	JMP I	PGOTOPR	/IT IS IN THE AC NOW
ISITFUN,TAD I	WORD
	TAD	O3754		/-4024, WHICH IS BEGINNING OF FUNCTIONS.
	SPA			/IS IT A LEGAL FUNCTION?
	JMP I	PSXERR		/NO. EXIT WITH MESSAGE.
	SNA			/WAS IT 'FN'
	JMS	GETWD		/YES,SKIP OVER LETTER
	JMS I	PPUSH
	GET+MUSTBE		/'('
	3755
	JMS	EVAL
	JMS I	PPOP
	TAD	FJUMP
	DCA	.+1
	HLT
	JMP I	.+1
	FNEXIT
FJUMP,	JMS I	FUNTAB
FUNTAB,	FN
	COS
	TAN
	ATN
	LOG
	EXP
	SQR
	ABS
	SGN
	INT
	RND
	SIN
	PUTJ			/POINTER TO PUT CHAR ROUTINE.
	SXERR			/FOR THE MISC. FUNCTIONS.
	SXERR
	SXERR
	GETJ			/GET A CHAR FROM THE TTY.

	IFZERO	MACHINE<
	SXERR
	TST
	SXERR
		>
	TAB			/TAB FUNCTION IS IMPLEMENTED.
	SXERR			/UNIMPLEMENTED USER FUNCTION.

	IFZERO	MACHINE<
	SXERR
	SXERR
	SXERR
		>
O3754,	3754
O4014,	4014
O4213,	4213
	OBLOW=.
	OBHIGH=FNEXIT-1
	PAGE
FNEXIT,	MUSTBE		/')'
	3761
GOTOPR,	JMS	GETWD
OPDONE,	JMS I	PPOP
	DCA	OLDOP
	TAD I	WORD
	AND	O700
	SNA CLA
	JMP	ITSOP
	TAD I	WORD
	AND	O7077
	TAD	O3755
	CLL
	TAD	O23
	SNL CLA
	JMP I	PSXERR
ITSOP,	TAD	OLDOP
	AND	O700
	DCA	OTEMP
	TAD I	WORD
	AND	O700
	CIA
	TAD	OTEMP
	SMA CLA
	JMP	DOITNOW
	TAD	OLDOP
	JMS I	PPUSH
	FENTER
	FST	OPERAND
	FEXIT
	TAD	OPERAND
	JMS I	PPUSH
	TAD	OPERAND+1
	JMS I	PPUSH
	TAD	OPERAND+2
	JMS I	PPUSH
	TAD I	WORD
	JMS I	PPUSH
	JMP I	PGETOPR
DOITNOW,TAD	OLDOP
	AND	O77
	TAD	O7764A
	SNA
	JMP	UDOPER
	IAC
	SNA CLA
	JMP	UMOPER
	TAD	OLDOP
	AND	O77
	TAD	OJUMP
	DCA	OTEMP
	JMS I	PPOP
	DCA	OPERAND+2
	JMS I	PPOP
	DCA	OPERAND+1
	JMS I	PPOP
	DCA	OPERAND
OTEMP,	HLT
O700,	700
O3755,	3755
O7764A,	7764
O7077,	7077
OJUMP,	JMP I	.+1
	PLUS
	MINUS
	STAR
	SLASH
	UPARRX	/OR 'UPARROW' IF NO EXTENDED FNS
	RELATE
	RELATE
	RELATE
	RELATE
	RELATE
	RELATE
PLUS,	FENTER
	FAD	OPERAND
FADEXT,	FEXIT
	JMP	OPDONE
MINUS,	FENTER
	FSB	OPERAND
	FEXIT
UMOPER,	TAD	AC1
	SZA CLA
	CLA CLL CML RAR
	TAD	ACS
	DCA	ACS	/DIRECT REF TO FLOATING AC
	JMP	OPDONE
STAR,	FENTER
	FMP	OPERAND
	FJMP+BKWD+.-FADEXT
SLASH,	FENTER
	FST+FWD+SLSHTMP-.
	FLD	OPERAND
	FDV+FWD+SLSHTMP-.
	FJMP+BKWD+.-FADEXT
SLSHTMP,0;0;0
RELATE,	TAD	OLDOP
	TAD	CONST
	DCA	THESKIP
	CDF	0		/''''''''' 8 K INSERT.
	TAD I	THESKIP
	CDF	10		/''''''''' 8 K INSERT.
	DCA	THESKIP
	FENTER
	FSB	OPERAND
THESKIP,HLT
	FJMP+FWD+4
	FLD	ONE
	FEXIT
	JMP	OPDONE
	FLD	ZERO
	FEXIT
	JMP	OPDONE
UDOPER,	JMS I	PPOP
	DCA	OLDOP
	JMP I	OLDOP
O23,	23
CONST,	.-4104
	FSEQ		/  =
	FSGT		/  <
	FSLT		/  >
	FSGE		/  <=
	FSLE		/  >=
	FSNE		/  <>
	PAGE
GETADDR,0
	CDF	0		/''''''''''' 8 K INSERT.
	TAD I	GETADDR
	DCA	INDEX2
	ISZ	GETADDR
	TAD I	GETADDR
	DCA	GSS1
	ISZ	GETADDR
	TAD I	GETADDR
	DCA	GSS2
	ISZ	GETADDR
	CDF	10		/''''''''''' 8 K INSERT.
	TAD I	INDEX2
	DCA	ADDRESS
	ISZ	ADDRESS
	TAD	GSS1
	SNA CLA
	JMP	NOSS1
	TAD I	INDEX2
	SNA
	JMP	ALLOC
	CLL CMA
	TAD	GSS1
	SZL CLA
	JMP	SSERR
	TAD I	INDEX2
	DCA	GDIM2
	TAD	GSS2
	SNA
	JMP	NOSS2
	CLL CIA
	TAD	GDIM2
	SNL CLA
	JMP	SSERR
	TAD	GSS1
	CIA
	DCA	GSS1
	SKP
	TAD	GDIM2
	ISZ	GSS1
	JMP	.-2
	TAD	GSS2
	DCA	GSS1
NOSS2,	TAD	GSS1
	CLL RAL
	TAD	GSS1
	TAD	ADDRESS
	DCA	ADDRESS
NOSS1,	JMP I	GETADDR
ALLOC,	ISZ	DIMFLAG
	SKP
	JMP	ISDIM
	DCA	DIMFLAG
	TAD	GSS2
	SZA CLA
	TAD	O13
	DCA	GSS2
	TAD	O13
	DCA	GSS1
ISDIM,	TAD	GSS2
	SNA
	CLA IAC
	CIA
	DCA	GDIM2
	ISZ	NOINT		/FORBID INTERUPTS NOW.
	CLA CLL IAC
	TAD	GSS1
	SZL
	JMP I	PSPACERR
	ISZ	GDIM2
	JMP	.-4
	DCA	GDIM2
	TAD	GDIM2
	CLL CML RAL
	SNL
	TAD	GDIM2
	DCA	GDIM2
	TAD	GDIM2
	SZL
	JMP I	PSPACERR
	JMS I	SPLEFT
	SKP
	JMP I	PSPACERR
	CLA CLL CMA RAL
	TAD	INDEX2
	DCA	INDEX2
	TAD	ARRLOC
	DCA I	INDEX2
	TAD	GSS1
	DCA I	INDEX2
	TAD	GSS2
	DCA I	INDEX2
	CLA CMA
	TAD	ADDRESS
	DCA	ADDRESS
	TAD	O7774
	DCA	GSS2
	TAD I	ADDRESS
	ISZ	ADDRESS
	JMS I	PSTICKIT
	ISZ	GSS2
	JMP	.-4
	TAD	GDIM2
	CIA
	TAD	O4
	DCA	GDIM2
	JMS I	PSTICKIT
	ISZ	GDIM2
	JMP	.-2
	CLA CLL CMA RTL
	TAD	GETADDR
	DCA	GETADDR
	JMS I	CNCLR		/CHECK FOR CONTROL C.
	JMP	GETADDR+1
GSS1,	0
GSS2,	0
GDIM2,	0
PSPACER,SPACERR
O7774,	7774
O13,	13		/(12) IF 1 ORG INDEXING
SSERR,	JMS I	PERROR
	TEXT 'SUBSCRIPT'
DEF,	TAD	LINENO
	DCA	INDEX1
	TAD I	INDEX1
	DCA	USERFN
	GET+MUSTBE	/'FN'
	3754
	GET+MUSTBE	/A VARIABLE
	7000
	GET+MUSTBE	/'('
	3755
	GET+MUSTBE	/A VARIABLE
	7000
	GET+MUSTBE	/')'
	3761
	GET+MUSTBE	/'='
	3673
	JMP I	PSKIPIT
PSKIPIT,SKIPIT
USERFN,	0
MORERD,	MUSTBE		/','
	3763
READ,	JMS I	PGETVAR
	CLA CMA
	TAD	LOCCTR
	DCA	LOCTMP
	TAD	READLOC
	DCA	LOCCTR
	GET+ISIT	/(CR) OR '\'
	2000
	SKP
	JMP	SEARCH
	ISIT		/A LINENO
	0000
	SKP
	JMP	SEARCH
	ISIT		/','
	3763
	JMP	DATAERR
ISSOME,	JMS I	PEVAL
	CLA CMA
	TAD	LOCCTR
	DCA	READLOC
	TAD	LOCTMP
	DCA	LOCCTR
	JMS I	PSTOVAR
	GET+ISIT	/(CR) OR '\'
	2000
	JMP	MORERD
	JMP I	PEXECUTE
SCHMOR,	JMS	GETWD
SEARCH,	ISIT		/'DATA'
	1757
	SKP
	JMP	ISSOME
	ISIT		/(EOF)
	1755
	JMP	SCHMOR
DATAERR,JMS I	PERROR
	TEXT 'DATA'
LOCTMP,	0
GETBLK,	0
	JMS I	PCHKFIT
	TAD	CODELOC
	DCA	LOCCTR
	TAD	CODELOC
	TAD	ABCDEF
	DCA	CODELOC
	TAD	CODELOC
	DCA	BCDEFG
	TAD	PSYMTAB		/UPDATE SYMBOL TABLE NOW.
	TAD	ABCDEF		/BY ADDING IN CORRECTION FACTOR.
	DCA	PSYMTAB
GTBKLP,	TAD I	LOCCTR		/MOVE TEXT NOW.
	ISZ	LOCCTR
	DCA I	BCDEFG
	ISZ	BCDEFG
	TAD	BCDEFG		/NOW CHECK FOR END.
	CIA
	TAD	PSYMTAB
	SZA CLA
	JMP	GTBKLP
	CLA CMA
	TAD	NSYMTAB
	DCA	NSYMTAB
	TAD	GSBPTR
	CMA
	TAD	PGOLIST
	DCA	BCDEFG
	TAD	PGOLIST
	DCA	WORD
	TAD	ABCDEF
	TAD I	WORD
	DCA I	WORD
	ISZ	WORD
	ISZ	BCDEFG
	JMP	.-5
	TAD	FORCT
	DCA	BCDEFG
	TAD	PPFORLIS
	DCA	WORD
	JMP	.+6
	TAD	ABCDEF
	TAD I	WORD
	DCA I	WORD
	ISZ	WORD
	ISZ	WORD
	ISZ	BCDEFG
	JMP	.-6
	TAD	PSYMTAB
	JMP I	GETBLK
ABCDEF,	-4
BCDEFG,	0
PPFORLI,FORLIST+1
PUTJ,	0
	JMS I	PFIX
	CLA
	TAD	AC3
	JMS I	PPUTCH
	JMS I	PANORM
	JMP I	PUTJ
GETJ,	0			/GETS A CHARACTER FROM THE TTY.
	JMS I	PBEGFIX		/CLEAN UP THE FAC
	JMS I	PGETCH		/FECTH A CHAR.
	DCA	AC3		/SAVE IT, BABY!
	JMS I	PANORM		/AND NORMALIZE AC.
	JMP I	GETJ		/AND RETURN NOW.
PBEGFIX,BEGFIX
	PAGE
NOTNOW,	ISZ	NOINT		/RESET ^C SWITCH SO NO INTERUPT NOW.
	ISZ	WORD
	TAD I	WORD
	SNA
	JMP	INSERT
	DCA	LOWLOC
	DCA I	WORD
	TAD	LOWLOC
	DCA	LOCCTR
	JMS I	PPASSCR
MOVE,	TAD	LOWLOC
	CIA
	TAD	CODELOC
	SNA CLA
	JMP	INSRT5
	CLA CLL CMA
	TAD	LOWLOC
	DCA	LOWLOC
	CLA CLL CMA
	TAD	LOCCTR
	DCA	LOCCTR
	TAD I	LOWLOC
	DCA I	LOCCTR
	JMP	MOVE
INSRT5,	TAD	LOCCTR
	DCA	CODELOC
INSERT,	TAD	FPTR
	TAD	MLINBUF
	CMA
	DCA	FPTR
	CLA CLL CML RTL
	TAD	FPTR
	SNA
	JMP	FIXLIN
	CMA
	JMS I	PCHKFIT
	TAD	CODELOC
	DCA	LOCCTR
	TAD I	PLINBUF
	IAC
	DCA	INDEX1
	TAD I	INDEX1
	DCA	OPERAND
	TAD I	INDEX1
	DCA	OPERAND+1
	JMS	COMPARE
	JMP	NOTFRST
	JMS	SUBRA
	JMP	TRANSF
NOTFRST,JMS I	PPASSCR
	JMS	COMPAR
	JMP	NOTFRST
	TAD	LOCCTR
	DCA	LSTLOC
	TAD	CODELOC
	DCA	LOCCTR
	JMS	SUBRA
	JMS	GETWD
MOVLUP,	TAD	WORD
	DCA I	PUTLOC
	ISZ	PUTLOC
	JMS	GETWD
	TAD	LSTLOC
	CIA
	TAD	LOCCTR
	SZA CLA
	JMP	MOVLUP
TRANSF,	TAD	PLINBUF
	DCA	GPTR
TRALUP,	TAD I	GPTR
	ISZ	GPTR
	DCA I	PUTLOC
	ISZ	PUTLOC
	ISZ	FPTR
	JMP	TRALUP
FIXLIN,	JMS I	PLINFIX
	JMP I	PEDIT
IGNORE,	0			/THIS ROUTINE LOOKS FOR A "\" OR A C.R.
	GET+ISIT
	5000			/TEXT?
	JMP	NOTBAD		/NOPE.
	JMS	GETWD
	TAD	WORD
	AND	O77
	SZA CLA			/END OF TEXT?
	JMP	.-4		/NOPE.
	JMP	IGNORE+1	/YEP. GET NEXT ITEM.
NOTBAD,	JMS I	PISITLIT	/IS IT A LITERAL?
	SKP
	JMP	IGNORE+1	/YES.
	ISIT
	2000			/"\" OR C.R.
	JMP	IGNORE+1	/  N O
	JMP I	IGNORE		/YES. RETURN TO CALLER.
COMPARE,0
	GET+ISIT	/A LINENO
	0000
	JMP	IAMLESS
	TAD	WORD
	IAC
	DCA	INDEX1
	TAD I	INDEX1
	CLL CIA
	TAD	OPERAND
	SZA CLA
	JMP	FRSTNE
	TAD I	INDEX1
	CLL CIA
	TAD	OPERAND+1
FRSTNE,	SNL CLA		/IS OPERAND<THIS LINENO
IAMLESS,ISZ	COMPARE	/YES
	JMP I	COMPARE
LSTLOC,	0
SUBRA,	0
	TAD	FPTR
	CLL
	TAD	CODELOC
	DCA	CODELOC
	TAD	CODELOC
	DCA	PUTLOC
	JMP I	SUBRA
LOWLOC,	0
PUTLOC,	0
PRINT,	JMS	GETWD		/THIS INSTRUCTION MAY BE COMBINED WITH THE
				/GET INSTRUCTION BELOW IF SPACE IS NEEDED.
	CLA CLL CMA RTL		/7775=-3 FOR DEVICE CHECK.
	TAD	OUTDEV		/MULTIPLY DEVICE BY 3.
	TAD	OUTDEV
	TAD	OUTDEV		/SO THAT LPT=6, PTP=3, AND TTY=0.
	TAD	O110		/NOW ADD IN 72. THUS TTY=72,LPT=80.
	DCA	TWIDTH		/AND SAVE FOR FUTURE USE.
	ISIT			/CHECK FOR FIRST COMMA. ONCE ONLY CHECK.
	3763
	JMP	PRINTC		/NO. CONTINUE CHECKING.
	JMP	PRINBLK		/YEP. GIVE BLANK, THEN TAB OVER.
PRINTG,	JMS	GETWD		/GET NEXT ELEMENT AFTER A TEXT ELEMENT.
PRINTC,	DCA	TABFLG		/RESET TAB INDICATER.
	ISIT			/CHECK TO SEE IF CARRIAGE RETURN.
	2000
	JMP	NOPCR		/NOT A CARRIAGE RETURN. CONTINUE CHECKING.
	JMS I	PPRINTXT
	CRLF
	JMP I	PEXECUTE
NOPCR,	ISIT			/IS IT A COMMA (",")
	3763
	JMP	PRENT		/NO. FINISH CHECKING BELOW.
	JMP	PRINCOM		/IT IS. PROCESS THE COMMA NOW.
PRINTHS,ISIT			/TEXT
	5000
	JMP	NOTTXT
PRINQUO,JMS	GETWD
	TAD	WORD
	RTR
	RTR
	RTR
	JMS	PRINHAF
	TAD	WORD
	JMS	PRINHAF
	JMP	PRINQUO
NOTTXT,	TAD	PPRINRET
	JMP I	PEVALGO
PEVALGO,EVALGO
PPRINRE,PRINRET
PRINRET,TAD	TABFLG		/WAS THERE A TAB PRESENT?
	SZA CLA
	JMP I	TABTHR		/YEP. EXECUTE TAB CORRECTER.
	TAD	O14		/SEE IF ROOM FOR 13 PLACES(1+12).
	JMS	CHECKW
	TAD	ACS
	SPA CLA
	JMP	.+3
	TAD	O240
	JMS I	PPUTCH
	JMS I	POUTNUM
	TAD	O240
	JMS I	PPUTCH
	JMP	PRINTC		/GO BACK AND GET NEXT.
PRINHAF,0
	AND	O77
	SNA
	JMP	PRINTG		/GO SKIP PAST TEXT ELEMENT AND CHECK NEXT.
	TAD	OO7736
	SNA
	JMP I	PRINHAF
	TAD	O2
	AND	O77
	TAD	O240
	DCA	ACS		/SAVE CHARACTER FOR A SECOND.
	JMS	CHECKW		/CHECK TO SEE IF IT'LL FIT ON THE LINE.
	TAD	ACS		/RESTORE THE CHARACTER.
	JMS I	PPUTCH
	JMP I	PRINHAF
PRINBLK,CLA			/MAKE SURE AC IS ZERO.
	TAD	O240
	JMS I	PPUTCH
	JMS	CHECKW		/CHECK TO SEE IF ROOM FOR ONE MORE.
PRINCOM,TAD	COLUMN		/SEE IF COLUMN ON COMMA BOUNDRY.
	SNA
	JMP	PRINSEM		/YEP.
	TAD	O7762		/SUBTRACT A LITTLE AN CHECK AGAIN.
	SMA			/TOO FAR?
	JMP	.-4		/NOPE.
	JMP	PRINBLK		/YEP. GIVE BLANK AND LOOP AGAIN.
PRINSEM,GET+ISIT	/(CR) OR '\'
	2000
	SKP
	JMP I	PEXECUTE/YES
PRENT,	ISIT		/';'
	3762
	SKP
	JMP	PRINSEM	/YES
	ISIT		/','
	3763
	JMP	PRINTHS
	JMP	PRINBLK
OO7736,	7736
O7762,	7762
LINFIX,	0
	TAD	CODELOC
	DCA	LOCCTR
LFXLUP,	JMS	GETWD
	TAD I	WORD
	SZA CLA		/IS IT A LINENO
	JMP I	LINFIX	/NO
	ISZ	WORD
	CLA CMA
	TAD	LOCCTR
	DCA I	WORD
	JMS I	PPASSCR
	JMP	LFXLUP
TABFLG,	0			/TAB FOUND FLAG.
CHECKW,	0			/THIS ROUTINE CHECKS FOR LINE TOO LONG.
	TAD	COLUMN		/GET WHERE AT NOW.
	CMA			/-WHEREAT-#OF PLACES IN OUT CHAR.
	TAD	TWIDTH		/ADD IN WIDTH OF DEVICE.
	SMA CLA			/TOO BIG.
	JMP I	CHECKW		/NAH. RETURN TO SENDER.
	JMS I	PPRINTXT	/YEP.GIVE C.R.L.F.
	CRLF
	JMP I	CHECKW		/AND RETURN TO SENDER.
TWIDTH,	0			/0 IS OK SINCE IT'LL BE SET UP CORRECTLY.
O14,	14			/MAGIC CONSTANT.
O110,	110			/WDTH OF TTY PAPER.
TABTHR,	TABDO			/ROUTINE WHICH PROCESS TAB CHARACTER.
MENDPDL,-ENDPDL-1
PUSH,	0
	DCA I	PDL
	ISZ	PDL
	TAD	PDL
	TAD	MENDPDL
	SZA CLA
	JMP I	PUSH
	JMS I	PERROR
	TEXT 'EXPRESSION'
EXIT,	JMS I	PCOWT		/WAIT FOR BUFFER TO EMPTY AND THEN CONTINUE.
	TAD	O215
	JMS I	PPUTCH
EDIT,	TAD	O212
	JMS I	PPUTCH
	TAD	OUTD2		/RESET DEVICE
	DCA	OUTDEV
	JMS I	CNCLR		/CHECK TO SEE IF ^C WAS TYPED.
	TAD	PXXTHEN
	JMS I	PGETLIN
	TAD I	PLINBUF
	DCA	WORD
	TAD I	WORD
	SNA CLA
	JMP I	PNOTNOW
	TAD	O212
	JMS I	PPUTCH
	TAD	OUTD2		/RESET I/O DEVICE.
	DCA	OUTDEV
	ISIT		/'RUN'
	3736
	SKP
	JMP	RUN
	ISIT		/'LIS'
	3737
	SKP
	JMP I	PLIST
	ISIT		/'SCR'
	3735
	JMP	IMMED
SCRATCH,TAD	PPERMSYM
	DCA	CODELOC
	TAD	PXXEOF
	DCA I	PPERMSYM
	TAD	PPERMSYM
	IAC
	DCA	PSYMTAB
	CLA CMA
	DCA	NSYMTAB
	JMS I	PRESET		/RESET DEVICES AFTER SCRATCH.
RUN,	JMS	CLEARV
	JMP I	PEXECUTE
IMMED,	TAD	PLINBUF
	DCA	LOCCTR
	TAD	PXXEOF
	DCA	LINENO
	JMP I	PEXECUTE
PJSET,	SETUP
CLEARV,	0
	JMS I	PJSET
	JMP	RUNIN
RUNLUP,	TAD I	EPTR
	TAD	O7000A
	SZA CLA		/IS IT A VARIABLE
	JMP	RUNNOT	/NO
	ISZ	EPTR
	TAD I	EPTR
	DCA	GPTR
	TAD I	GPTR
	DCA I	EPTR
	SKP
RUNNOT,	ISZ	EPTR
	ISZ	EPTR
	ISZ	EPTR
	ISZ	EPTR
RUNIN,	ISZ	FPTR
	JMP	RUNLUP
	TAD	PLIMIT
	DCA	ARRLOC
	TAD	PSYMTAB
	DCA	EPTR
	TAD	NSYMTAB
	DCA	FPTR
	JMP	RUN2IN
RUN2LUP,TAD I	EPTR
	TAD	O7000A
	SZA CLA		/IS IT A VARIABLE
	JMP	RUN2NOT	/NO
	ISZ	EPTR
	TAD I	EPTR
	DCA	TMP
	TAD	ARRLOC
	DCA I	EPTR
	TAD	TMP
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	ISZ	EPTR
	DCA I	EPTR
	ISZ	EPTR
	DCA I	EPTR
	JMP	.+4
RUN2NOT,ISZ	EPTR
	ISZ	EPTR
	ISZ	EPTR
	ISZ	EPTR
RUN2IN,	ISZ	FPTR
	JMP	RUN2LUP
	TAD	CODELOC
	DCA	LOCCTR
	TAD	PPDLIST
	DCA	PDL
	TAD	CODELOC
	DCA	READLOC
	CLA CMA
	DCA	FORCT
	TAD	PGOLIST
	DCA	GSBPTR
	JMP I	CLEARV
O7000A,	7000
PLIMIT,	LIMIT		/FIRST WORD OF USER AREA
PXXTHEN,XXTHEN
PLIST,	LIST
PXXEOF,	XXEOF
PPERMSY,PERMSYM
PNOTNOW,NOTNOW
END,	JMS	CLEARV
STOP,	JMS I	PRESET		/RESET ALL DEVICES NOW,
	JMS I	PCOWT		/AND WAIT FOR I/O TO FINISH UP.
	JMS I	PPRINTXT	/AND GIVE THE STOP MESSAGE
	READY
	JMP I	PEDIT
	PAGE
GETLRET,JMS I	PLINFIX
	JMS I	CNCLR		/CHECK TO SEE IF ^C WAS TYPED WHILE HERE.
	JMP I	GETLIN
GETLIN,	0
	DCA	SNUMFLG
	TAD	OUTDEV		/GET THE OUTPUT DEVICE.
	DCA	OUTD2		/SAVE FOR A SECOND.
	DCA	OUTDEV		/TURN OFF THE OUTPUT DEVICE.
NEWLIN,	TAD	PLBEGIN
	DCA	EPTR
	TAD	O40
	DCA I	EPTR
	ISZ	EPTR
NEWCHAR,JMS I	PGETCH
	DCA I	EPTR
	CLA CMA			/CHECK THE INPUT DEVICE NOW.
	TAD	INDEV		/GET IT, BABY.
	SZA CLA			/IS IT THE TTY?
	JMP	.+4		/NOPE.
	DCA	CNTLO		/IT IS. RESET CONTROL O.
	CLA IAC			/AND TEMPORARILY SET THE OUTPUT TO THE TTY.
	DCA	OUTDEV
	TAD I	EPTR
	TAD	O7603
	SNA		/IS IT ALT-MODE (175)
	JMP	ALTMODE	/YES
	TAD	O36
	SNA		/IS IT '_'
	JMP	BARROW	/YES
	TAD	O122
	SNA		/IS IT (CAR. RET.)
	JMP	CARRET	/YES
	TAD	O7715
	SNA		/IS IT '@'
	JMP	NEWCHAR	/YES
	AND	O140B
	SZA
	TAD	O7640B
	SZA CLA		/IS IT A PRINTABLE CHARACTER
	JMP	NEWCHAR	/NO
	TAD I	EPTR
	JMS I	PPUTCH
	TAD	EPTR
	ISZ	EPTR
	TAD	MLEND
	SZA CLA
	JMP	NEWCHAR
TUBIG,	JMS I	PRESET		/RESET ALL DEVICES NOW.
	JMS I	PPRINTXT		/AND GIVE THE ERROR MESSAGES.
	TOOLONG
	JMP	NEWLIN
ALTMODE,JMS I	PPRINTXT
	DELETED
	JMP	NEWLIN
BARROW,	TAD	EPTR
	TAD	MLBEGIN
	SNA CLA
	JMP	NEWCHAR
	CLA CMA
	TAD	EPTR
	DCA	EPTR
	TAD	O3737B
	JMS I	PPUTCH
	JMP	NEWCHAR
CARRET,	TAD	O215
	JMS I	PPUTCH
	ISZ	NOINT		/SET FLAG TO PREVENT INTERUPTS AS OF NOW.
	TAD	PLBEGIN	/EPTR=BEGINNING OF STRING
	DCA	EPTR	/FPTR=WHERE TRANSLATED SYMBOL GOES
	TAD	PLINBUF	/GPRE=CHAR IN STRING(.GE. EPTR)
	DCA	FPTR	/HPTR=POSITION IN TABLE
SLOOP,	TAD	PTABLE
	DCA	HPTR
GLOOP,	TAD	EPTR
	DCA	GPTR
	TAD I	HPTR
	SNA CLA
	JMP I	POTHER
	TAD	HPTR
	DCA	WORD
	ISZ	HPTR
	DCA	ACS
HLOOP,	TAD I	GPTR
	TAD	O7740
	SZA CLA
	JMP	BSKIP
	ISZ	GPTR
	JMP	HLOOP
BSKIP,	CLA CLL CML RAR
	TAD	ACS
	DCA	ACS
	TAD I	HPTR
	SZL
	ISZ	HPTR
	SZL
	JMP	.+4
	RTR
	RTR
	RTR
	AND	O77
	SNA
	JMP I	JMATCH
	TAD	O7740
	SNA
	JMP	BSKIP
	AND	O77
	TAD	O40
	CIA
	TAD I	GPTR
	ISZ	GPTR
	SNA CLA
	JMP	HLOOP
	TAD I	HPTR
	AND	O77
	ISZ	HPTR
O7640B,	SZA CLA
	JMP	.-4
	JMP	GLOOP
JMATCH,	AMATCH
O36,	36
O40,	40
O122,	122
O140B,	140
O3737B,	3737
O7603,	7603
O7715,	7715
POTHER,	OTHER
PTABLE,	XXPLUS
	PAGE
OTHER,	JMS	NONBLNK
	TAD	O7763B
	SZA
	JMP	NOTCR
	TAD	PXXCRLF
	DCA I	FPTR
	TAD	FPTR
	DCA	INDEX1
	TAD	PXXEXIT
	DCA I	INDEX1
	TAD	INDEX1
	TAD	MENDLIN
	SNA
	JMP I	PGETLRET
	SPA CLA
	JMP	.-7
	JMP I	PTUBIG
PTUBIG,	TUBIG
PGETLRE,GETLRET
NOTCR,	TAD	O7737
	SNA
	JMP I	JDIGIT
	TAD	O7764B
	CLL
	TAD	O12
	SZL
	JMP I	JDIGIT
	TAD	O7725A
	CLL
	TAD	O32
	SZL
	JMP I	PLETTER
	CLA CLL CML RAR
	TAD I	EPTR
	DCA I	EPTR
REMPACK,TAD	PTEXT
	DCA I	FPTR
	ISZ	FPTR
TXTPAK,	DCA	THISTXT
	TAD I	EPTR
	TAD	O7763B
	SNA
	JMP	CRINTXT
	TAD	O7753
	SNA CLA
	JMP	DQINTXT
	TAD I	EPTR
	AND	O77
	DCA I	EPTR
	TAD	THISTXT
	SNA
	JMP	LHALF
	TAD I	EPTR
	DCA I	FPTR
	ISZ	FPTR
	JMP	RHALF
LHALF,	TAD I	EPTR
	CLL RTL
	RTL
	RTL
RHALF,	ISZ	EPTR
	JMP	TXTPAK
CRINTXT,TAD	THISTXT
	JMP I	JTXXIT
O7725A,	7725
O7763B,	7763
O7764B,	7764
PLETTER,LETTER
O7753,	7753
O4200,	4200
O42,	42
THISTXT,0
NONBLNK,0
	TAD I	EPTR
	TAD	O7740
	SZA CLA
	JMP	.+3
	ISZ	EPTR
	JMP	NONBLNK+1
	TAD I	EPTR
	JMP I	NONBLNK
O32,	32
O7737,	7737
JTXXIT,	MTXXIT
JDIGIT,	DIGIT
PXXCRLF,XXCRLF
PXXEXIT,XXEXIT
POPERA,	OPERAND-1
PXXLIT0,XXLIT0
LITRAL,	FENTER
	FST	OPERAND
	FEXIT
	TAD	OPERAND+2
	SZA CLA
	JMP	ALL3
	TAD	OPERAND+1
	SZA CLA
	JMP	JUST2
	TAD	OPERAND
	SNA CLA
	JMP	JUST0
JUST1,	CLA CLL CMA RAL
ALL3,	IAC
JUST2,	TAD	O2
JUST0,	CMA
	DCA	TMP
	TAD	POPERA
	DCA	INDEX1
	TAD	TMP
	CMA
	TAD	PXXLIT0
	JMP	JUST0P
JUST0F,	CDF	0		/'''''''''''' 8 K INSERT.
	TAD I	INDEX1
	CDF	10		/'''''''''''' 8  K INSERT.
JUST0P,	DCA I	FPTR
	ISZ	FPTR
	ISZ	TMP
	JMP	JUST0F
	JMP I	PSLOOP
DQINTXT,TAD	THISTXT
	ISZ	EPTR
	SZA
	JMP	.+3
	TAD	O4200
	JMP I	JTXXIT
	TAD	O42
	DCA I	FPTR
	ISZ	FPTR
MTXXIT,	DCA I	FPTR
	ISZ	FPTR
	JMP I	PSLOOP
DIGIT,	CLA
	TAD I	SNUMFLG
	TAD	O1774
	SZA		/IS IT 'GOTO' OR 'THEN'
	IAC
	SZA		/OR 'GOSUB'
	TAD	O1742
	SNA CLA		/OR 'LIST'
	CLA CMA		/YES
	DCA	SNUMFLG
	FENTER
	FLD	ZERO
	FEXIT
	DCA	DPFLAG
	DCA	DECFRAC
	SKP
DIGIN,	ISZ	EPTR
	JMS I	PNONBLNK
	TAD	O7673
	SNA
	JMP	ITSE
	TAD	O27
	SNA
	JMP	ITSDP
	TAD	O7764C
	CLL
	TAD	O12
	SNL
	JMP	ENDNUM
	CLL RAR
	TAD	O2040A
	DCA	FDIGIT
	RAR
	DCA	FDIGIT+1
	FENTER
	FMPI	PTEN
	FAD+FWD+FDIGIT-.
	FEXIT
	TAD	DPFLAG
	SZA CLA
	ISZ	DECFRAC
	JMP	DIGIN
ITSDP,	TAD	DPFLAG
	SZA CLA
	JMP	ENDNUM
	ISZ	DPFLAG
	JMP	DIGIN
ITSE,	DCA	FDIGIT
	TAD	SNUMFLG
	SZA CLA
	JMP	ENDNUM
	ISZ	EPTR
	JMS I	PNONBLNK
	TAD	O7725B
	SNA
	JMP	ITSP
	TAD	O7776
	SZA CLA
	JMP	NOTSGN
	ISZ	FDIGIT
ITSP,	ISZ	EPTR
NOTSGN,	JMS I	JISDIG
	JMP	ENDNUM
	ISZ	EPTR
	DCA	FDIGIT+1
	JMS I	JISDIG
	JMP	ONLY1
	CLA
	TAD	FDIGIT+1
	CLL RTL
	TAD	FDIGIT+1
	CLL RAL
	DCA	FDIGIT+1
	JMS I	JISDIG
O7673,	7673
	TAD	FDIGIT+1
	DCA	FDIGIT+1
	ISZ	EPTR
ONLY1,	TAD	FDIGIT
	CLL RAR
	TAD	FDIGIT+1
	SNL
	CIA
	TAD	DECFRAC
	DCA	DECFRAC
ENDNUM,	CLA
	TAD	DECFRAC
	SMA CLA
	TAD	DIVXTEN
	TAD	MULXTEN
	DCA	MULEXP
	TAD	DECFRAC
	SPA
	CIA
	CMA
	DCA	DECFRAC
	JMP	.+4
	FENTER
MULEXP,	HLT
	FEXIT
	ISZ	DECFRAC
	JMP	.-4
	ISZ	SNUMFLG
	JMP I	PLITRAL
	JMS I	PFIX
	CLA
	JMP I	PCOMMON
PCOMMON,COMMON
FDIGIT,	0;0;0
MULXTEN,FMPI	PTEN
DIVXTEN,FDV-FMP
DPFLAG,	0
DECFRAC,0
JISDIG,	ISDIG
O27,	27
O7725B,	7725
O7776,	7776
O2040A,	2040
O7764C,	7764
O1742,	1742
O1774,	1774
PLITRAL,LITRAL
	PAGE
COMMON,	TAD	PSYMTAB
	DCA	GPTR
	TAD	NSYMTAB
	DCA	HPTR
	JMP	IN
LUP,	TAD I	GPTR
	ISZ	GPTR
	ISZ	GPTR
	SZA CLA		/IS IT A LINENO
	JMP	NOT	/NO
	TAD I	GPTR
	ISZ	GPTR
	CIA
	TAD	AC2
	SZA CLA
	JMP	NOT+1
	TAD I	GPTR
	CIA
	TAD	AC3
	SZA CLA
	JMP	NOT+1
	CLA CLL CMA RTL
	JMP	ISDEF2
NOT,	ISZ	GPTR
	ISZ	GPTR
IN,	ISZ	HPTR
	JMP	LUP
	JMS I	PGETBLK
	DCA	SNUMFLG
	DCA I	SNUMFLG
	TAD	SNUMFLG
	DCA	INDEX1
	DCA I	INDEX1
	TAD	AC2
	DCA I	INDEX1
	TAD	AC3
	DCA I	INDEX1
	JMP	ITSDEF
LETTER,	IAC
	CLL RTL
	RTL
	RTL
	DCA	TMP
	ISZ	EPTR
	JMS I	PNONBLNK
	TAD	O7706C
	CLL
	TAD	O12
	SNL CLA
	JMP	SIMPLV
	TAD I	EPTR
	TAD	TMP
	DCA	TMP
	ISZ	EPTR
SIMPLV,	TAD	PSYMTAB
	DCA	GPTR
	TAD	NSYMTAB
	DCA	HPTR
	JMP	VSCHIN
O7706C,	7706
O7000B,	7000
VSCHLUP,TAD I	GPTR
	TAD	O7000B
	SZA CLA
	JMP	VSCHNOT
	ISZ	GPTR
	TAD I	GPTR
	DCA	SNUMFLG
	TAD I	SNUMFLG
	CIA
	TAD	TMP
	SZA CLA
	JMP	VSCHNOT+1
	CLA CMA
ISDEF2,	TAD	GPTR
	DCA	SNUMFLG
ITSDEF,	TAD	SNUMFLG
	DCA I	FPTR
	ISZ	FPTR
	JMP I	PSLOOP
VSCHNOT,ISZ	GPTR
	ISZ	GPTR
	ISZ	GPTR
	ISZ	GPTR
VSCHIN,	ISZ	HPTR
	JMP	VSCHLUP
	JMS I	PGETBLK
	DCA	SNUMFLG
	CLA CMA
	TAD	SNUMFLG
	DCA	INDEX1
	TAD	O1000
	DCA I	INDEX1
	TAD	ARRLOC
	DCA I	INDEX1
	DCA I	INDEX1
	DCA I	INDEX1
	JMS I	PCHKFIT
	TAD	TMP
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	JMS I	PSTICKIT
	JMP	ITSDEF
O1000,	1000
POP,	0
	CLA CMA
	TAD	PDL
	DCA	PDL
	TAD I	PDL
	JMP I	POP
FOURLF,	TEXT '____'
UGH1,	TEXT '_TOO BIG. LINE IGNORED_'
	PAGE
LIST,	TAD I	PXLINBUF
	DCA	WORD
	ISIT			/CHECK FOR A "*"
	3476
	JMP	.+4		/NOPE.
	CLA CMA			/YEP. SET UP PUTXRA BY GIVING A PHOONEY
	JMS I	PCOWT		/CALL TO THE WAIT ROUTINE.
	JMS	GETWD		/AND GET ANOTHER WORD NOW.
	ISIT		/LINENO
	0000
	JMP	LISTALL
	ISZ	WORD
	TAD I	WORD
	SNA
LISTALL,TAD	CODELOC
LISTSOM,DCA	LOCCTR
LISTLUP,JMS	GETWD
	ISIT		/(EOF)
	1755
	JMP	LNOEND		/NOT DUNE YET
	JMS I	PCOWT		/WAIT FOR I/O TO FINISH AND CLEAN UP.
	JMS	PRINTXT
	FOURLF
	JMP I	PEDIT
LNOEND,	ISIT		/A LINENO
	0000
	JMP	LIST2	/NO
	TAD	WORD
	JMS I	PPRINUM
	TAD	O240
	JMS I	PPUTCH
	JMP	LISTLUP
LIST2,	ISIT		/A VARIABLE
	7000
	JMP	LIST3
	ISZ	WORD
	TAD I	WORD
	DCA	WORD
	TAD I	WORD
	DCA	PRINVAR
	JMS	PRINTXT
	PRINVAR
	JMP	LISTLUP
PRINVAR,0
	0
LIST3,	JMS I	PISITLIT /ISIT A LITERAL
	JMP	LIST4	/NO
	JMS I	POUTNUM	/PRINT IT
	JMP	LISTLUP
LIST4,	ISIT		/(TEXT)
	5000
	JMP	LIST5
L4LUP,	JMS	GETWD
	TAD	WORD
	DCA	PRINVAR
	JMS	PRINTXT
	PRINVAR
	TAD	WORD
	AND	O77
	SZA CLA
	JMP	L4LUP
	JMP	LISTLUP
LIST5,	TAD	WORD	/ITS A SYSTEM SYMBOL
	IAC
	JMS	PRINTXT
	JMP	LISTLUP
PRINTXT,0
	SZA
	JMP	JBPENT+1	/'''''''''''' 8 K INSERT.
	CDF	0		/'''''''''''' 8 K INSERT.
	TAD I	PRINTXT
JBPENT,	ISZ	PRINTXT
	DCA	PRTEMP
PRLOOP,	TAD I	PRTEMP
	RTR
	RTR
	RTR
	JMS	PRSUBR
	TAD I	PRTEMP
	JMS	PRSUBR
	ISZ	PRTEMP
	JMP	PRLOOP
PRTXRET,CDF	10		/'''''''' 8 K INSERT.
	JMP I	PRINTXT
PRSUBR,	0
	AND	O77
	SNA
	JMP	PRTXRET
	TAD	O7741
	SNA
	JMP	CRLFPR
	TAD	O77
	AND	O77
	TAD	O240
	JMS I	PPUTCH
	JMP I	PRSUBR
CRLFPR,	TAD	O215
	JMS I	PPUTCH
	TAD	O212
	JMS I	PPUTCH
	JMP I	PRSUBR
O7741,	7741
PXLINBU,LINBUF+1
PRINUM,	0
	IAC
	DCA	INDEX1
	JMS	BEGFIX		/SET UP FAC TO RECEIVE INTEGER DATA.
	TAD I	INDEX1
	DCA	AC2
	TAD I	INDEX1
	DCA	AC3
	JMS I	PANORM
	JMS I	POUTNUM
	JMP I	PRINUM
BEGFIX,	0			/SETS UP FOR INTEGER TO AC MODE.
	DCA	AC2		/CLEAR THEM ALL, EXCEPT FOR LOW WORD.
	DCA	AC1
	DCA	OV
	DCA	ACS
	TAD	O233
	DCA	ACE
	JMP I	BEGFIX
O233,	233
RESTORE,GET+MUSTBE	/(CR) OR '\'
	2000
	TAD	CODELOC
	DCA	READLOC
	JMP I	PEXECUTE
	PAGE
MOREIN,	ISIT		/(CR) OR '\'
	2000
	JMP	INPLUP
	TAD	O212
	JMS I	PPUTCH
	TAD	OUTD2		/GET THE OLD OUTPUT DEVICE.
	DCA	OUTDEV		/AND RESET IT.
INPUT,	CLA CMA			/CHECK THE INPUT DEVICE NOW.
	TAD	INDEV		/ARE WE INPUT FROM THE TELETYPE.
	SZA CLA
	JMP	IPNOPE		/NOPE.
	TAD	OUTDEV		/GET THE OUTPUT DEVICE.
	JMS I	PPUSH		/SAVE IT FOR A SECOND.
	CLA IAC			/SET OUTPUT DEVICE TO TTY FOR "?"
	DCA	OUTDEV
	JMS I	PCOWT		/WAIT FOR OUTPUT TO FINISH, THEN CONTINUE.
	TAD	O77
	JMS I	PPUTCH
	JMS I	PPOP		/RESET OUTPUT DEVICE NOW.
	DCA	OUTDEV
IPNOPE,	TAD	LOCCTR
	DCA I	GSBPTR
	TAD	PTEXT
	JMS I	PGETLIN
	TAD I	GSBPTR
	DCA	LOCCTR
	TAD	PLINBUF
	DCA	INPPTR
INPLUP,	JMS I	PGETVAR
	TAD	WORD
	DCA	INWDTMP
	TAD	LOCCTR
	DCA	INLCTMP
	TAD	INPPTR
	DCA	LOCCTR
	JMS I	PEVAL
	TAD	LOCCTR
	DCA	INPPTR
	TAD	INLCTMP
	DCA	LOCCTR
	JMS I	PSTOVAR
	CLA CLL CML RTR
	TAD I	INWDTMP
	SZA CLA
	JMP	MOREIN
	TAD	O212
	JMS I	PPUTCH
	TAD	OUTD2		/RESET THE DEV, BABY
	DCA	OUTDEV
	DCA	COLUMN
	JMP I	PEXECUTE
INPPTR,	0
INWDTMP,0
INLCTMP,0
XGISIT,	0
	JMS	GETWD
	TAD	XGISIT
	DCA	XISIT
	JMP	XISIT+1
XISIT,	0
	TAD I	WORD
	CDF	0		/''''''''''''' 8 K INSERT.
	TAD I	XISIT
	CDF	10		/''''''''''''' 8 K INSERT.
	ISZ	XISIT
	SNA CLA
	ISZ	XISIT
	JMP I	XISIT
ISITLIT,0
	TAD I	WORD
	CLL CMA RTL
	CML RTR
	DCA	ACS
	TAD	ACS
	TAD	O4
	SNL CLA
	JMP I	ISITLIT
	ISZ	ISITLIT
	DCA	AC1
	DCA	AC2
	DCA	AC3
	JMS	ISLIT
	DCA	AC3
	JMS	ISLIT
	DCA	AC2
	JMS	ISLIT
	DCA	AC1
LOADED,	FENTER
	FLD	AC3
	FEXIT
	JMP I	ISITLIT
ISLIT,	0
	ISZ	ACS
	SKP
	JMP	LOADED
	JMS	GETWD
	TAD	WORD
	JMP I	ISLIT
ERROR,	0
	JMS I	PRESET		/RESET ALL I/O DEVICES.
	JMS I	PPRINTXT
	CRLF
	TAD	ERROR
	DCA	.+2
	JMS I	PPRINTXT
	HLT
	JMS I	PPRINTXT
	QERROR
	TAD I	LINENO
	SPA CLA
	JMP	.+5
	JMS I	PPRINTXT
	ATLINE
	TAD	LINENO
	JMS I	PPRINUM
	JMS I	PPRINTXT
	CRLF
	TAD	PPDLIST
	DCA	PDL
	JMP I	PEDIT
QERROR,	TEXT ' ERROR'
	PAGE
	/	JMS	FPT	/ENTER FLOATING POINT PACK
	/	0000		/FEXIT
	/	0040		/FSNE
	/	0050		/FSEQ
	/	0100		/FSGE
	/	0110		/FSLT
	/	0140		/FSGT
	/	0150		/FSLE
	/		IF BIT 4 OFF THEN SAME AS PDP-8
	/		IF BIT 4 ON THEN IF BIT 3 OFF THEN RELATIVE PLUS
	/				 IF BIT 3 ON THEN RELATIVE MINUS
	/	1XXX		/FJMP
	/	2XXX		/FST
	/	3XXX		/FLD
	/	4XXX		/FAD
	/	5XXX		/FSB
	/	6XXX		/FMP
	/	7XXX		/FDV
FPT,	0
	JMP	.+3
FPLOOP,	JMS I	PANORM
	ISZ	FPT
	CDF	0		/'''''''' 8 K INSERT.
	TAD I	FPT
	RTL
	RTL
	AND	O7
	SNA
	JMP	FPOPER
	DCA	FPGOTO
	TAD I	FPT
	AND	O200
	SNA CLA
	JMP	FPPGZ
	TAD I	FPT
	AND	O177
	SZL
	CIA
	TAD	FPT
	DCA	FPADDR
	JMP	FPDOIT
FPPGZ,	TAD I	FPT
	AND	O177
	DCA	FPADDR
	SNL
	JMP	FPDOIT
	TAD I	FPADDR
	DCA	FPADDR
	CDF	10		/'''''''' 8 K INSERT.
FPDOIT,	CLA CLL CMA RTL
	TAD	FPGOTO
	SPA CLA
	JMP	FPNOADR
	CLA CLL CML RAR
	AND I	FPADDR
	DCA	OPS
	TAD I	FPADDR
	SZA CLA
	CMA
	DCA	FPFLAG
	TAD I	FPADDR
	RTR
	RAR
	AND	O377
	DCA	OPE
	TAD I	FPADDR
	AND	O7
	DCA	OP1
	ISZ	FPADDR
	TAD I	FPADDR
	DCA	OP2
	ISZ	FPADDR
	TAD I	FPADDR
	DCA	OP3
FPNOADR,TAD	FPGOTO
	TAD	FPJUMP
	DCA	.+1
FPGOTO,	HLT
FPJUMP,	JMP I	.
	FPJMP
	FPSTO
	FPLAC
	FPADD
	FPSUB
	FPMUL
	FPDIV
FPADDR,	0
FPOPER,	TAD I	FPT
	CDF	10		/''''''''''' 8 K INSERT.
	SNA
	JMP I	FPT
	TAD	O7600
	DCA	FPSKIP
	JMS	HIGHWD
FPSKIP,	HLT
	ISZ	FPT
	JMP	FPLOOP+1
FPJMP,	TAD	FPADDR
	DCA	FPT
	JMP	FPLOOP+2
FPSTO,	JMS	HIGHWD
	DCA I	FPADDR
	ISZ	FPADDR
	TAD	AC2
	DCA I	FPADDR
	ISZ	FPADDR
	TAD	AC3
	DCA I	FPADDR
	JMP	FPLOOP+1
HIGHWD,	0
	TAD	ACE
	CLL RAL
	SMA
	CLL RTL
	SPA SZL
	JMP	O7600
	TAD	ACS
	TAD	AC1
	JMP I	HIGHWD
O7600,	7600
	TAD	O377
	DCA	ACE
	JMP	HIGHWD+1
FPLAC,	TAD	OPS
	DCA	ACS
	TAD	OPE
	DCA	ACE
	TAD	OP1
	DCA	AC1
	TAD	OP2
	DCA	AC2
	TAD	OP3
	DCA	AC3
	DCA	OV
	JMP	FPLOOP
UPARR2,	CIA		/(CMA) IF 1 ORG INDEXING
	DCA	INDEX1
	FENTER
	FLD	ONE
	FEXIT
	JMP	.+4
	FENTER
	FMP	OPERAND
	FEXIT
	ISZ	INDEX1
	JMP	.-4
	JMP I	.+1
	OPDONE
AR1,	0
	TAD	AC1
	CLL RAR
	DCA	AC1
	TAD	AC2
	RAR
	DCA	AC2
	TAD	AC3
	RAR
	DCA	AC3
	RAR
	DCA	OV
	JMP I	AR1
ACN,	0
	TAD	POP3
	DCA	OADD
	CLA CLL CMA RTL
	DCA	AR1
	CML RAL
	TAD I	OADD
	CIA
	DCA I	OADD
	ISZ	OADD
	ISZ	AR1
	JMP	.-6
	JMP I	ACN
POP3,	OP3
OADD,	0
	CLL
	TAD	AC3
	TAD	OP3
	DCA	AC3
	RAL
	TAD	AC2
	TAD	OP2
	DCA	AC2
	RAL
	TAD	AC1
	TAD	OP1
	DCA	AC1
	JMP I	OADD
FPSUB,	CLA CLL CML RAR
	TAD	OPS
	DCA	OPS
FPADD,	ISZ	FPFLAG
	JMP	EOFAD
	TAD	ACE
	CLL CIA
	TAD	OPE
	SZL
	JMP	BCKWDS
	DCA	OADD
ALGNLP,	TAD	OP1
	CLL RAR
	DCA	OP1
	TAD	OP2
	RAR
	DCA	OP2
	TAD	OP3
	RAR
	DCA	OP3
	ISZ	OADD
	JMP	ALGNLP
	JMP	SETSGN
BCKWDS,	CMA
	DCA	OADD
	TAD	OPE
	DCA	ACE
	SKP
	JMS	AR1
	ISZ	OADD
	JMP	.-2
SETSGN,	TAD	ACS
	TAD	OPS
	SPA CLA
	JMS	ACN
	JMS	OADD
	TAD	AC1
	SMA CLA
	JMP	EOFAD
	CLA CLL CMA RTL
	JMS	ACN
	TAD	OPS
	DCA	ACS
EOFAD,	DCA	OV
	JMP I	PFPLOOP
FPMUL,	ISZ	FPFLAG
	JMP	MULCLR
	TAD	ACS
	TAD	OPS
	DCA	ACS
	TAD	ACE
	TAD	OPE
	TAD	O7577
	DCA	ACE
	TAD	AC1
	DCA	OPS
	TAD	AC2
	DCA	OPE
	TAD	AC3
	DCA	TMP
	DCA	AC1
	TAD	O7745
	DCA	FPTEMP
MPYLUP,	JMS	AR1
	TAD	OPS
	RAR
	DCA	OPS
	TAD	OPE
	RAR
	DCA	OPE
	TAD	TMP
	RAR
	DCA	TMP
	SZL
	JMS	OADD
	ISZ	FPTEMP
	JMP	MPYLUP
	JMP I	PFPLOOP
MULCLR,	CLA CLL CMA RTL
	DCA	ACE
	DCA	AC1
	JMP I	PFPLOOP
PFPLOOP,FPLOOP
FPTEMP,	0
O7577,	7577
	PAGE
ANORM,	0
	TAD	AC1
	SNA			/IS HIGH WORD ZERO?
	JMP	MAYZERO		/YEP. ENTIRE NUMBER MAY BE ZERO.
	TAD	O7770
	SPA CLA
	JMP	NOTBIG
	JMS I	PAR1
	ISZ	ACE
	JMP	ANORM+1
MAYZERO,TAD	AC2		/IS SECOND WORD ZERO?
	SZA CLA
	JMP	NOTBIG		/NOPE. NORMAL NORMALIZE.
	TAD	AC3		/1 & 2 ARE ZERO. IS THIRD WORD?
	SNA CLA
	JMP	UNDERF		/YEP. CLEAR AC. ALL ZERO.
NOTBIG,	TAD	OV
	SNA CLA
	JMP	NOBUMP
	ISZ	AC3
	JMP	NOBUMP
	ISZ	AC2
	JMP	NOBUMP
	ISZ	AC1
	DCA	OV
	JMP	ANORM+1
	CLA CMA
NOBUMP,	TAD	ACE
	SPA
	JMP	UNDERF
	DCA	ACE
	CLA CLL CMA RTL
	TAD	AC1
	SMA SZA CLA
	JMP I	ANORM
	JMS	AL1
	JMP	NOBUMP-1
UNDERF,	CLA
	DCA	ACS
	DCA	ACE
	DCA	AC1
	DCA	AC2
	DCA	AC3
	JMP I	ANORM
AL1,	0
	TAD	AC3
	CLL RAL
	DCA	AC3
	TAD	AC2
	RAL
	DCA	AC2
	TAD	AC1
	RAL
	DCA	AC1
	JMP I	AL1
FPDIV,	CDF	0		/''''''''''''''''''' 8 K INSERT.
	ISZ	FPFLAG
	JMP	FPZDIV
	TAD	ACS
	TAD	OPS
	DCA	ACS
	TAD	OPE
	CIA
	TAD	ACE
	TAD	O177
	DCA	ACE
	DCA	TMP
	TAD	O7743
	DCA	ANORM
DIVLP,	CLA CLL CML RAR
	AND	OP1
	TAD	AC1
	SMA CLA
	JMS I	PACN
	JMS I	POADD
	TAD	TMP
	RAL
	DCA	TMP
	TAD	OPE
	RAL
	DCA	OPE
	TAD	OPS
	RAL
	DCA	OPS
	JMS I	PAL1
	ISZ	ANORM
	JMP	DIVLP
	TAD	OPS
	DCA	AC1
	TAD	OPE
	DCA	AC2
	TAD	TMP
	DCA	AC3
	JMP I	PPFLOOP
FPZDIV,	TAD	O377
	DCA	ACE
	JMP I	PPFLOOP
PPFLOOP,FPLOOP
PACN,	ACN
O7743,	7743
FIX,	0
	TAD	AC1
	SNA CLA
	JMP	ZFIXEX
FIXLUP,	TAD	ACE
	TAD	O7545
	SMA CLA
	JMP	FIXEXIT
	JMS I	PAR1
	TAD	ACS
	AND	OV
	SZA CLA
	ISZ	AC3
	JMP	.+4
	ISZ	AC2
	JMP	.+2
	ISZ	AC1
	ISZ	ACE
	JMP	FIXLUP
ZFIXEX,	DCA	ACE
	DCA	AC1
	DCA	AC2
	DCA	AC3
FIXEXIT,DCA	OV
	TAD	AC3
SSFIX,	IAC		/(NOP) IF 1 ORG INDEXING
	JMP I	FIX
O7545,	7545
	PAGE
OUTNUM,	0
	CDF	0		/'''''''''' 8 K INSERT.
	TAD	ACS
	SMA CLA
	JMP	.+3
	TAD	O255
	JMS I	PPUTCH
	TAD	AC1
	SZA CLA
	JMP	NONZERO
	TAD	O260
	JMS I	PPUTCH
	CDF	10		/'''''''''' 8 K INSERT.
	JMP I	OUTNUM
NONZERO,JMS I	FIXUP
	TAD	O7771
	DCA	PRTEMP
	TAD	PNUMBUF
	DCA	ACE
	JMP	.+5
CVTLOOP,TAD	AC1
	AND	O177
	DCA	AC1
	JMS I	PMPY
	TAD	AC1
	RTL
	RTL
	RTL
	AND	O17
	TAD	O260
	DCA I	ACE
	ISZ	ACE
	ISZ	PRTEMP
	JMP	CVTLOOP
	CLA CLL CML RTL
	TAD	DECEXP
	SNA
	JMP	FMT1	/.0NNNNNNN
	SPA
	JMP	FMT2	/N.NNNNNNE-NN
	TAD	O7770
	SPA CLA
	JMP	FMT3	/OTHER THAN N.NNNNNNE+NN
FMT2,	CLA		/N.NNNNNNE+NN
	TAD	PNUMBUF
	DCA	ACE
	TAD	O7772
	DCA	PRTEMP
	TAD I	ACE
	JMS I	PPUTCH
	TAD	O256A
	JMS I	PPUTCH
	ISZ	ACE
	TAD I	ACE
	JMS I	PPUTCH
	ISZ	PRTEMP
	JMP	.-4
	TAD	O305
	JMS I	PPUTCH
	TAD	DECEXP
	SPA CLA
	CLA CLL CML RTL
	TAD	O253
	JMS I	PPUTCH
	DCA	ACE
	TAD	DECEXP
	SPA
	CIA
	DCA	DECEXP
	TAD	DECEXP
	TAD	O7766
	SPA
	JMP	.+4
	DCA	DECEXP
	ISZ	ACE
	JMP	.-6
	CLA
	TAD	ACE
	TAD	O260
	JMS I	PPUTCH
	TAD	DECEXP
	TAD	O260
	JMS I	PPUTCH
FMTENF,	CDF	10		/'''''''''' 8 K INSERT.
	JMP I	OUTNUM
FMT1,	JMS I	PPRINTXT
	DOTZERO
	CDF	0		/'''''''''' 8 K INSERT.
FMT3,	TAD	O7771
	DCA	PRTEMP
	TAD	PNBF6
TRYAGIN,DCA	ACE
	TAD I	ACE
	TAD	O7520
	SZA CLA
	JMP	ZERDONE
	ISZ	PRTEMP
	CLA CMA
	TAD	ACE
	JMP	TRYAGIN
ZERDONE,JMP I	.+1		/'''''''' 8 K INSERT.
	PZERDONE		/''''''' 8 K INSERT.
FIXUP,	FIXITUP
O17,	17
O253,	253
O255,	255
O305,	305
O7520,	7520
O7766,	7766
O7771,	7771
O256A,	256
O7772,	7772
PMPY,	MPY
PNBF6,	NUMBUF+6
TOOLONG,TEXT '_LINE TOO LONG_'
	PAGE
FIXITUP,0
	TAD	ACE
	TAD	O7610
	DCA	ACE
	SKP
OCC,	TAD	DECEXP
	DCA	DECEXP
NORMIT,	TAD	AC1
	RTL
	SZL CLA
	JMP	NORMED
	JMS I	PAL1
	CLA CMA
	TAD	ACE
	DCA	ACE
	JMP	NORMIT
NORMED,	TAD	ACE
	SMA SZA
	JMP	NOTX10
	CLA
	JMS I	PAR1
	JMS I	PAR1
	JMS I	PAR1
	JMS I	PAR1
	JMS	MPY
	TAD	ACE
	TAD	O4
	DCA	ACE
	CLA CMA
	JMP	OCC
NOTX10,	TAD	O7773
	SPA
	JMP	EXPOK
	CLA
EXPGOOD,TAD	O7740
	DCA	MPY
	CLL
DVLOOP,	TAD	AC1
	TAD	O5400
	SMA
	DCA	AC1
	CLA CML CMA RAL
	DCA	OP1
	JMS I	PAL1
	ISZ	OP1
	ISZ	AC3
	ISZ	MPY
	JMP	DVLOOP
	TAD	AC1
	AND	O377
	DCA	AC1
	CLA IAC
	JMP	OCC
EXPOK,	DCA	PRTEMP
	SKP
	JMS I	PAR1
	ISZ	PRTEMP
	JMP	.-2
	TAD	AC1
	TAD	O5400
	SMA CLA
	JMP	EXPGOOD
	CLA CLL
	TAD	AC3
	TAD	O2062
	DCA	AC3
	SZL
	ISZ	AC2
	SKP
	ISZ	AC1
	TAD	AC1
	TAD	O5400
	SZA CLA
	JMP I	FIXITUP
	TAD	O200
	DCA	AC1
	DCA	AC2
	DCA	AC3
	ISZ	DECEXP
	NOP
	JMP I	FIXITUP
MPY,	0
	JMS I	PAL1
	TAD	AC1
	DCA	OP1
	TAD	AC2
	DCA	OP2
	TAD	AC3
	DCA	OP3
	JMS I	PAL1
	JMS I	PAL1
	JMS I	POADD
	JMP I	MPY
NUMBUF,	0;0;0;0;0;0;0
O2062,	2062
O7610,	7610
O7773,	7773
O5400,	5400
RNDJMP,	FEXIT
	JMS I	PANORM
	JMP I	RND
RND,	0
	FENTER
	FLD+FWD+FRNDX-.
	FEXIT
	TAD	OP3
	RTL
	RTL
	RTL
	DCA	AC1
	TAD	AC1
	RAR
	AND	O7740
	DCA	AC2
	DCA	AC3
	JMS I	POADD
	JMS I	POADD
	JMS I	POADD
	TAD	OPE
	DCA	ACE
	TAD	AC1
	AND	O7
	DCA	AC1
	FENTER
	FST+FWD+FRNDX-.
	FJMP+BKWD+.-RNDJMP
FRNDX,	2004;4173;1231
FSQRX,	0;0;0
SQR,	0
	FENTER
	FST	OPERAND
	FSNE
	FJMP+FWD+SQEXIT-.
	FEXIT
	TAD	ACS
	SPA CLA
	JMP I	PARGERR
	TAD	ACE
	TAD	OO7600
	CLL
	SPA
	CML
	RAR
	TAD	O200
	DCA	ACE
	TAD	O7770
	DCA	INDEX1
SQLOOP,	FENTER
	FST+BKWD+.-FSQRX
	FLD	OPERAND
	FDV+BKWD+.-FSQRX
	FAD+BKWD+.-FSQRX
	FEXIT
	CLA CMA
	TAD	ACE
	DCA	ACE
	ISZ	INDEX1
	JMP	SQLOOP
SQEXIT,	FEXIT
	JMP I	SQR
OO7600,	7600
FN,	0
	TAD	LOCCTR
	JMS I	PPUSH
	TAD	WORD
	JMS I	PPUSH
	CDF	0			/''''''' 8 K INSERT
	TAD I	PUSERFN
	CDF	10			/'''''''' 8 K INSERT.
	IAC
	DCA	LOCCTR
	GET+ISIT	/'DEF'
	1761
	JMP I	PFNERR	/NO
	JMS	GETWD	/SKIP 'FN'
	JMS	GETWD	/SKIP LETTER
	JMS	GETWD	/SKIP '('
	GET+ISIT	/A VARIABLE
	7000
	JMP I	PFNERR	/NO
	ISZ	WORD
	TAD I	WORD
	DCA	INDEX1
	TAD I	INDEX1
	JMS I	PPUSH
	TAD I	INDEX1
	JMS I	PPUSH
	TAD I	INDEX1
	JMS I	PPUSH
	TAD	INDEX1
	JMS I	PPUSH
	CLA CLL CMA RAL
	TAD	INDEX1
	DCA	INDEX1
	FENTER
	FSTI	INDEX1
	FEXIT
	JMS	GETWD	/SKIP ')'
	JMS	GETWD	/SKIP '='
	JMS I	PEVAL
	JMS I	PPOP
	DCA	WORD
	JMS I	PPOP
	DCA I	WORD
	CLA CMA
	TAD	WORD
	DCA	WORD
	JMS I	PPOP
	DCA I	WORD
	CLA CMA
	TAD	WORD
	DCA	WORD
	JMS I	PPOP
	DCA I	WORD
	JMS I	PPOP
	DCA	WORD
	JMS I	PPOP
	DCA	LOCCTR
	JMP I	FN
PUSERFN,USERFN
PFNERR,	FNERR
TAB,	0			/FUNCTION "TAB" IN PRINT STATEMENT.
	JMS I	PFIX		/FIX THE FAC NOW.
	CDF	0		/SET DATA FIELD TO FIELD ZERO.
	CLA IAC			/SET FLAG TO INDICATE WE'VE DONE THIS FUNCTION.
	DCA I	PTABFLG		/AND STORE AWAY.
	TAD	ACS		/GET SIGN OF FAC
	SNA CLA			/WAS IT A POSITIVE NUMBER?
	TAD	AC3		/YEP. PICK UP DESIRED POSITION.
	AND	O377		/MAXIMUM OF 256 COLUMNS.
	DCA I	PTABDES		/SAVE AWAY FOR ACTUAL SPACER TO USE.
	JMS I	TBEGFIX		/PREPARE TO RETURN PRESENT COLUMN NUMBER.
	CLA IAC
	TAD	COLUMN		/INCREMENT TO ACCOUNT FOR DIFFERENCES.
	DCA	AC3		/AND STORE AWAY.
	CDF	10		/RESET DATA FIELD NOW.
	JMS I	PANORM		/NORMALIZE AC NOW.
	JMP I	TAB		/AND RETURN NOW.
PTABDES,TABDES			/POINTER TO DESIRED LOCATION OF PRINT HEAD.
PTABFLG,TABFLG			/POINTER TO TAB IN PRINT FLAG.
TBEGFIX,BEGFIX			/POINTER TO MINI-FIX-SET-UP ROUTINE.
RUBO,	CLA IAC			/SET RUBOUT SWITCH.
NORUBO,	DCA	RBSWCH
	JMP I	.+1		/AND CLEAN IT UP.
	DEVCOM			/CLEAN-UP POINTER.
	PAGE
TAN,	0
	FENTER
	FST+FWD+FTANT1-.
	FEXIT
	JMS	COS
	FENTER
	FST+FWD+FTANT2-.
	FLD+FWD+FTANT1-.
	FEXIT
	JMS	SIN
	FENTER
	FDV+FWD+FTANT2-.
	FEXIT
	JMP I	TAN
COS,	0
	FENTER
	FAD+FWD+FSINC7-.
	FEXIT
	JMS	SIN
	JMP I	COS
SIN,	0
	FENTER
	FDV+FWD+FSINC1-.
	FST+FWD+FSINZ-.
	FEXIT
	DCA	ACS
	JMS I	PINT
	CLA CLL CML RAR
	AND	FSINZ
	DCA	ACS
	FENTER
	FSB+FWD+FSINZ-.
	FMP+FWD+FSINM4-.
FSIN10,	FST+FWD+FSINZ-.
	FEXIT
	DCA	ACS
	FENTER
	FSB	ONE
	FSGT
	FJMP+FWD+FSINOK-.
	FLD+FWD+FSINZ-.
	FEXIT
	JMS I	PSGN
	ISZ	ACE
	FENTER
	FSB+FWD+FSINZ-.
	FJMP+BKWD+.-FSIN10
FSINOK,	FLD+FWD+FSINZ-.
	FMP+FWD+FSINZ-.
	FST+FWD+FSINZZ-.
	FMP+FWD+FSINC3-.
	FAD+FWD+FSINC4-.
	FMP+FWD+FSINZZ-.
	FAD+FWD+FSINC5-.
	FMP+FWD+FSINZZ-.
	FAD+FWD+FSINC6-.
	FMP+FWD+FSINZZ-.
	FAD+FWD+FSINC7-.
	FMP+FWD+FSINZ-.
	FEXIT
	JMP I	SIN
PSGN,	SGN
PINT,	INT
FTANT1,	0;0;0
FTANT2,	0;0;0
FSINZ,	0;0;0
FSINZZ,	0;0;0
FSINC1,	2036;2207;7325
FSINC3,	1644;7553;6722
FSINC4,	5714;6223;1432
FSINC5,	1755;0632;1276
FSINC6,	6005;1256;7406
FSINC7,	2016;2207;7325
FSINM4,	6034;0000;0000
UPARRX,	FENTER
	FST+BKWD+.-FSINZ
	FSGE
	FJMP+FWD+EXPLONG-.
	FEXIT
	JMS I	PINT
	FENTER
	FSB+BKWD+.-FSINZ
	FSEQ
	FJMP+FWD+EXPLONG-.
	FLD+BKWD+.-FSINZ
	FSB+FWD+FUPRC1-.
	FSLE
	FJMP+FWD+EXPLONG-.
	FLD+BKWD+.-FSINZ
	FEXIT
	JMP I	.+1
	UPARROW
FUPRC1,	2077;7700
EXPLONG,FLD	OPERAND
	FEXIT
	JMS I	PLOG
	FENTER
	FMP+BKWD+.-FSINZ
	FEXIT
	JMS I	PEXP
	JMP I	.+1
	OPDONE
PLOG,	LOG
PEXP,	EXP
	PAGE
EXP,	0
	FENTER
	FDV+FWD+FEXPC1-.
	FST+FWD+FEXPU-.
	FEXIT
	JMS I	PPINT
	CLA CLL CML RAR
	TAD	ACS
	DCA	ACS
	FENTER
	FST+FWD+FEXPI-.
	FAD+FWD+FEXPU-.
	FST+FWD+FEXPF-.
	FMP+FWD+FEXPF-.
	FAD+FWD+FEXPC2-.
	FST+FWD+FEXPU-.
	FLD+FWD+FEXPI-.
	FEXIT
	JMS I	PFIX
FXXPFX,	NOP		/(IAC IF 1 ORG INDEXING)
	DCA	FEXPI
	TAD	ACS
	CMA CLL CML RAL
	TAD	FEXPI
	SNL
	CIA
	IAC
	DCA	FEXPI
	FENTER
	FLD+FWD+FEXPC3-.
	FDV+FWD+FEXPU-.
	FAD+FWD+FEXPC4-.
	FSB+FWD+FEXPF-.
	FST+FWD+FEXPU-.
	FLD+FWD+FEXPF-.
	FMP+FWD+FEXPF-.
	FMP+FWD+FEXPC5-.
	FAD+FWD+FEXPU-.
	FST+FWD+FEXPU-.
	FLD+FWD+FEXPF-.
	FDV+FWD+FEXPU-.
	FAD+FWD+FEXPC6-.
	FST+FWD+FEXPF-.
	FEXIT
	TAD	ACE
	TAD	FEXPI
	DCA	ACE
	JMP I	EXP
PPINT,	INT
FEXPI,	0;0;0
FEXPU,	0;0;0
FEXPF,	0;0;0
FEXPC1,	2005;4271;0300
FEXPC2,	2075;3552;7022
FEXPC3,	6124;6477;0715
FEXPC4,	2044;7643;0062
FEXPC5,	1744;3372;3400
FEXPC6,	2004;0000;0000
LOG,	0
	TAD	ACS
	SPA CLA
	JMP I	PARGERR
	TAD	ACE
	DCA	LOGACE
	TAD	O200
	DCA	ACE
	FENTER
	FST+BKWD+.-FEXPU
	FAD+FWD+FLOGC1-.
	FST+BKWD+.-FEXPF
	FLD+BKWD+.-FEXPU
	FSB+FWD+FLOGC1-.
	FDV+BKWD+.-FEXPF
	FST+BKWD+.-FEXPF
	FMP+BKWD+.-FEXPF
	FMP+FWD+FLOGC2-.
	FAD+FWD+FLOGC3-.
	FMP+BKWD+.-FEXPF
	FMP+BKWD+.-FEXPF
	FAD+FWD+FLOGC4-.
	FMP+BKWD+.-FEXPF
	FSB+BKWD+.-FEXPC6
	FST+BKWD+.-FEXPF
	FLD+FWD+LOGFWD-.
	FSB+FWD+LOGOKW-.
	FAD+BKWD+.-FEXPF
	FMP+BKWD+.-FEXPC1
	FEXIT
	JMP I	LOG
FLOGC2,	2004;6253;2521
FLOGC3,	2007;5421;3604
FLOGC4,	2025;6125;1007
LOGFWD,	2174
LOGACE,	0
	0
LOGOKW,	2174;0200;0
FLOGC1,	2005;5202;3632
	PAGE
ATN,	0
	TAD	ACS
	DCA	FATNSX
	DCA	ACS
	FENTER
	FST+FWD+FATNT-.
	FST+FWD+FATNAX-.
	FSB+FWD+FATNC1-.
	FSGT
	FJMP+FWD+ATNBIG-.
	FSB+FWD+FATNC2-.
	FSGT
	FJMP+FWD+ATNLOW-.
	FLD	ONE
	FDV+FWD+FATNT-.
	FST+FWD+FATNT-.
ATNLOW,	FLD	ZERO
	FST+FWD+FATNC-.
	FLD+FWD+FATNT-.
	FSB+FWD+FATNC3-.
	FSGE
	FJMP+FWD+ATNNOT-.
	FLD+FWD+FATNT-.
	FAD+FWD+FATNC4-.
	FST+FWD+FATNT-.
	FLD+FWD+FATNCJ-.
	FDV+FWD+FATNT-.
	FAD+FWD+FATNC4-.
	FST+FWD+FATNT-.
	FLD+FWD+FATNC5-.
	FST+FWD+FATNC-.
ATNNOT,	FLD+FWD+FATNT-.
	FMP+FWD+FATNT-.
	FST+FWD+FATNTT-.
	FLD+FWD+FATNC6-.
	FMP+FWD+FATNTT-.
	FAD+FWD+FATNC7-.
	FMP+FWD+FATNTT-.
	FAD+FWD+FATNC8-.
	FMP+FWD+FATNTT-.
	FAD+FWD+FATNC9-.
	FMP+FWD+FATNTT-.
	FAD	ONE
	FMP+FWD+FATNT-.
	FAD+FWD+FATNC-.
	FST+FWD+FATNT-.
	FLD+FWD+FATNAX-.
	FSB	ONE
	FSGT
	FJMP+FWD+ATNBIG-.
	FLD+FWD+FATNCH-.
	FSB+FWD+FATNT-.
	FST+FWD+FATNT-.
ATNBIG,	FLD+FWD+FATNT-.
	FEXIT
	TAD	FATNSX
	DCA	ACS
	JMP I	ATN
FATNSX,	0
FATNAX,	0;0;0
FATNT,	0;0;0
FATNTT,	0;0;0
FATNC1,	1634;0000;0000
FATNC2,	2007;7776;0000
FATNC3,	1774;2230;2427
FATNC4,	2016;7331;7272
FATNC5,	2004;1405;2216
FATNC6,	1756;0462;4562
FATNC7,	5764;4221;3403
FATNC8,	1766;3141;6672
FATNC9,	5775;2525;2337
FATNC,	0;0;0
FATNCH,	2016;2207;7325
FATNCJ,	6034;0000;0000
TABDO,	TAD	COLUMN		/GET WHERE WE ARE NOW.
	CIA
	TAD	TABDES		/COMPARE AGAINST WHERE WE WANT TO BE.
	SMA SZA CLA		/DO WE HAVE TO BACK UP?
	JMP	TABOK		/NOPE.
	TAD	O215		/YEP. GIVE C.R.
	JMS I	PPUTCH		/SEND IT
	JMS I	PPUTCH		/ALSO SEND A NULL CHARACTER TO ALL TTY TO RETURN.
TABOK,	TAD	COLUMN		/GET WHERE WE ARE.
	CMA			/NEGATE-1
	TAD	TABDES		/WHERE DO WE WANT TO BE?
	SNA SPA CLA		/?
	JMP I	TPRINT		/HERE. EXIT.
	TAD	O240		/FARTHER UP.
	JMP	TABOK-1		/GIVE SPACE AND LOOP AGAIN.
TABDES,	0
TPRINT,	PRINTC			/NORMAL EXIT LOCATION.

	PAGE
CHKFIT,	0
	TAD	O4
	JMS I	SPLEFT
	JMP I	CHKFIT
	JMS I	PLINFIX
	JMS I	PRESET		/RESET ALL I/O DEVICES.
	JMS I	PPRINTXT
	UGH1
	DCA	SNUMFLG		/RESET THIS FLAG NOW
	JMP I	.+1
	NEWLIN			/THIS MAY BE RIGHT.
RMLEFT,	0
	CLL
	TAD	ARRLOC
	SZL
	JMP	NORLFT
	CIA
	TAD	CODELOC
	SNL CLA
NORLFT,	ISZ	RMLEFT
	JMP I	RMLEFT
ABS,	0
	DCA	ACS
	JMP I	ABS
STICKIT,0
	DCA I	ARRLOC
	ISZ	ARRLOC
	JMP I	STICKIT
INT,	0
	JMS I	PFIX
	CLA
	JMS I	PANORM
	JMP I	INT
SXERR,	0			/INCASE THIS IS JMS'D TO.
	CLA
	DCA	SXERR		/AND REMAKE INTO AN "AND"
	JMS I	PERROR
	TEXT 'SYNTAX'
ATLINE,	TEXT ' AT LINE '
O7570,	7570
UPARROW,TAD	ACS
	SMA CLA
	TAD	O7570
	TAD	ACE
	SMA CLA
	JMP I	PARGERR
	JMS I	PFIX
	JMP I	.+1
	UPARR2
MOREDIM,MUSTBE		/','
	3763
DIM,	CLA CMA
	DCA	DIMFLAG
	JMS I	PEVAL
	ISIT		/(CR) OR '\'
	2000
	JMP	MOREDIM
	JMP I	PEXECUTE/YES
DELETED,TEXT ' DELETED_'
AMATCH,	TAD	WORD
	DCA	SNUMFLG
	TAD	SNUMFLG
	DCA I	FPTR
	ISZ	FPTR
	TAD	GPTR
	DCA	EPTR
	ISIT		/'REM'
	1762
	JMP I	PSLOOP
	JMP I	.+1
	REMPACK
BREAK,	3723;2417;2056
READY,	TEXT '_READY.__'
CRLF=.-1
ISDIG,	0
	JMS I	PNONBLNK
	TAD	O7706A
	CLL
	TAD	O12
	SNL
	CLA
	SZL
	ISZ	ISDIG
	JMP I	ISDIG
O7706A,	7706
PZERDON,TAD	PRTEMP
	TAD	DECEXP
	SPA CLA
	JMP	.+4
	TAD	DECEXP
	CMA
	DCA	PRTEMP
	TAD	PNUMBUF
	DCA	ACE
	CLA CLL CMA RAL
DIGLUP,	CMA
	TAD	DECEXP
	SZA
	JMP	.+3
	TAD	O256B
	JMS I	PPUTCH
	DCA	DECEXP
	TAD I	ACE
	JMS I	PPUTCH
	ISZ	ACE
	ISZ	PRTEMP
	JMP	DIGLUP
	JMP I	.+1		/'''''''' 8 K INSERT RETURN.
	FMTENF
O256B,	256
	PAGE
	LSF=6661
	LCF=6662
	LLS=6666
INTER,	DCA	INTAC		/SAVE ALL IMPORTANT STUFF ON INTERUPT.
	RAR
	DCA	INTL
	RIB
	AND	O70
	TAD	O6202
	DCA	INTCIF		/SAVE INSTRUCTION FIELD
	RIB
	AND	O7
	CLL RTL			/SHIFT IT OVER
	RAL
	TAD	O6201A		/AND THE INSTUCTION FIELD
	DCA	INTCDF
O6201A,	CDF	0		/JUST IN CASE.
	
	IFZERO	MACHINE<
	NOP			/TO KEEP PAGE SAME SIZE.
		>
	TSF			/IS IT THE TELEPRINTER.
	JMP	.+3		/NO
	TCF
	JMP	INODUN		/YEP. CLEAN IT UP.
	LSF			/PRINTER?
	JMP	.+3
	LCF			/YEP.
	JMP	INODUN
	PSF			/PUNCH?
	JMP	.+3
	PCF
	JMP	INODUN
	RSF			/READER?
	JMP	INOPPP		/NOPE.
	CLA CLL CML RAR		/4000 TO AC
	RRB			/READ IN THE CHARACTER.
	DCA I	PHRCHAR
	JMP	INTEXT		/EXIT FROM THE INTERUPT.
INOPPP,	6663			/LINE PRINTER ERROR?
	JMP	INOTTT		/NOPE.
	6667			/YEP. INGORE THE LINE PRINTER NOW.
	JMP	INTEXT		/AND EXIT.
INOTTT,	KSF			/IS IT THE KEYBOARD.
	HLT			/NOPE. A BADDY. WE'RE F--KED.
	KRB			/READ IN THE CHARACTER.
	AND	O177		/CHOP OFF THE CRAP.
	DCA	INTEMP		/SAVE IN THE INTERUPT TEMPORARY.
	TAD	INTEMP		/RECALL IT NOW, BUBBY.
	TAD	O7775		/IS IT A ^C
	SNA			/?
	JMP	FCNTLC		/YES!
	TAD	O7764D		/^O?
	SNA CLA
	JMP	FCNTLO
	CLA CLL CML RAR
	TAD	INTEMP		/SET HIGH ORDER BIT ON FOR SAFETY.
	DCA I	PINCHAR		/PUT IT AWAY
	JMP	INTEXT		/AND EXIT FROM INTERUPT.
FCNTLC,	TAD	NOINT		/CHECK IF OK TO INTERUPT.
	SZA CLA
	JMP	CNTLCF		/NOT OK.
CNTLCR,	IOF			/TURN OFF INTERUPTS TO BE SURE.
	JMS I	DELOUT		/DELETE OUTPUT BUFFERS.
	JMS I	PRESET		/RESET ALL I/O DEVICES.
	JMS I	PPRINTXT	/GIVE THE STOP MESSAGE
	BREAK			/I DON'T LIKE "THOSE PEOPLE" LOOKING OVER MY SHOULDER WHILE I TYPE.
	TAD	PPDLIST		/RESET PUSH DOWN POINTER
	DCA	PDL
	JMP I	PEDIT		/AND RESTART CISAB
CNTLCF,	CMA			/RESET ^C FOUND SWITCH.
	DCA	NOINT
	JMP	INTEXT
FCNTLO,	JMS I	DELOUT		/DELETE THE OUTPUT NOW, BABY.
	TAD	CNTLO		/NEGATE CNTLO SWITCH.
	CMA
	DCA	CNTLO
	JMP	INTEXT
INODUN,	DCA I	POFLAG		/RESET OUTPUT FLAG.
	JMS I	POUTIT		/PREFORM THE NEXT OPERATION.
	JMP	INTEXT
BIDLE,	0			/THE IDLE ROUTINE
	IOF
	CLA IAC
	DCA	BUSY		/RESET THE IDLE TASK FLAG.
	RDF			/SAVE THE DATA FIELD NOW.
	TAD	O6201A
	DCA	INTECDF		/AND PLACE IN WHERE TO GO ON IDLE EXIT.
	TAD	IDLELK		/RESTORE THE IDLE ROUTINES PARAMETERS.
	CLL RAL
	TAD	IDLEAC
IDLECD,	CDF	10
IDLECI,	CIF	0
	ION			/AND DO THE IDLE STUFF
	JMP I	IDLEPC
IDLELK,	0
IDLEAC,	0
IDLEPC,	NULJOB
INTAC,	0
INTL,	0
INTEMP,	0
BUSY,	0
PHRCHAR,HRCHAR
PINCHAR,INCHAR
POFLAG,	OFLAG
POUTIT,	OUTIT
INTEXT,	TAD	BUSY		/GET STATUS.
	SNA CLA
	JMP	INTOU		/WE WERE NOT IDLE. EXIT NOW.
	DCA	BUSY		/RESET BUSY FLAG.
	TAD	0
	DCA	IDLEPC
	TAD	INTAC		/SAVE SH-T.
	DCA	IDLEAC
	TAD	INTL
	DCA	IDLELK
	TAD	INTCIF
	DCA	IDLECIF
	TAD	INTCDF
	DCA	IDLECDF
INTECD,	HLT			/IDLE ROUTINES CALLING CDF.
	ION
	JMP I	BIDLE		/AND GO BACK NOW.
INTOU,	TAD	INTL
	CLL RAL
	TAD	INTAC
INTCDF,	HLT
INTCIF,	HLT
	ION
	JMP I	0
O70,	70
O6202,	6202
O7775,	7775
O7764D,	7764
	PAGE
PUTER,	0			/THE CHARACTER PUTTER.
	DCA	OPUTC		/SAVE THE CHARACTER NOW.
	RDF			/READ THE DATA FIELD NOW.
	TAD	O6201B		/CREATE PROPER CDF INSTRUCTION.
	DCA	PUTCDF		/SAVE CDF INSTRUCTION.
O6201B,	CDF	0		/RESET CDF TO THIS DATA FIELD.
	SKP
PUTLP,	JMS I	PBIDLE		/CALL IN THE IDLE ROUTINE NOW.
	TAD	OCOUNT		/GET NUMBER OF CHARACTERS IN THE BUFFER.
	SNA
	JMP	PUTCIN		/PUT IT IN NOW, BABY.
	TAD	OCMLIM		/TEST FOR TOO MANY IN BUFFER.
	SNA CLA
	JMP	PUTLP		/YEP. WAIT AWHILE.
	TAD	OUTDEV
	CIA
	TAD	ODEV		/CHECK FOR A MATCH.
	SZA CLA
	JMP	PUTLP		/NOPE. WAIT FOR BUFFER TO BECOME EMTPY.
PUTCIN,	IOF			/TURN THEM OFF, BABY.
	TAD	CNTLO		/CHECK FOR CONTROL "O" ACTIVE.
	SNA CLA
	TAD	OUTDEV		/MOVE OVER OUTPUT DEVICE.
	DCA	ODEV
	ISZ	OCOUNT
	TAD	OPUTC		/STICK A CHARACTER IN THE BUFFER.
	DCA I	IPOINT
	JMS	OBOP		/BOP UP THE POINTER NOW.
IPOINT,	OBLOW
	JMS	OUTIT		/SEND IT OUT
	ION			/RESTORE INTERUPTS.
PUTCDF,	HLT			/USER'S CORRECT CDF
	JMP I	PUTER
OPUTC,	0
OCOUNT,	0
OUTIT,	0
	TAD	OFLAG
	SZA CLA
	JMP I	OUTIT		/FLAG STILL UP. EXIT.
	TAD	OCOUNT
	SNA
	JMP I	OUTIT		/NO CHARS TO GO. SO WE WILL.
	TAD	O7777		/PLEASE IGNORE THE COMMENTS OF A DERANGED MIND.
	DCA	OCOUNT
	TAD	ODEV
	TAD	OPOTAB		/MAP DEVICE INTO TABEL TOO ET WHAT TO DO.
	DCA	OFLAG		/AND ALSO RESET FLAG AT THE SAME TIME.
	TAD I	OFLAG		/GET THE MAGIC INSTUCTION.
	DCA	.+2		/AND PLACE IT HERE.
	TAD I	OPOINT		/GET THE CHARACTER.
	HLT			/AND HALT.
	CLA			/AFTER PRINTING THE CHARACTER,
	JMS	OBOP		/WE SHALL INCREMENT THE POINTER.
OPOINT,	OBLOW
	JMP I	OUTIT		/AND EXIT.
OPNUL,	CLA			/RESET OFLAG
	DCA	OFLAG		/SO DEVICES INACTIVE.
	JMS I	DELOUT		/DELETE ANY STRAY CHARACTERS IN THE BUFFER.
	JMP I	OUTIT		/AND RETURN NOW.
OPOTAB,	.+1
	JMP	OPNUL		/NUL DEVICE (NO ECHOING)
	TLS
	PLS
	LLS
OFLAG,	0
OBOP,	0
	TAD I	OBOP
	TAD	OTST1
	SNA
	TAD	OFLOW
	TAD	OCOR
	DCA I	OBOP
	ISZ	OBOP
	JMP I	OBOP
OTST1,	-OBHIGH
OCOR,	OBHIGH+1
O7777,	7777
OFLOW,	-OBHIGH-1+OBLOW
OCMLIM=OFLOW
RESET1,	0
	CLA IAC
	DCA	OUTDEV
	CLA IAC
	DCA	OUTD2
	CLA IAC
	DCA	INDEV
	DCA	CNTLO
	DCA	NOINT		/CLEAR NO-INTERUPT FLAG.
	CDF	0		/RESET DATA FIELD TO HERE.
	DCA I	QHRCHAR		/CLEAR ALL INPUT FLAGS.
	DCA I	SINCHAR
	DCA I	PBUSY		/AND ALSO THE BUSY FLAG.
	DCA I	PPXRA		/RESET NULL AFTER C.R. FLAG.
	IFZERO	MACHINE<
	CDF	10
	ION
		>
	6665			/TELL LPT IT'S OK TO INTERUPT NOW.
	JMP I	RESET1
LLLUUU,	UUULLL			/POINTER TO UPPER CORE RESETER.
RESET2,	0
	JMS I	PRESET
	JMS I	DELOUT
	DCA	OFLAG
	JMP I	RESET2
OUTDEL,	0
	DCA	OCOUNT
	TAD	OPRST
	DCA	OPOINT
	TAD	OPRST
	DCA	IPOINT
	JMP I	OUTDEL
OPRST,	OBLOW
QHRCHAR,HRCHAR
PBUSY,	BUSY
PPXRA,	PUTXRA
PBIDLE,	BIDLE
SINCHAR,INCHAR
LPTOUT,	CLA IAC			/LINE PRINTER OUTPUT
PTPOUT,	IAC			/PUNCH OUT
TTYOUT,	IAC			/TTY OUT
	DCA	OUTDEV		/AND SET IT UP
	TAD	OUTDEV		/ALSO MOVE OVER TO SECONDARY DEVICE.
	DCA	OUTD2
	JMP	DEVCOM		/AND CHECK FOR END.
PTRIN,	CLA IAC
TTYIN,	IAC
	DCA	INDEV
DEVCOM,	JMS	GETWD
DEVCON,	MUSTBE
	2000			/C.R. OR \
	JMP I	PEXECUTE
GETCH,	0
	JMS	GWHERE
	JMS I	QBIDLE
	TAD	INCHAR
	SNA
	JMP	GETCH+2
	AND	O177
	DCA	GTEMP
	DCA	INCHAR
	DCA	HRCHAR
	TAD	RBSWCH
	SNA CLA
	JMP	GRB
	TAD	GTEMP
	TAD	O7601
	SZA CLA
	JMP	GRB
GRDELA,	TAD	O137
	JMP I	GETCH
GRB,	TAD	GTEMP
	TAD	O7770
	SNA
	JMP	GRDELA
	TAD	O7612
	SNA
	JMP	GALT
	TAD	O143
	SNA CLA
	JMP	GALT
	TAD	GTEMP
	TAD	O7640C
	SPA
	JMP	GOUT
	TAD	O7746
	SMA
	JMP	GOUT
	TAD	O132
	JMP I	GETCH
GALT,	TAD	O175
	JMP I	GETCH
GOUT,	CLA
	TAD	GTEMP
	JMP I	GETCH
GTEMP,	0
INCHAR,	0
HRCHAR,	0
QBIDLE,	BIDLE
O7601,	7601
O137,	137
O7612,	7612
O7640C,	7640
O7746,	7746
O132,	132
O143,	143
O175,	175
GWHERE,	0
	CLA CMA
	TAD	INDEV
	ISZ	GWHERE
	SPA SNA CLA
	JMP I	GWHERE		/INPUT=TTY
	TAD	O7746
	DCA	GTEMP
	DCA	HRCHAR
	RFC			/START THE READER NOW.
HRLOP,	TAD	HRCHAR
	SZA
	JMP	HFOUND		/GOT IT.
	ISZ	INCHAR
	JMP	HRLOP
	ISZ	GTEMP
	JMP	HRLOP
	CLA IAC
	DCA	OUTDEV		/RESET OUTPUT DEVICE FOR A SECOND.
	DCA	CNTLO		/RESET THE CONTROL "O" SWITCH ALSO.
	JMS I	PPRINTXT	/GIVE THE MESSAGE.
	HRMES
	CLA IAC
	DCA	INDEV
	JMP I	GWHERE
HFOUND,	ISZ	GWHERE
	JMP I	GWHERE
HRMES,	TEXT	'_TTY_'
COWT,	0			/THIS ROUTINE WAITS FOR OUTPUT TO STOP.
	CDF	0		/SET D.F. TO THIS FIELD.
	DCA I	CCXRA		/SET OR RESET NULL AFTER C.R. FLAG.
COWTLP,	TAD I	COWTFP		/GET OUTPUT FLAG STATUS.
	CDF	10		/RESET D.F.
	SNA CLA			/IS OUTPUT DONE?
	JMP	COWTO		/YEP. EXIT.
	JMS I	COWTW		/NOPE. IDLE LOOP TILL INTERUPT.
	CDF	0		/RESET D.F. TO ZERO.
	JMP	COWTLP		/AND LOOP.
COWTO,	DCA	CNTLO		/CLEAR CONTROL O STATE.
	JMP I	COWT
CCXRA,	PUTXRA
COWTFP,	OFLAG
COWTW,	BIDLE
XGMUST,	0
	JMS	GETWD
	TAD	XGMUST
	DCA	XMUST
	JMP	XMUST+1
XMUST,	0
	TAD I	WORD
	CDF	0		/''''''''' 8 K INSERT.
	TAD I	XMUST
	CDF	10		/''''''''' 8 K INSERT.
	ISZ	XMUST
	SNA CLA
	JMP I	XMUST
	JMP I	PSXERR
ARGERR,	JMS I	PERROR
	TEXT	'ARGUMENT'
DOTZERO,TEXT '.0'
RTERR,	JMS I	PERROR		/GIVE RATE ERROR FOR CLOCK.
	TEXT	'RATE'
	PAGE
	IFZERO	MACHINE<
	NOPUNCH>
PLOT,	TAD	DISB		/GET BUFFER ADDRESS.
	SZA CLA			/IS THERE ONE?
	JMP	DBGOT
	TAD	PASSUME		/GET ASSUMMED LENGTH.
	JMS I	SPLEFT		/ROOM LEFT TO FIT IT IN.
	SKP
	JMP I	NPSPERR		/NO.
	TAD	ARRLOC		/GET A USABLE ADDRESS.
	DCA	DLAST		/SAVE AWAY.
	TAD	ARRLOC		/NOW UPDATE OUR ARRAY.
	TAD	PASSUME
	DCA	ARRLOC
	CLA CMA
	TAD	ARRLOC		/GET LAST WORD OF OUR BUFFER NOW.
	DCA	DDLAST		/AND GO.
	JMS	PLOTB		/FIGURE OUT OUR CRAP NOW.
DBGOT,	DCA	DBAD		/TELL IT POINT IS ON SCREEN
	JMS	GETWD		/GET NEXT SYNTATICAL ELEMENT.
	JMS I	PMEVAL		/EVALUATE OUR EXPRESSION.
	FENTER
	FMP+FSHIFT+FWD-.	/CORRECT NUMBER FOR SYMETRICAL SCREEN.
	FEXIT
	JMS	DBLIT		/PUT IT IN THE BUFFER.
	JMS I	PMEVAL		/GET Y COORDINATE.
	JMS	DBLIT		/PUT IT IN THE BUFFER.
	TAD	DBAD		/IS IT A BAD ONE? <OFF SCREEN?>
	CIA
	TAD	DINP
	DCA	DINP
	CLA CLL CML RAR		/4000=END OF BUFFER CHARACTER.
	DCA I	DINP
	JMP I	PDEVCON
PASSUME,1750
PMEVAL,	MEVAL
PDEVCON,DEVCON
FSHIFT,	2007;1600;0000		/MAGIC CONSTANT FOR SYMETRICAL SCREEN.
USE,	TAD	DISB		/IS DISPLAY BUFFER ASSIGNED.
	SZA CLA
	JMP I	USKIPIT		/YES. EXIT.
	JMS	GETARY		/GET THE ARRAY DATA
	TAD	AC1		/GET FIRST FREE LOCATION
	DCA	DLAST
	TAD	AC2		/GET SECOND FREE LOCATION
	DCA	DDLAST		/SAVE AWAY.
	JMS	PLOTB		/SET UP STUFF.
	JMS	GETWD		/GET NEXT ELIMAENT AFTER VARIABLE.
	JMP I	PDEVCON
USKIPIT,SKIPIT
GETARY,	0			/THIS ROUTINE GETS THE FIRST AND LAST LOCATIONS OF AN ARRAY.
	GET+MUSTBE		/MUST BE A VARIABLE.
	7000
	TAD	WORD		/GET POINTER TO VARIABLE.
	DCA	UVP
	ISZ	WORD
	TAD I	WORD		/GET POINTER NOW.
	IAC
	DCA	AC1		/SAVE AWAY.
	ISZ	WORD
	TAD I	WORD
	DCA	U1P
	ISZ	WORD
	TAD I	WORD
	DCA	U2P
	JMS I	PGETADD
UVP,	0
U1P,	0
U2P,	0
	CLA CLL CML RTL		/+2
	TAD	ADDRESS
	DCA	AC2
	JMP I	GETARY
DLAST,	0
DINP=DLAST
DDLAST,	0
DBAD,	0
PLOTB,	0
	CLA CMA
	TAD	DLAST
	DCA	DISB
	TAD	O4001
	DCA I	DDLAST
	CLA CLL CML RAR
	DCA I	DLAST
	JMP I	PLOTB
O4001,	4001
DBLIT,	0
	TAD	ACS
	SMA CLA
	JMP	.+4
DBBAD,	CLA CLL CML RTL
	DCA	DBAD
	JMP	DBISRT
	TAD	ACE
	TAD	O7577B
	SMA CLA
	JMP	DBBAD
	TAD	ACE
	TAD	O12
	DCA	ACE
	JMS I	PFIX
	CLA
	TAD	AC3
DBISRT,	JMS	DBPUT
	CLA CLL CML RAR
	ISZ	DINP
	JMS	DBPUT
	JMP I	DBLIT
O7577B,	7577
NPSPERR,SPACERR
DBPUT,	0
	DCA	AC2
	CLA CLL CMA RAR		/-4001=3777
	TAD I	DINP
	SNA CLA
	JMP I	NPSPERR		/NO ROOM IN BUFFER. BOMB HIM.
	TAD	AC2
	DCA I	DINP
	JMP I	DBPUT
UUDATA,	JMS I	PERROR
	TEXT	'A-D FULL'
	ENPUNCH

	IFZERO	MACHINE<
	*PLOT>
SETUP,	0
	TAD	PSYMTAB
	DCA	EPTR
	TAD	NSYMTAB
	DCA	FPTR
	DCA	DISB
	JMP I	SETUP

	IFZERO	MACHINE<
	CDEVCOM=0
		>
ISET,	0
	DILC
	DIXY
	JMS I	IIXR
	JMP I	ISET
IIXR,	RESET2

	IFZERO	MACHINE<
	NOPUNCH>
MEVAL,	0
	ISIT			/IS IT A C.R.
	2000
	SKP
	JMP I	PSXERR
	ISIT
	3763			/,
	JMP	.+3
	JMS	GETWD
	JMP	MEVAL+1
	TAD	MEVAL
	JMP I	MEVALGO
MEVALGO,EVALGO
CLEAR,	TAD	DISB
	SNA			/IS IT THERE?
	JMP I	CDEVCOM		/NOPE.
	DCA	INDEX1
	CLA CLL CML RAR		/4000
	DCA I	INDEX1
	CDF	0		/RESET INPUT POINTER ALSO.
	TAD	INDEX1
	DCA I	CDINP
	CDF	10
	JMP I	CDEVCOM
CDINP,	DINP
LLLJMS,	0
	TAD I	LLLJMS
	ISZ	LLLJMS
	DCA	LLLJMP
	JMS I	LLLJMP
	SKP			/IN CASE OF SKIPPING RETURN.
	ISZ	LLLJMS
	CIF CDF 10
	JMP I	LLLJMS
LLLJMP,	0
	TAD I	LLLJMP
	DCA	LLLJMP
	JMP I	LLLJMP
DELAY,	CLA CLL CML RTL		/+2
	DCA	NDELAY		/SET UP DEALY TIME (ONE TIME THROUGH).

	IFZERO	MACHINE<
	ENPUNCH
	*MEVAL
NULJOB,	IAC
	JMP	NULJOB
	NOPUNCH>
	DCA	DISAUTO		/WITH POINTER TO OUR BUFFER.
	TAD	NDELAY		/UPDATE DELAY WORD.
	CLL RAR
	DCA	NDELAY
	SZL			/ARE WE FINISHED WITH DELAY COMMAND?
	JMP I	CDEVCOM		/YEP. EXIT NOW.
	TAD	DISB		/GET OUR WORD NOW.
	SNA CLA			/ZERO?
	JMP	NULJOB		/YEP. WAIT AWHILE.
NULLOP,	TAD I	DISAUTO
	SPA
	JMP	NULCMD
	TAD	O7000C		/BRING DOWN INTO RANGE OF SCREEN.
	DISD
	JMP	.-1
	DILX
	CLA
	TAD I	DISAUTO
	SPA
	JMP	NULCMD
	TAD	O7000C		/CENTER AGAIN.
	DISD
	JMP	.-1
	DILY
	CLA
	DISD
	JMP	.-1
	DIXY
	JMP	NULLOP
NULCMD,	CLA
	JMP	NULJOB
O7000C,	7000
NINTECDF,INTECDF
UUNOAD,	JMS I	PERROR
	TEXT	'NO A-D'
CCINTK,	0
	6131
	JMP I	CCINTK
	CIF CDF	10
	JMP I	.+1
	CLOCKI
	REALTI=.
	SETRAT=.
	SETCLO=.
	WAITC=.
	WAIT=.
	REJECT=.
	ACCEPT=.
	
	TAD I	WORD
	CDF CIF	10
	JMP I	.+1
	UPCOMDO
	TIM=.
	CLC=.
	CLS=.
	ADC=.
	ADB=.
	0
	TAD I	PDL		/RECALL CORRECT FUNCTION NUMBER (IT'S ON THE STACK)
	CIF CDF	10
	JMS I	.+2
	JMP I	ADB
	UPFUN
	ENPUNCH
	IFZERO	MACHINE<
	*NULJOB+2>
TSTFX,	BEGFIX
NDELAY,	0
TST,	0
	JMS I	TSTFX
	CDF	0
	TAD I	TSTP
	CDF	10
	DCA	AC3
	JMS I	PANORM
	JMP I	TST
TSTP,	INCHAR
	FIELD	1
	*0
TEN,	2045;0000;0000		/INSERTED IN UPPER CORE BECAUSE OF FEEBILITY.
CLKSTS,	0
TIM1,	0
TIM2,	0
ABDGET,	0
ADACPT,	0
ADCUNT,	0
CLTEMP,	0
ADCX,	0
U100,	100
CT3,	0
CT2,	0
CT1,	0
U177,	177
U4707,	4707
U7775,	7775
ACOUNT,	0
APUT1,	0
APUT2,	0
ADA1,	0
ADA2,	0
ADA3,	0
UUSETF,	USETF
UMEVAL,	UUMEVAL
UPFIX,	UUPFIX
U7,	7
U5010,	5010
U7767,	7767
U10,	10
UAC1,	UUAC1
UAC2,	UUAC2
UAC3,	UUAC3
PPAC1,	AC1
PPAC2,	AC2
PPAC3,	AC3
PPACE,	ACE
PPACS,	ACS
U17,	17
U7777,	7777
UDOAD,	DOAD
U7760,	7760
UTEMP,	0
UJMP,	UUJMP
UJMS,	UUJMS
UDEVCON,UUDEVCON
UGETWD,	6000
	JMS I	UJMS
	GETWD
	JMP I	UGETWD
AUTEMP,	0
ADCCOR,	-11			/ABOUT 512 FOR FUDGE.
	PAGE
	*.-3
CLOCKI,	6135			/CLEAR CLOCK FLAG.
	DCA	CLKSTS		/AND SAVE STATUS.
	ISZ	TIM2		/INCREMENT CLOCK.
	JMP	.+3
	ISZ	TIM1
	NOP
	TAD	ABDGET		/IS REAL TIME OPTION RUNNING?
	SPA SNA CLA
	JMP	UIEXT		/NOPE.
	TAD	ADACPT		/IT SO, ARE WE NOW ACCEPTING DATA?
	SNA CLA
	JMP	UIEXT		/NOPE.
	TAD	ADCUNT		/YEP. GET NUMBER OF CHANNELS TO DO.
	DCA	CLTEMP		/SET UP OUR COUNTER.
	TAD	ADCX		/GET STARTING CHANNEL NUMBER.
	6531			/SEND TO TO CONTROLLER.
	TAD	U100		/TELL IT TO INCREMENT MULTIPLEXOR WHEN DONE.
	6536
UCLOOP,	JMS I	UDOAD		/PREFORM A-D INSTRUCTION.
	JMS	APUT		/STORE IN USERS BUFFER.
	ISZ	CLTEMP		/ALL DONE?
	JMP	UCLOOP		/NOPE. WAIT.
	ISZ	CT3		/DONE. INCREMENT TOTAL NUMBER OF SAMPLES.
	JMP	UIEXT
	ISZ	CT2
	JMP	UIEXT
	ISZ	CT1
	JMP	UIEXT
	CLA CMA			/ALL DONE. STOP SAMPLING.
	DCA	ABDGET
	DCA	ADACPT		/AND GO INTO "REJECT" MODE.
UIEXT,	6031			/HAS HE TYPED A CONTROL C?
	JMP	UIEXT2		/NO.
	6034
	AND	U177
	TAD	U7775		/^C?
	SNA CLA
	JMP	UIEXT3		/YES! BOMB HIM.
UIEXT2,	6131
	JMP	UIEXT4		/CLOCK HAS NOT COME UP AGAIN. ALL IS WELL.
UIEXT3,	TAD	U4707		/STOP CLOCK IMMEADIATATELY.
	6132
	6135
	6130
	CLA CMA
	6130			/CLEAR ALL AFTER PARTIAL ENABLE.
	6032			/CLEAT TTY FLAG.
	DCA	ABDGET		/FREE BUFFER AND ACCEPT MODE.
	DCA	ADACPT
	JMS I	UJMP
	RTERR
UIEXT4,	CIF CDF	0		/INTERUPT EXIT.
	JMP I	.+1
	INTEXT			/AND DO WHATEVER GOD INTENDED.
APUT,	0			/THIS ROUTINE PUTS A SAMPLE IN THE BUFFER.
	DCA I	APUT1		/PLACE IN BUFFER.
	ISZ	ACOUNT		/INCREMENT COUNTER.
	JMS	ABOP		/BOP UP POINTER.
	APUT1
	TAD	APUT1		/GET INPUT POINTER.
	CIA
	TAD	APUT2		/DOES IT MATCH OUTPUT POINTER?
	SZA CLA
	JMP I	APUT		/NOPE. ALL IS WELL.
	DCA	ABDGET		/FREE BUFFER.
	DCA	ADACPT		/AND ACCEPT.
	JMS I	UJMP		/GIVE ERROR.
	UUDATA			/A-D ERROR.
AGET,	0			/THIS GETS A DATA ITEM FROM BUFFER.
	CLA CMA			/DECREMENT COUNTER.
	TAD	ACOUNT
	SMA			/OR SHOULD WE?
	JMP	.+5		/YEP. STILL ITEMS LEFT.
	CLA
	JMS I	UJMS		/PUT TO SLEEP
	BIDLE
	JMP	AGET+1		/AND CHECK AGAIN WHEN AWAKE.
	DCA	ACOUNT		/SAVE COUNTER.
	TAD I	APUT2		/GET THE SAMPLE.
	DCA	ATEMP		/SAVE WHILE UPDATE TAKES PLACE.
	IOF
	JMS	ABOP
	APUT2
	ION			/ABOP WILL F--K YOU UP IF CALLED RE-ENTRENTLY.
	TAD	ATEMP
	JMP I	AGET
ATEMP,	0
ATEMP2,	0
ABOP,	0
	TAD I	ABOP
	DCA	ATEMP2		/SAVE POINTER NOW.
	TAD I	ATEMP2
	ISZ	ABOP		/GET VALUE AND SKIP PAST POINTER #1.
	TAD	ADA1		/TEST AGAINST UPPER.
	SNA
	TAD	ADA2		/CORRECT TO LOWER.
	TAD	ADA3		/AND ADD IN UPPER.
	DCA I	ATEMP2		/AND THEN SAVE AWAY.
	JMP I	ABOP		/AND THEN EXIT.
UCLS,	0			/GETS STATUS AFTER LAST CLOCK INTERUPT.
	TAD	CLKSTS
	JMS I	UUSETF
	0
	JMP I	UCLS		/RETURN WHEN DONE.
UCLC,	0			/READS IN AS A CLCA
	6137			/GET COUNT REGISTER.
	JMS I	UUSETF
	0			/FIX IT UP.
	JMP I	UCLC		/AND RETURN NOW.
UUULLL,	0
	CLA
	DCA	ACOUNT
	DCA	ABDGET
	DCA	ADACPT
	ION
	CIF	0
	JMP I	UUULLL
DOAD,	0
	TAD	U7760		/PLENTY OF DELAY
	DCA	DSCREW		/SAVE IN A COUNTER WORD.
	6532			/START CONVERSION.
DOADLP,	6534			/WAIT UNTIL DONE.
	SKP			/IF NOT DONE, WAIT SOME.
	JMP	.+3		/IF DONE, READ IT IN.
	ISZ	DSCREW
	JMP	DOADLP		/WAIT UNTIL DONE OR TOO LONG.
	6533			/THEN READ IN THE CONVERTED NUMBER.
	JMP I	DOAD		/AND RETURN.
DSCREW,	0
	PAGE
USETR,	JMS	UGETWD		/BOP PAST CHAR.
	JMS I	UMEVAL		/THIS ROUTINE SETS UP CLOCK TO A GIVEN TIME.
	JMS I	UPFIX		/FIX  UP AC.
	AND	U7		/JUST GET SIGNIFICANT BITS (0-7).
	CLL RTL			/NOW MOVE TO TIME PORTION (3-5)
	RTL
	RTL
	TAD	U5010		/SET OTHER CORRECT BITS NOW.
	JMP	USETM
USETC,	JMS	UGETWD		/BOP PAST BAD POINTER.
	JMS I	UMEVAL		/THIS ROUTINE LOADS CLOCK WITH USERS COMMAND REGISTER.
	JMS I	UPFIX
	AND	U7767		/MAKE SURE TO TURN INTERUPTS ON.
	TAD	U10
USETM,	DCA	UTEMP		/SAVE ENABLE REGISTER FOR A SECOND.
	CLA CMA			/CLEAR CLOCK NOW.
	6130
	CLA			/SO WE CAN LOAD IN CORRECT STUFF.
	JMS I	UMEVAL		/EVALUATE HIS TIME SETTING.
	JMS I	UPFIX
	CIA
	IOF			/MAKE SURE INTERUPTS ARE OFF.
	6133
	CLA
	DCA	TIM1		/CLEAR OUT THE TIM NOW.
	DCA	TIM2
	TAD	UTEMP		/RECALL DESIRED ENABLE REGISTER.
	6132			/SEND IT OUT.
	ION			/TURN ON INTERUPTS NOW.
	CLA
	JMP I	UDEVCON		/AND EXIT NOW.
UWAIT,	CLA CMA			/WAITS FOR AN INTERUPT. SET TO LOOK LIKE CLOCK DID IT.
UWAITC,	TAD	TIM2		/GET LOW ORDER WORD.
	DCA	UTEMP		/SAVE FOR AWHILE.
	JMS I	UJMS
	BIDLE			/PUT TO SLEEP.
	TAD	UTEMP		/WAS IT CLOCK (OR OTHER IF CLOCK FUDGED?)
	CIA
	TAD	TIM2		/COMPARE AGAINST PRESENT CLOCK.
	SNA CLA
	JMP	UWAITC+2	/NOT CORRECT. WAIT SOME MORE.
RANDAE,	JMS I	UJMP
	DEVCOM
UACCPT,	TAD	ABDGET		/IS BUFFER ASSIGNED?
	SZA SMA CLA
	CLA IAC			/YEP. WE CAN ACCEPT NOW.
UREJT,	DCA	ADACPT		/OR REJECT.
	JMP	RANDAE		/AND THEN EXIT.
				/REAL TIME DECODING FUNCTION.
UREAL,	TAD	ADACPT		/ARE WE ACCEPTING NOW?
	SNA CLA
	JMP	.+3
	JMS I	UJMP
	SKIPIT
	JMS I	UJMS
	GETARY			/PICK UP BUFFER ITEMS.
	JMS I	UAC1		/GET WE FIRST WORD OF ARRAY.
	DCA	APUT1		/SAVE AWAY NOW.
	TAD	APUT1		/ALSO SET UP OUTPUT POINTER.
	DCA	APUT2
	JMS I	UAC2		/GET LAST WORD OF ARRAY.
	CIA
	DCA	ADA1		/SAVE IN UPPER LIMIT TESTER.
	JMS I	UAC2		/GET AGAIN.
	IAC			/ADD ONE.
	DCA	ADA3		/AND SAVE AWAY IN BOPPER WORD.
	TAD	ADA3		/FINALLY GET THE RESET WORD.
	CIA
	TAD	APUT1
	DCA	ADA2		/AND SAVE AWAY FOR WRAP AROUND CONDITION.
	JMS	UGETWD		/BYPASS REAL TIME STATEMENT.
	JMS I	UMEVAL		/EVALUATE AN EXPRESSION
	JMS I	UPFIX		/FIX THE AC NOW.
	AND	U17		/JUST GET CHANNEL NUMBER.
	DCA	ADCX		/SAVE AWAY.
	JMS I	UMEVAL		/EVALUATE ANOTHER ITEM.
	JMS I	UPFIX		/FIX IT UP.
	SZA			/IF ZERO, DO NOT SUBTRACT ONE.
	TAD	U7777		/SUBTRACT ONE TO BRING INTO 0-17 RANGE.
	AND	U17		/MAKE INTO 0-17.
	CMA			/NOW NEGATE AND SUBTRACT ONE.
	DCA	ADCUNT		/AND SAVE AWAY CORRECT ISZ COUNTER.
	JMS I	UMEVAL		/NOW GET NUMBER OF SAMPLES (CLOCK TICKS)
	JMS I	UPFIX
	CLL CML CIA
	DCA	CT3		/SET UP LOW ORDER WORD OF COUNTER.
	RAL			/AND PRESERVE CARRY.
	JMS I	UAC2
	CLL CML CIA
	DCA	CT2
	RAL
	JMS I	UAC1
	CLL CML CIA
	DCA	CT1
	DCA	ACOUNT		/CLEAR PRESENT BUFFER COUNTER.
	CLA IAC
	DCA	ABDGET		/SET UP BUFFER.
	JMP I	UDEVCON
UTIM,	0			/RETURNS CLOCK TICK.
	TAD	TIM1
	DCA	.+3
	TAD	TIM2
	JMS I	UUSETF
	0
	JMP I	UTIM
USETF,	0
	DCA	UTEMP		/SAVE LOW ORDER WORD OF FAC.
	JMS I	UJMS
	BEGFIX			/PREPARE TO INTERGIZE IT.
	TAD I	USETF		/GET MIDDLE WORD.
	CDF	0
	DCA I	PPAC2		/PLACE IN FAC.
	TAD	UTEMP		/GET LOW WORD.
	DCA I	PPAC3		/PLACE IN FAC.
	CDF	10
	JMS I	UJMS
	ANORM
	ISZ	USETF		/BYPASS VALUE
	JMP I	USETF		/RETURN NOW.
	PAGE
UADCB,	0			/THIS RETURNS A VALUE FROM THE A-D.
	SPA CLA			/BUFFERED OR DIRECT?
	JMP	UADCN		/DIRECT.
	TAD	ABDGET		/CHECK TO SEE WHETHER BUFFER ASSGINED.
	SNA
	JMP	UABAD		/NO BUFFER ASSIGNED.
	SPA CLA			/IS BUFFER ACTIVE?
	JMP	UADCMY		/NO. GET COUNT.
	TAD	ADACPT		/ACTIVE. ARE WE ACCEPTING DATA?
	SNA CLA
	JMP	UADCMY		/NO. CHECK COUNT IN BUFFER.
UADCIN,	JMS I	UPAGET		/GET VALUE FROM A-D BUFFER.
	JMP	UINAC		/AND FIX IT UP.
UADCMY,	TAD	ACOUNT		/GET BUFFER COUNTER NOW.
	SZA CLA			/=0?
	JMP	UADCIN		/NOPE. WE CAN RETURN SOME DATA.
UABAD,	JMS I	UJMP
	UUNOAD			/NO A-D DATA IN BUFFER. HE'S F--KED.
UADCN,	JMS I	UPFIX		/NON-REAL TIME.
	AND	U17		/JUST GET CHANNEL NUMBER.
	IOF			/WE CANNOT BE INTERUPTTED HERE.
	6531
	6536
	JMS I	UDOAD		/PREFORM THE CONVERSION NOW.
	ION			/RESTORE INTERUPTS.
UINAC,	DCA	AUTEMP		/SAVE FOR A SECOND.
	TAD	AUTEMP		/PLACE ABSOLUTE VALUE IN FAC.
	SPA
	CIA
	JMS I	UUSETF
	0
	TAD	AUTEMP		/NOW SET SIGN OF FAC.
	CDF	0		/SET TO PICK UP FIELD 0. NO COOLNESS LEFT, DESPITE COMMENTS.
	SPA CLA			/IF POSITVE LEAVE ALONE.
	CLA CLL CML RAR		/SET LEFT MOST BIT ON TO INDICATE NEGATIVE.
	DCA I	PPACS
	TAD I	PPACE		/GET EXPONENT NOW.
	TAD	ADCCOR		/BRING INTO CORRECT RANGE NOW.
	SMA			/IF TOO FAR,
	DCA I	PPACE		/DON'T CORRECT.
	CLA
	CDF	10		/RESET CDF.
	JMP I	UADCB		/RETURN TO FIELD ONE (COOL ,UGH!)
UPAGET,	AGET
UUAC1,	0
	CDF	0
	TAD I	PPAC1
	CDF	10
	JMP I	UUAC1
UUAC2,	0
	CDF	0
	TAD I	PPAC2
	CDF	10
	JMP I	UUAC2
UUAC3,	0
	CDF	0
	TAD I	PPAC3
	CDF	10
	JMP I	UUAC3
UUMEVAL,0
	JMS I	UJMS
	MEVAL
	JMP I	UUMEVAL
UUPFIX,	0
	JMS I	UJMS
	FIX
	CLA
	JMS I	UAC3
	JMP I	UUPFIX
UUDEVC,	JMS I	UJMP
	DEVCON
UUJMS,	0
	CIF	0
	TAD I	UUJMS
	DCA	.+2
	JMS I	UUUJMS
	0
	SKP			/IN CASE OF SKIPPING RETURN
	ISZ	UUJMS
	ISZ	UUJMS
	JMP I	UUJMS
UUUJMS,	LLLJMS
UUJMP,	0
	CIF	0
	TAD I	UUJMP
	DCA	.+2
	JMS I	UUUJMP
	0
UUUJMP,	LLLJMP
UPCOMDO,TAD	UUFUDGE
	TAD	UPJMP
	DCA	.+1
	HLT
UUFUDGE,-6040
UPJMP,	JMP I	.+1
	UREAL
	USETR
	USETC
	UWAITC
	UWAIT
	0000			/NOT USED NOW.
	UACCPT
	UREJT
UPFUN,	0
	TAD	UFFUD
	TAD	UFJMP
	DCA	.+1
	HLT
	CIF	0
	JMP I	UPFUN
UFFUD,	-21
UFJMP,	JMS I	.+1
	ZZADC
	0000
	UTIM
	0000
	0000
	UCLS
	UCLC
	ZZADB
ZZADC,	0
	CLA CMA
	JMS I	.+2
	JMP I	ZZADC
	UADCB
ZZADB,	0
	JMS I	ZZADB-1
	JMP I	ZZADB
	PAGE
	IFZERO	MACHINE<
	LIMIT=TEN+3
		>

	*7022
PERMSYM,0
XXPLUS,	4200;TEXT '+'
XXMINUS,4201;TEXT '-'
XXSTAR,	4302;TEXT '*'
XXSLASH,4303;TEXT '/'
XXUPARR,4404;TEXT '^'
XXLE,	4110;TEXT '<='
XXGE,	4111;TEXT '>='
XXNE,	4112;TEXT '<>'
XXEG,	4111;TEXT '=>'
XXEL,	4110;TEXT '=<'
XXEQ,	4105;TEXT '='
XXLT,	4106;TEXT '<'
XXGT,	4107;TEXT '>'
XXCOMMA,4015;TEXT ','
XXSEMI,	4016;TEXT ';'
XXCLOSE,4017;TEXT ')'
XXRBRAK,4017;TEXT ']'
XXTO,	4021;TEXT ' TO '
XXSTEP,	4022;TEXT ' STEP '
XXOPEN,	4023;TEXT '('
XXLBRAK,4023;TEXT '['
XXFN,	4024;TEXT 'FN'
XXCOS,	4025;TEXT 'COS'
XXTAN,	4026;TEXT 'TAN'
XXATN,	4027;TEXT 'ATN'
XXLOG,	4030;TEXT 'LOG'
XXEXP,	4031;TEXT 'EXP'
XXSQR,	4032;TEXT 'SQR'
XXABS,	4033;TEXT 'ABS'
XXSGN,	4034;TEXT 'SGN'
XXINT,	4035;TEXT 'INT'
XXRND,	4036;TEXT 'RND'
XXSIN,	4037;TEXT 'SIN'
XXPUT,	4040;TEXT 'PUT'
XXLIST,	4041;TEXT 'LIST'
XXLIS,	4041;TEXT 'LIS'
XXRUN,	4042;TEXT 'RUN'
XXSCR,	4043;TEXT 'SCR'
XXGET,	4044;TEXT 'GET'
XXADC,	4045;TEXT 'ADC'
XXTTY,	4046;TEXT 'TST'
XXTIME,	4047;TEXT 'TIM'
XXTAB,	4050;TEXT 'TAB'
XXUUF,	4051;TEXT 'UUF'
XXCLS,	4052;TEXT 'CLS'
XXCLC,	4053;TEXT 'CLC'
XXADB,	4054;TEXT 'ADB'
XXCRLF,	6000;TEXT '_'
XXBSLSH,6000;TEXT '\'
XXEND,	6001;TEXT 'END'
XXFOR,	6002;TEXT 'FOR '
XXGOSUB,6003;TEXT 'GOSUB '
XXGOTO,	6004;TEXT 'GO TO '
XXTHEN,	6004;TEXT ' THEN '
XXIF,	6005;TEXT 'IF '
XXINPUT,6006;TEXT 'INPUT '
XXLET,	6007;TEXT 'LET '
XXNEXT,	6010;TEXT 'NEXT '
XXPRINT,6011;TEXT 'PRINT '
XXRETRN,6012;TEXT 'RETURN'
XXSTOP,	6013;TEXT 'STOP'
XXDIM,	6014;TEXT 'DIM '
XXRSTOR,6015;TEXT 'RESTORE'
XXREM,	6016;TEXT 'REM '
XXDEF,	6017;TEXT 'DEF '
XXREAD,	6020;TEXT 'READ '
XXDATA,	6021;TEXT 'DATA '
XXTTYI,	6024;TEXT 'TTY IN'
XXTTYO,	6025;TEXT 'TTY OUT'
XXLPT,	6026;TEXT 'LPT'
XXPTP,	6027;TEXT 'PTP'
XXPTR,	6030;TEXT 'PTR'
				/6031 HAS BEEN REMOVED.
XXRUB,	6032;TEXT 'RUBOUTS'
XXNRUB,	6033;TEXT 'NO RUBOUTS'
XXCLEAR,6034;TEXT 'CLEAR'
XXDELAY,6035;TEXT 'DELAY'
XXUSE,	6036;TEXT 'USE '
XXPLOT,	6037;TEXT 'PLOT '
XXREAL,	6040;TEXT 'REAL TIME '
XXSETR,	6041;TEXT 'SET RATE '
XXSETC,	6042;TEXT 'SET CLOCK '
XXWAITC,6043;TEXT 'WAITC'
YYWAIT,	6044;TEXT 'WAIT'
XXUCOM,	6045;TEXT 'UCOM '
XXACPT,	6046;TEXT 'ACCEPT'
XXREJT,	6047;TEXT 'REJECT'
	0
XXTEXT,	3000
XXEOF,	6023
XXUNARY,4113
XXFINI,	4014
XXEXIT,	6022
XXLIT0,	2000;2001;2002;2003
NOPUNCH
LINBUF,	ZBLOCK	51
LBEGIN,	ZBLOCK	60
ENDLIN,	0
PDLIST,	ZBLOCK	40
ENDPDL,	0
FORLIST,ZBLOCK	20
GOLIST,	ZBLOCK	30
GSBEND,	0
	ENPUNCH
$