/DECUS	8-152 MUSIC PLAYING PROGRAM
/
/VERSION 2.3
/
/
/
/
*0200
PLAY,	CLA CLL 
	TAD WORD0
	DCA WORD
	TAD NOTE0
	CIA
	DCA NOTE
START,	TAD I WORD
	CLL RTL 
	AND MASKD
	TAD DAMP0
	DCA DAMP
	TAD I DAMP
	DCA DAMP
	TAD DFIX
	DCA DAMPI
	TAD I WORD
	AND MASKF
	TAD CONSTF
	DCA N0
	TAD I N0
	DCA N0
	TAD I WORD
	AND MASKA
	CLL RAR 
	SZA 
	JMP .+3
	TAD CDAM
	DCA DAMPI
	DCA AMP
	TAD I WORD
	AND MASKL
	RTR 
	CLL RTR 
	RAR 
	TAD CONSTL
	DCA L0
	TAD I L0
	CIA
	DCA L0
	TAD L0
	DCA L
	TAD CNTR
	DCA CNT
	TAD N0
	6554	/FREQ OUT
	CLA CLL 
A,	ISZ L
	JMP A
	TAD AMP
DAMPI,	TAD DAMP
	RTR 
	6551
	RTL 
	DCA AMP
	ISZ CNT
	SKP 
	JMP FIN
	TAD L0
	DCA L
	JMP A
FIN,	ISZ WORD
	6552	/FREQ OFF
	ISZ NOTE
	SKP 
	HLT
	JMP START
/
/
/
/
/
/

/
/EDITOR PAGE 2
/
/
*0376
CDAM,	NOP
DFIX,	TAD DAMP
/
/
/
*0020
WORD0,	0000
WORD,	0000
NOTE0,	0000
NOTE,	0000
MASKF,	0037
CONSTF,	0100
N0,	0000
MASKA,	3000
AMP,	0000
MASKL,	0740
CONSTL,	0150
L0,	0000
L,	0000

CNTR,	7740	/TEMPO COUNTER
CNT,	0000
MASKD,	0001
DAMP0,	DAMPP
DAMP,	0000
/
/
/
/
*0170
DAMPP,	7777
	7777
/
/
/
/
/
/
/
/
/NOTE FREQUENCIES
/
/
*0100
A1,	373
A1S,	355
A2,	175
A2S,	166
A3,	76
A3S,	72
B1,	337
	337
B2,	157
	157
B3,	67
C1,	323
C1S,	307
C2,	151
C2S,	143
C3,	64
C3S,	61
D1,	274
D1S,	261
D2,	135
D2S,	130
E1,	247
	247
E2,	123
F1,	236
F1S,	225
F2,	116
F2S,	112
G1,	214
G1S,	204
G2,	106
G2S,	102
/
/
/NOTE LENGTHS
/
/
*0150
SIXT,	0010
SIXT1,	0014
EIGHT,	0020
EIGHT1,	0030
QUART,	0040
QUART1,	0060
QUARTS,	0050
HALF,	0100
HALF1,	0140
HALFS,	0110
HALFE,	0120
WHOLE,	0200
WHOLE1,	0300
WHOLEQ,	0240
WHOLHQ,	0340
WHOLW,	0400
/
/
/
/
/
/
$