/DECUS 8-152A MUSIC CODING
/
/VERSION 1.2
/
/
/
/EDITOR PAGE 1
/
/
*0600
END,	0
	CLA 
	TAD TEMP
	TAD ARR
	SZA 
	JMP I END
	HLT
	JMS LEADER
	TAD ORGW
	JMS ORIGIN
	TAD WORD0
	JMS PUNC
	TAD WORD0
	JMS ORIGIN
	TAD NLOOP
	CIA
	DCA NLOOP
	TAD LCO0
	DCA LCO
	TAD LCC0
	DCA LCC
	DCA NOTE0
LOOP0,	TAD I LCC
	CIA
	TAD I LCO
	DCA TEMP
	TAD TEMP
	CIA
	TAD NOTE0
	DCA NOTE0
	TAD WORD0
	TAD I LCO
	DCA WORD
LOOP1,	TAD I WORD
	JMS PUNC
	CLA CLL 
	ISZ WORD
	ISZ TEMP
	JMP LOOP1
	ISZ LCO
	ISZ LCC
	ISZ NLOOP
	JMP LOOP0
	TAD ORGN
	JMS ORIGIN
	TAD NOTE0
	JMS PUNC
	JMS PUNC
	JMP CKSUM
PUNCH,	0
	TLS
	TSF 
	JMP .-1
	TAD CHKSUM
	DCA CHKSUM
	CLA 
	JMP I PUNCH
FIX,	0
	RTR 
	RTR 
	RTR 
	AND MASK
	JMP I FIX
ORIGIN,	0
	DCA TA
	TAD TA
	JMS FIX
	TAD ORG
	JMS PUNCH
	TAD TA
	AND MASK
	JMS PUNCH
	JMP I ORIGIN
PUNC,	0
	DCA TA
	TAD TA
	JMS FIX
	JMS PUNCH
	TAD TA
	AND MASK
	JMS PUNCH
	JMP I PUNC
ARR,	0244
ORGW,	0020
ORGN,	0022
MASK,	0077
ORG,	0100
LEADER,	0000
	CLA CLL 
	TAD M30
	DCA T1
	TAD P200
	JMS PUNCH
	ISZ T1
	JMP .-3
	CLA CLL 
	DCA CHKSUM
	JMP I LEADER
M30,	-30
T1,	0000
P200,	0200
CKSUM,	TAD CHKSUM
	JMS PUNC
	JMS LEADER
	HLT
CHKSUM,	0000
/
/
/
*0020
WORD0,	1000
WORD,	0
NOTE0,	0
CNT,	0
RB,	0377
LF0,	0212
CR,	0215
AST,	0252
SP,	0240
TEMP,	0
LEN0,	0
FREQ0,	0000
TA,	0000
BRA,	0257
SS0,	0044
AA0,	0301
RR0,	0013
AMP0,	0000
LL0,	0261
ASTI,	ASTK
ENDI,	END
LENI,	LEN
MASKL,	0003
CORR,	260
UPARRI,	UPARR
UPA,	336
DAMP,	4000
DAMP0,	0
FREQI,	FREQ
OBR0,	0274
CBR0,	0276
LCO0,	7400
LCO,	0
LCC0,	7500
LCC,	0
NLOOP,	0
OBRI,	OBR
CBRI,	CBR
READI,	READ

/
/EDITOR PAGE 2
/
/
*0100
D00100,	CLA CLL
D00101,	RFC
	TAD WORD0
	DCA WORD
	DCA NOTE0
	DCA NLOOP
START,	JMS ACCEPT
	JMS I ASTI
	JMS I ENDI
P00111,	JMS I OBRI
	JMS I CBRI
	JMS I UPARRI
	JMS I FREQI
	JMP START
ACCEPT,	0000
	CLA CLL 
	RSF 
	JMP .-1
	RRB RFC 
	CIA
	DCA TEMP
	TAD TEMP
	JMP I ACCEPT
/
/
*0200
FREQ,	0000
	CLA CLL 
	TAD TEMP
	TAD AA0
	SNA 
	JMP AA
	IAC
	SNA 
	JMP BB
	IAC
	SNA 
	JMP CC
	IAC
	SNA 
	JMP DD
	IAC
	SNA 
	JMP EE
	IAC
	SNA 
	JMP FF
	IAC
	SNA 
	JMP GG
	TAD RR0
	SNA 
	JMP RR
	JMP I FREQ
AA,	CLA CLL 
	DCA FREQ0
	JMP FINF
BB,	TAD B
	DCA FREQ0
	JMP FINF
CC,	TAD C
	DCA FREQ0
	JMP FINF
DD,	TAD D
	DCA FREQ0
	JMP FINF
EE,	TAD E
	DCA FREQ0
	JMP FINF
FF,	TAD F
	DCA FREQ0
	JMP FINF
GG,	TAD G
	DCA FREQ0
	JMP FINF
RR,	TAD AMP0
	DCA TA
	DCA AMP0
	DCA FREQ0
	CLA CMA 
	DCA CNT
	ISZ NOTE0
	ISZ WORD
	JMP I LENI
FINF,	ISZ NOTE0
	ISZ WORD
	JMS ACCEPT
	TAD LL0
	SNA 
	JMP FINF1
	IAC
	SNA 
	JMP TW
	IAC
	SNA 
	JMP TH
	JMP FINF
TW,	TAD FREQ0
	TAD TWO
	DCA FREQ0
	JMP FINF1
TH,	TAD FREQ0
	TAD THREE
	DCA FREQ0
FINF1,	JMS ACCEPT
	TAD BRA
	SNA 
	JMP FINFS
	TAD SS0
	SNA 
	JMP SS
	JMP FINF1
SS,	TAD FREQ0
	IAC
	DCA FREQ0
	JMP FINF1
FINFS,	JMP I LENI
READ,	0000
	CLA 
	JMS ACCEPT
	TAD CORR
	CIA
	CLL RTL 
	RAL 
	DCA TA
	JMS ACCEPT
	TAD CORR
	CIA
	TAD TA
	JMP I READ
OBR,	0000
	CLA CLL 
	TAD TEMP
	TAD OBR0
	SZA 
	JMP I OBR
	JMS READ
	TAD LCO0
	DCA LCO
	TAD NOTE0
	IAC
	DCA I LCO
	JMP START
B,	6
C,	13
D,	21
E,	25
F,	30
G,	34
TWO,	2
THREE,	3
/
/
/
/

/EDITOR PAGE 3
/
*0400
LEN,	JMS ACCEPT
	TAD EI0
	SNA 
	JMP EI
	TAD HA0
	SNA 
	JMP HA
	TAD QA0
	SNA 
	JMP QA
	TAD SI0
	SNA 
	JMP SI
	TAD WH0
	SNA 
	JMP WH
	JMP LEN
EI,	TAD ET
	DCA LEN0
	JMP FINL
HA,	TAD H0
	DCA LEN0
	JMP FINL
QA,	TAD Q
	DCA LEN0
	JMP FINL
SI,	CLA CLL 
	DCA LEN0
	JMP FINL
WH,	TAD W
	DCA LEN0
	JMP FINL
FINL,	JMS ACCEPT
	TAD DOT0
	SNA 
	JMP DOT
	IAC
	SNA 
	JMP FINL1
	JMP FINL
DOT,	TAD LEN0
	IAC
	DCA LEN0
	JMP FINL
FINL1,	TAD LEN0
	CLL RTL 
	RTL 
	RAL 
	TAD AMP0
/
/VRS: The stuff below is missing from the write-up.
	TAD FREQ0
	TAD DAMP0
	DCA I WORD
	ISZ CNT
	JMP .+3
	TAD TA
	DCA AMP0
	DCA CNT
	DCA DAMP0
	JMP START

CBR,	0
	CLA CLL
	TAD TEMP
	TAD CBR0
	SZA
	JMP I CBR
	JMS I READI
	TAD LCC0
	DCA LCC
	TAD NOTE0
	IAC
	DCA I LCC
	ISZ NLOOP
	JMP START

ASTK,	0
	CLA CLL
	TAD TEMP
	TAD AST
	SZA
	JMP I ASTK
	JMS ACCEPT
	CIA
	AND MASKL
	CLL RTR
	RTR
	DCA AMP0
	JMP START

EI0,	305
HA0,	3
QA0,	11
SI0,	2
WH0,	4
ET,	2
H0,	7
Q,	4
W,	13
DOT0,	256

UPARR,	0
	CLA CLL
	TAD TEMP
	TAD UPA
	SZA
	JMP I UPARR
	TAD DAMP
	DCA DAMP0
	JMP START
$