/
/
/
/ PART 6
/
/
/HANN THE FINAL SPECTRUMM
/
HANN2,	NOP
	TAD KNOP 	/REMOVE THE MINUS SIGNS
	DCA OPR1
	TAD KNOP
	DCA OPR2
/
HANNPS,DCA I IMAGPT 	/H(N+1)=0 [LAST VALUE]
	TAD REALPT
	JMS HANN
/
	JMP FINDSP
/
/
	PAGE
/
/
/ HANNING PROCESS
/ EQUATION
/ H'(N)=[+-](1/4)*H(N-1) +(1/2)*H(N) [+-](1/4)*H(N+1)
/
HANN,	0
	DCA PTR1
	DCA TEMP 	/=0
	TAD MN
	DCA CNT1
H0,	TAD TEMP 	/H(N-1)
	SPA
	JMP NEG1
	HALF
	HALF 		/ (1/4)
OPR1,	HLT 		/SET TO CIA OR NOP
H1,	DCA HAN1
	TAD I PTR1 	/H(N)
	DCA TEMP 	/H(N-1) NEXT TIME
	TAD TEMP
	SPA
	JMP NEG2
	HALF 		/ (1/2)
H2,	DCA HAN2
	ISZ PTR1
	TAD I PTR1 	/H(N+1)
	DCA TTEMP
	CMA
	TAD PTR1
	DCA PTR1
	TAD TTEMP
	SPA
	JMP NEG3
	HALF
	HALF 		/ (1/4)
OPR2,	HLT 		/SET TO CIA OR NOP
H3,	TAD HAN1
	TAD HAN2
	DCA I PTR1 	/STORE HANNED TERM
	ISZ PTR1
	ISZ CNT1 	/HANN JOB DONE?
	JMP H0 	/NO, KEEP HANNING
	JMP I HANN 	/YES, EXIT
/
NEG1,	STL RAR 	/NEGATIVE SCALING ROUTINES
	STL RAR 	/PRESERVE THE SIGN BIT
	JMP OPR1
/
NEG2,	STL RAR
	JMP H2
/
NEG3,	STL RAR
	STL RAR
	JMP OPR2
/
/
/
/
/
/
/
/
/   DISPLAY OF FINAL RESULTS
/      THE POWER SPECTRUM
/
/    KNOB 34 CONTROLS VERTICAL SCALING
/    KNOB 35 CONTROLS HORIZONTAL SCALING
/    KNOB 36 CONTROLS STARTING VALUE OF FREQUENCY
/
/    BIT 9 UP MEANS DRAW HISTOGRAM FORM
/    BIT 10 UP MEANS KEEP DISPLAYING
/
FINDSP,CLR
	TAD K34
	ACMX
	JMS SAM
	AND K700
	CLL RTR
	RTR
	RTR
	CMA
	DCA SCLCNT 	/MINUS(0-7) FOR VERT SCALE
	JMS SAM 	/CHANNEL 35
	CLL RTR
	RTR
	AND K37
	SNA
	TAD K40
	DCA WINC 	/0-40  FOR HORIZ SCALE
	JMS SAM 	/CHANNEL 36
	CLL RAL
	DCA WSTART 	/0-2000 FOR STARTING ADDRESS
/
/
	TAD RLPTR 	/WHERE FINAL SPECTRUM IS
	TAD WSTART
	DCA AI10 	/POINTS TO COEFFICIENTS
SPCDIS,DXCDXL 	/ACTUAL SPECTRAL DISPLAY
	DCA HORIZ
	TAD SCLCNT
	DCA CNT1
	TAD I AI10 	/GET THE COEFFICIENT
	SKP 		/1ST TIME
	CLL RAL 	/*2 (SCALING
	ISZ CNT1 	/ANY SCALING TO BE DONE?
	JMP .-2 	/YES
	TAD M400 	/NO, SHIFT FOR SCOPE
	DISY 		/DISPLAY THE POINT
	DCA TEMP 	/SAVE IT, JUST IN CASE
	OSR
	RTR
	RAR
	SZL CLA 	/IS BIT 9 UP?
	JMP HIST 	/YES, DRAW A HISTOGRAM
NXTDIS,TAD WINC 	/NO,SET FOR NEXT
	TAD HORIZ
	TAD M1000
	SMA 		/PAST THE END OF THE SCREEN?
	JMP CHKDIS 	/YES
	TAD K1000 	/NO, RESTORE X POSITION
	JMP SPCDIS 	/KEEP DISPLAYING POINTS
/
/
CHKDIS,LAS 		/SHOULD WE REFRESH THE DISPLAY?
	RTR
	SZL 		/IS BIT 10 UP?
	JMP FINDSP 	/YES, RESTART THE DISPLAY
	NOP 		/NO,END OF ANALYSIS!!!
	JMP I .+1
	START 		/GLUTTON FOR PUNISHMENT!
/
/
HIST,	TAD TEMP
	SMA 		/IS IT NEGATIVE?
	JMP HISDIS 	/NO
	CIA 		/YES, HOW MUCH SO?
	TAD M400
	SMA CLA 	/LESS THAN -400?
	JMP NXTDIS 	/YES, DONE WITH THIS LINE
	TAD TEMP 	/NO
HISDIS,TAD M4 	/DECREMENT POINT BY 4
	DISY
	DCA TEMP 	/SAVE IT
	JMP HIST 	/KEEP DRAWING
/
/
/
SAM,	0 		/READ THIS CHANNEL
	ADCV
	SKAD
	JMP .-1
	RADC
	ICMX
	SMA 		/NEGATIVE?
	IAC 		/NO, ADD 1
	TAD K400 	/LEAVE WITH 0<=AC<=1000
	JMP I SAM
/
/
/
	$