EJECT PAGE/100-280
EV9=EV
POP9=POP
PUSH9=PUSH
RET9, EVRET
TEST9=TEST
/TABLE OF LISP SYSTEM ROUTINES
TAB, AAND  /0  0
  AHD      /1  1
  ATL      /2  2
  ALSTIN   /3  3
  ALSTOT   /4  4
  ANULL    /5  5
  AATOM    /6  6
  APROG    /7  7
  AEQ      /8  10
  ACOND    /9  11
  EVERR    /10 12
  ASET     /11 13
  ABEGIN   /12 14
  ARETURN  /13 15
  ASETHD   /14 16
  ASETTL   /15 17
  ACONS    /16 20
  AOR      /17 21
  AGO      /18 22
  AMACH    /19 23
  APLUS    /20 24
  AMINUS   /21 25
  ATIMES   /22 26
  ANUMBER  /23 27
  AGREATP  /24 30
  AIF      /25 31
  APAUSE   /26 32
  ANOT     /27 33
  AEXIT2   /28 34
  AQUOTE   /29 35
  AENTRY   /30 36
  EVERR    /31 37
/GARBAGE COLLECTOR PATCH
COLON, TAD I COSTK
  DCA COYAP
COLZAP, TAD COYAP
  TAD COMIN
  SPA CLA
  JMP I COLZIP
  TAD I COYAP
  JMS CORANG
  JMP COLEXL
  TAD I COYAP
  DCA .+2
  JMS I COLPAT
   0
COLEXL, STA
  TAD COYAP
  DCA COYAP
  JMP COLZAP
CORANG, 0 /SKIP-IF-ARG-IN-RANGE SUB
  CIA
  TAD EVBEG
  CIA
  SPA
  JMP CORON /NOT IN RANGE
  TAD EVLEN
  SPA
  ISZ CORANG /IN RANGE
CORON, CLA
  JMP I CORANG
COLPAT, COMAIN
COSTK, STPTR
COMIN, 0/SET BY INIT
COLZIP, COLNXT
COYAP, 0
/AND & OR ROUTINES
AAND, /COMPUTES THE LOGICAL "AND" OF AN INDEFINATE SET OF ARGS.
  IAC
  DCA LOSW
  TAD ANSUB
ANON, DCA LOSUB
  JMP LOGDO
ANSUB, AND LOSW
AOR, /COMPUTES THE LOGICAL "OR" OF AN INDEFINATE SET OF ARGS.
  DCA LOSW
  TAD ORSUB
  JMP ANON
ORSUB, JMP OROR
OROR, CMA
  DCA ORTMP
  TAD LOSW
  CMA
  AND ORTMP
  CMA
  JMP LOSUB+1
ORTMP, 0
/MAIN ROUTINE
LOGDO,
  JMS I LOPUSH /RECURSIVE SELF PROTECTION
   LOSW
  JMS I LOPUSH /RECURSIVE SELF PROTECTION
   LOSUB
  JMS I LOEV /GET AN ARG
  JMS I LOPOP
   LOSUB
  JMS I LOPOP
   LOSW
  CMA /-1?
  SNA
  JMP LOEND /YES
  CMA /NO
  JMS I LOTEST /REALLY?
  JMP LOGDO /NO
LOSUB, 0 /SUPLIED BY AND & OR
  DCA LOSW
  JMP LOGDO
LOEND, TAD LOSW
  JMP I LORET
LOSW, 0 /SUPLIED BY AND & OR
LOPUSH=PUSH9
LOPOP=POP9
LOEV=EV9
LORET=RET9
LOTEST=TEST9
/GREATP ROUTINE
/RETURNS T IF FIRST ARG IS GREATER NUMERICALLY THAN SECOND
/  ARG.  RETURNS F OTHERWISE.  NO TEST IS MADE TO SEE IF
/  ARGS ARE ACTUALLY NUMERICAL (OR IF THEY ARE BOTH ATOMS).
AGREATP,
  JMS I GRPUSH /RECURSIVE SELF-PROTECTION
   GRA
  JMS I GREV /GET 1ST ARG
  JMS I GRDECB /CONVERT TO BINARY
  DCA GRA
  JMS I GREV /GET SECOND ARG
  JMS I GRDECB /CONVERT TO BINARY
  CIA
  TAD GRA
  SL1 CLA
  IAC /-B+A>0 IMPLIES T
  JMS I GRPOP /ELSE F
   GRA
  JMP I GRRET
GRA, 0
GRDECB, DECBIN
GRPUSH=PUSH9
GRPOP=POP9
GREV=EV9
GRRET=RET9
PAGE /Added by VRS