50 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
90 GOTO 11100
100 DIM B(16),B$(12)
110 Z(0)=.5\Z=.5
120 I=1
130 B1=0\B2=0\B3=0\I1=0\I2=0\I3=0
140 C1=0\C2=0\PRINT
150 IFC2<>4 GOTO160\PRINT"THE BATTER WALKS."\A=9\GOSUB 920
155 GOTO 140
160 IFC1<>3THEN180\PRINT"THE BATTER STRUCK OUT."\C3=C3+1\GOTO140
170 IF S1=1THEN180\X=X+1
180 IFC3<3THEN270\IFS1=1THEN190\S1=1\GOTO200
190 PRINT"AFTER";I;"INNINGS";\I=I+1\S1=0
200 PRINT I2;"RUNS,";I1;"HITS,";I3;"ERRORS AND";B1+B2+B3;"LEFT ON BASE."
210 IF I=10THEN1420\IFS1=0THEN230\PRINT"I'M";\GOTO 240
220 IF S1=0 THEN 230\PRINT"I'M";\GOTO 240
230 PRINT"YOU'RE";
240 PRINT" UP NOW."\PRINT"SCORE: ME";S2;"YOU";S3
250 PRINT\C3=0
260 GOTO 130
270 PRINT "YOUR PLAY";
280 INPUT B$
290 D=1*RND(0)\PRINT
295 REM**************MAYBE 5*RND(0)+1 ************************
300 IF S1=0THEN420
310 IF B$<>"CURVE"THEN320\D=D+C(X)\GOTO1280
320 IF B$<>"FASTBALL"THEN330\D=D+F(X)\GOTO 1280
330 IF B$="BEANBALL"THEN1280
340 IF B$="BRUSHBACK"THEN1280
350 IF B$="SLIDER"THEN1280
360 IF B$="KNUCKLE"THEN 1280
370 IF B$<>"GREASEBALL"THEN 380\IFD<.8 THEN 1280\GOTO 1270
380 IF B$<>"SPITBALL"THEN 390\IF D<.8 THEN 1280\GOTO 1270
390 IF B$<>"CHECK"THEN 400\PRINT"RUNNERS ARE STICKING."\GOTO  270
400 IF B$<>"BALL" THEN 410\GOTO 1300
410 PRINT B$;"?"\GOTO 270
420 IFB$<>"BUNT"THEN430\PRINT"YOUR BATTER";\GOSUB 570
425 GOTO 140
430 IF B$="SWING"THEN1280
440 IF B$<>"CHECK"THEN450\PRINT"CHECK NOT YET IN."\GOTO 270
450 IF B$="HIT-AWAY"THEN 1280
470IF B$="SACRIFICE"THEN 1280
480 IF B$="GROUNDER"THEN 1280
490 IF B$="FLY"THEN 1280
500 IF B$="KILL"THEN 1280
510 GOTO 410
520 A=9*RND(0)\IF S1=0 THEN 530\PRINT"MY BATTER";\GOTO 540
525 REM**************MAYBE A=9*RND(0)+1**********************
530 PRINT "YOUR BATTER";
540 IF A>1 THEN 550\PRINT" LINED OUT TO THE THIRD BASEMAN."\GOTO840
550 IF A>2 THEN 560\PRINT" POPPED OUT IN SHALLOW LEFT."\GOTO 840
560 IF A>3 THEN 580
570 PRINT" GROUNDED TO THE PITCHER";\GOTO 590
580 IF A>4 THEN 680\PRINT" GROUNDED TO SHORTSTOP";
590 PRINT" WHO THREW OUT THE MAN";\IF C3 =2 THEN 670
600 IF B1=0 THEN670\IFB2=0THEN630\IFB3=0THEN620\PRINT" FORCED HOME."
610 GOTO 850
620 PRINT" FORCED TO THIRD."\GOTO 850
630 A1=INT(3*RND(0))\PRINT" FORCED TO SECOND";\IFA1<>1THEN650
640 PRINT"."\GOTO850
650 PRINT\PRINT"AND THEN TO FIRST FOR A DOUBLE PLAY!"
660 C3=C3+1\B1=0\GOTO840
670 PRINT" AT FIRST."\GOTO 840
680 IFA>5THEN700\PRINT" HIT A FLY INTO DEEP CENTER WHERE IT WAS";
690 PRINT" CAUGHT."\GOTO710
700 IF A>6 THEN 880\PRINT" HIT TO LEFT FIELD FOR AN OUT."
710 IF C3=2 THEN 840\IF B1+B2+B3=0 THEN 840
720 PRINT"THE MAN ON";\IF B3=1 THEN 730\IF B2=1 THEN 750\GOTO 790
730 PRINT" THIRD MADE IT HOME,";\GOSUB 930
735 B3=0
740 IF B2=0 THEN 780
750 PRINT" SECOND";\IF A1=0 THEN 760\PRINT" STAYED PUT."\GOTO 780
760 IFA1>1THEN770\PRINT" MADE IT TO THIRD."\B3=1\B2=0\GOTO780
770 PRINT" WAS OUT TRYING TO TAKE THIRD."\C3=C3+1\B2=2
780 IF B1<>1 THEN 840
790 IF B2<>1 THEN 800\PRINT" FIRST STUCK."\GOTO 840
800 PRINT" ON FIRST";\IF B2<>2 THEN 820
810 PRINT" MADE IT TO SECOND."\B2=1\B1=0\GOTO 840
820 W=2*RND(0)\IF W>1 THEN 810\PRINT" WAS OUT GOING."\C3=C3+1
830 B2=0
840 Z(Y)=Z(Y)-(Z(Y)/100)\GOTO 860
850 Z(Y)=Z(Y)+(Z(Y)/100)
860 C3=C3+1\PRINT"THAT WAS OUT NUMBER";C3
870 GOTO 1260
880 IFA>7THEN890\PRINT" HIT OVER THE PITCHER'S HEAD FAR A";\GOTO910
890 IFA>8THEN900\PRINT" HIT THROUGH THE HOLE INTO RIGHT FOR A";\GOTO910
900 PRINT" HIT INTO LEFT FIELD FOR A";
910 IFZ>4*DTHEN1210\IFZ>3*DTHEN1130\IFZ>2*DTHEN1040\PRINT" SINGLE."
920 IF B3=0THEN 970\GOSUB 930
925 B3=0\GOTO 960
930 IF S1=1 THEN 940\S3=S3+1\GOTO 950
940 S2=S2+1
950 I2=I2+1\RETURN
960 PRINT"THE MAN ON THIRD SCORED."
970 IFB2=0THEN1000\PRINT"THE MAN ON SECOND";\IFA>8THEN990\PRINT" SCORED."
980 GOSUB 930
985 B2=0\GOTO 1000
990 PRINT" WENT TO THIRD."\B2=0\B3=1
1000 IFB1=0THEN1030\PRINT"THE MAN ON FIRST";\IFA>8THEN1020
1010 IF C2=4 THEN 1020\B1=0\GOTO990
1020 PRINT" TO SECOND."\B2=1
1030 B1=1\GOTO 1240
1040 W=3*RND(0)\IF W>1 THEN 1050\PRINT"N OFF THE WALL";
1045 REM*****************MAYBE " OFF THE WALL"*****************
1050 IF A2=1 THEN 1060\PRINT" STAND UP";
1060 PRINT" DOUBLE."\IF B3=0THEN1080\PRINT"THE MAN ON THIRD SCORED."
1070 GOSUB 930
1075 B3=0
1080 IFB2=0THEN1090\PRINT"THE MAN ON SECOND SCORED."\GOSUB 930
1085 B2=0
1090 IFB1=0THEN1120\PRINT"THE MAN ON FIRST";\IFA>8THEN1110\PRINT" SCORED."
1100 GOSUB 930
1105 B1=0\GOTO 1120
1110 PRINT" WENT TO THIRD."\B1=0\B3=1
1120 B2=1\GOTO 1240
1130 PRINT" TRIPLE!"\A3=B1+B2+B3\IFA3=0THEN1200\PRINT"THE MAN ON";
1140 IF B1=0 THEN 1150\PRINT" FIRST";\GOSUB 930
1150 IF B2=0 THEN 1170\IF B1=0 THEN 1160\PRINT", AND";
1160 PRINT" SECOND";\GOSUB 930
1170 IF B3=0 THEN 1190\IF B1+B2=0 THEN 1180\PRINT", AND";
1180 PRINT" THIRD";\GOSUB 930
1190 PRINT" SCORED."\B1=0\B2=0
1200 B3=1\GOTO 1240
1210 IF B1+B2+B3<3THEN 1220\PRINT" GRAND SLAM";
1220 PRINT" HOME RUN!!"
1222 FOR A1=1 TO(B1+B2+B3+1)
1224 GOSUB 930
1226 NEXT A1
1230 B1=0\B2=0\B3=0
1240 IF C2=4 THEN 1260\Z(Y)=Z(Y)+(Z(Y)/100)
1250 I1=I1+1
1260 RETURN
1270 PRINT"PITCHER THROWN OUT FOR THROWING ILLEGAL PITCH."\GOTO 270
1280 A=5*RND(0)\IF A<3 THEN 1320
1290 IF A>4 THEN 1300\PRINT"INSIDE - ";\GOTO 1310
1300 PRINT"OUTSIDE - ";
1310 C2=C2+1\PRINT"BALL";C2\GOTO 150
1320 IFZ(Y)<DTHEN1340\GOSUB 520
1325 IF A<6 THEN 1330\C(Y)=C(Y)+1\GOTO 140
1330 C(Y)=C(Y)-1\GOTO 140
1340 C(Y)=C(Y)-1\B=3*RND(0)
1345 REM**************MAYBE B=3*RND(0)+7********************
1350 IF B>1THEN 1360\PRINT"A SWING & A MISS - ";\GOTO 1390
1360 IF B>2 THEN 1380\PRINT"INSIDE CORNER - CALL ";
1370 GOTO 1390
1380 PRINT"FOUL! - ";\IF C1=2 THEN 1400
1390 C1=C1+1\PRINT" STRIKE";C1\GOTO 150
1400 PRINT"COUNT STAYS AT";C2;"BALLS AND";C1;
1410 PRINT"STRIKES."\GOTO 150
1420 PRINT"FINAL SCORE: ME";S2;"YOU";S3
1430 IF S2>S3THEN 1450\IF S3=S2 THEN1440\PRINT"YOU WON."\GOTO 1460
1440 PRINT"A DRAW!"\GOTO 1460
1450 PRINT"I WON!"
1460 STOP
1470 STOP
11100 DIM T(50),C(19),F(19),Z(19),A$(26)
11110 FOR X=1TO19\READ C(X),Z(X),F(X)\NEXT X
11115 X=1
11120PRINT"WELCOME TO HUISMAN STADIUM FOR TODAY'S GREAT GAME BETWEEN"
11130 PRINT"THE PDP-8 PANTHERS AND (YOUR NAME PLEASE) THE ";
11140 INPUT A$
11150 PRINT\PRINT "A HIGHLY PARTISAN CROWD OF";
11160 B=2*RND(0)\A=INT(70000*RND(0))\PRINT A;
11180 PRINT"FANS IS ANXIOUSLY AWAITING THE"\PRINT"START OF THE GAME."
11190 PRINT"HERE IS MY TEAM:","AND HERE IS YOURS:"
11200 PRINT"NAME","AVERAGE","NAME","AVERAGE"
11210 PRINT"----","-------","----","-------"
11220 GOSUB 11400
11230 PRINT\PRINT
11240 PRINT"THE PANTHERS ARE TAKING THE FIELD NOW AS ANDREWS OF THE"
11250 PRINT A$;
11260 PRINT" ADVANCES TO THE PLATE.  PLEASE WAIT AS THE COMPUTER SINGS"
11270 PRINT"OUR NATIONAL ANTHEM TO ITSELF - 2 OR 3 TIMES!  JUST SING"
11280 PRINT"ALONG UNTIL ASKED FOR YOUR PLAY."\PRINT
11290 GOTO 11580
11300 DATA .05,.412001,.05,.02,.263003,.03
11310 DATA-.02,.236001,.02,.03,.316001,-.01
11320 DATA .01,.241001,.03,.02,.321001,.02
11330 DATA-.02,.367001,.02,-.02,.386001,-.01
11340 DATA.01,.295001,.03,-.01,.296001,.02
11350 DATA-.02,.319001,.02,-.02,.285001,.02
11360 DATA-.03,.295001,.01,.02,.295001,.03
11370 DATA.02,.218001,.02,.02,.139001,-.02
11380 DATA.03,.238001,.01,.03,.231001,-.02
11390 DATA 0,0,0
11400 PRINT"HUISMAN",Z(1),"KLOOS",Z(2)
11410 PRINT"HOEREN",Z(3),"ANDREWS",Z(4)
11420 PRINT"BACCUS",Z(5),"MAYER",Z(8)
11430 PRINT"SMITH",Z(7),"HANSEN",Z(6)
11440 PRINT"SCHNEIDER",Z(9),"MICHEL",Z(10)
11450 PRINT"ROSENBAUM",Z(11),"P. D. PETE",Z(12)
11460 PRINT"POULSEN",Z(13),"WILLIAMS",Z(14)
11470 PRINT"KILGOUR",Z(15),"NELSON",Z(16)
11480 PRINT"JOHNSON",Z(17),"ANKCORN",Z(18)
11490 PRINT"WHITNEY"," MANAGER","IVEY"," MANAGER"\PRINT
11500 PRINT"PITCHER'S OPTIONS ARE:"\PRINT"FASTBALL"
11510 PRINT"BEANBALL"\PRINT"BRUSHBACK"\PRINT"BALL"\PRINT"CURVE"
11520 PRINT"SLIDER"\PRINT"KNUCKLE"\PRINT"GREASBALL (ILLEGAL)"
11530 PRINT"SPITBALL (ILLEGAL)"\PRINT"CHECK"\PRINT
11540 PRINT"BATTERS OPTIONS ARE:"\PRINT"BUNT"\PRINT"SWING"
11550 PRINT"HIT-AWAY"\PRINT"SACRIFICE"\PRINT"GROUNDER"\PRINT "FLY"
11560 PRINT"KILL"\PRINT
11570 RETURN
11580 GOTO 100
11590 END