4 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
5 RANDOMIZE
6 PRINT "YOU ARE NOW A PILOT IN A WORLD WAR II BOMBER"
10 PRINT "WHAT SIDE -- ITALY(1), ALLIES(2), JAPANESE(3), GERMANY(4)";
15 INPUT A
20 IF A<1 GOTO 24\IF A>4 GOTO 24
21 A=INT(A)\GOTO 25
24 PRINT "TRY AGAIN...."\GOTO 10
25 IF A=1 GOTO 30\IF A=2 GOTO 110\IF A=3 GOTO 200\IF A=4 GOTO 220
30 PRINT "WHAT IS YOUR TARGET -- ALBANIA(1), GREECE(2), NORTH AFRICA(3)";
35 INPUTB
40 IF B<1 THEN 44\IF B>3 GOTO 44\B=INT(B)
41 GOTO 45
44 PRINT "TRY AGAIN...."\GOTO 30
45 PRINT\IF B=1 GOTO 50\IF B=2 GOTO 80\IF B=3 GOTO 90
50 PRINT "SHOULD BE EASY YOU'RE FLYING A NAZI-MADE PLANE."
60 GOTO 280
80 PRINT "BE CAREFUL!!!"\GOTO 280
90 PRINT "YOU'RE GOING FOR THE OIL, EH?"\GOTO 280
110 PRINT "AIRCRAFT -- LIBERATOR(1), B-29(2), B-17(3), LANCASTER(4)";
111 INPUT G\G=INT(G)
120IF G>4 GOTO 124\IF G<1 GOTO 124
121 IFG=2 GOTO 150\IF G=3 GOTO 170\IF G=4 GOTO 190\IF G=1 GOTO 130
124 PRINT "TRY AGAIN...."\GOTO 110
130 PRINT "YOU'VE GOT 2 TONS OF BOMBS FLYING FOR PLOESTI"
140 GOTO 280
150 PRINT "YOU'RE DROPPING THE A-BOMB ON HIROSHIMA."
160 GOTO 280
170 PRINT "YOU'RE CHASING THE BISMARK IN THE NORTH SEA."
180 GOTO 280
190 PRINT "YOU'RE BUSTING A GERMAN HEAVY WATER PLANT IN THE RUHR."
195 GOTO 280
200 PRINT "YOU'RE FLYING A KAMIKAZE (SUICIDE BOMBER) OVER THE USS LEXINGTON."
205 PRINT "YOUR FIRST KAMIKAZE MISSION (Y OR N)";\INPUT F$
208 IF F$="Y" THEN 210
209 S=0\GOTO 358
210 PRINT\IF RND(0)>.65 THEN 325\GOTO 380
220 PRINT "A NAZI, EH?  OH WELL. ARE YOU GOING FOR RUSSIA(1), ENGLAND(2)"
230 PRINT "OR FRANCE(3)";\INPUT M\M=INT(M)\IF M<1 GOTO 233\IF M>3 GOTO 233
231 GOTO 235
233 PRINT "WHAT??"\GOTO 220
235 PRINT\IF M=2 GOTO 260\IF M=3 GOTO 270
250 PRINT "YOU'RE NEARING STALINGRAD....."\GOTO 280
260 PRINT "NEARING LONDON. BE CAREFUL, THEY'VE GOT A GOOD AIR-RAID DEFENCE."
265 GOTO 280
270 PRINT "NEARING VERSAILLES.  DUCK SOUP.  THEY'RE NEARLY DEFENSELESS."
280 PRINT
285 PRINT "HOW MANY MISSIONS HAVE YOU FLOWN";\INPUT D
290 IF D<160 THEN 300\PRINT "MISSIONS, NOT MILES...."
295 PRINT "150 MISSIONS IS HIGH EVEN FOR OLD-TIMERS.  NOW THEN,"\GOTO 285
300 PRINT\IF D<100 THEN 310\PRINT"THAT'S PUSHING THE ODDS!"\GOTO 320
310 IF D>=25 THEN 320\PRINT "FRESH OUT OF TRAINING, EH?"
320 PRINT\IF D<160*RND(0) THEN 330
325 PRINT "DIRECT HIT!!!! ";INT(100*RND(0));"KILLED! MISSION SUCCESSFUL."
326 GOTO 390
330 PRINT "MISSED TARGET BY";INT(2+30*RND(0));"MILES!!"
335 PRINT "NOW YOU'RE REALLY IN FOR IT !!"\PRINT
340 PRINT "DOES THE ENEMY HAVE GUNS(1), MISSILES(2), OR BOTH(3)";\INPUTR
345 R=INT(R)\IF R<1 GOTO 347\IF R>3 GOTO 347\GOTO 350
347 PRINT "TRY AGAIN...."\GOTO 340
350 PRINT\IF R=2 THEN 360
355 PRINT "WHAT IS THE PERCENT HIT RATE OF THE ENEMY GUNNERS (10 TO 50)";
356 INPUT S
358 IF S>=10 GOTO 360\PRINT"YOU LIE, BUT YOU'LL PAY...."\PRINT\GOTO 380
360 PRINT\IF R=<1 GOTO 365\T=35
365 IF S+T>100*RND(0) THEN 380
370 PRINT"YOU MADE IT THROUGT TREMENDOUS FLAK!!"\GOTO 390
380 PRINT "* * * * * BOOM * * * * *"
384 PRINT "YOU HAVE BEEN SHOT DOWN......."
386PRINT"DEARLY BELOVED, WE ARE GATHERED HERE TODAY TO PAY OUR LAST TRIBUTE.."
390 PRINT\PRINT\PRINT\PRINT"PLAY AGAIN (Y OR N)";\INPUT U$\IFU$="Y"GOTO10
400 PRINT "CHICKEN!!!!!"\PRINT\PRINT
999 END