/TC01 RANDOM EXERCISER

RANBFR=6774
BUFFRS=RANBFR+201
IOT=6000

/GO TO PROCESS INTERRUPT

*1
	5402
	IRECD

*40
RECORD,	0
BLKFND,	0
IDCON,	.-1
WCLOC,	7754
CALOC,	7755
CDRIVE,	0
UNFUNC,	0
MSBITS,	0
COMBIT,	0
POSITN,	0
DIRECT,	0
LSTBLK,	0
LSTDRV,	0
SRCHIT,	SEARCH
REWIND,	REPOSI
NEWDRV,	CHNGDR
SELRAN,	RANSEL
GENPAT,	PATGEN
RANGEN,	GENRAN
READ1,	RDDATA
REGENP,	PREGEN
DATACO,	CODATA
WAITI,	WATINT
ERRSTP,	ERSTP
DATAMV,	MVDATA
RECRDK,	RECORD
COCNTR,	7777
RBUFST,	RANBFR
RBFLOC,	RANBFR-1
BF1LOC,	BUFFRS-1
DIRFLG,	0
NUMBLK,	0
RBUFND,	RANBFR+200
WRTDTY,	TYWDAT
RBFWD2,	RANBFR+1
BF2LOC,	BUFFRS+201
READ2,	REREAD
READ2A,	REREDA
TYPCON,	TYCONT
TYPTEX,	TYTEXT
K7760,	7760
K0037,	37
K7779,	7770
K0200,	200
K0040,	40
K0614,	614
K0030,	30
K7577,	7577
K0007,	7
K4000,	4000
K0700,	700
K0070,	70
K7000,	7000
K0003,	3
K0214,	214
K7700,	7700
DRIVTY,	TYDRV
K1000,	1000
EZBIT=K1000
K0010,	10
K0020,	20
K0077,	77
K0100,	100
K0240,	240
K0400,	400
K0604,	604
K16,	16
K260,	260
K3777,	3777
READTY,	TYRDAT
SRCHTY,	TYSRCH
K5075,	5075
K5076,	5076
K0050,	50
PASFLG,	0
K0002,	2
K2701,	2701
K6000,	6000
SRCHER,	SRHERR
TAPONT,	0
BLKFLG,	0
PREBLK,	0
RETUJM,	JMRETU
FRSWAT,	0

*200
RANDEX,	CLA OSR
	AND K7760
	SZA 
	JMP .+3
	HLT
	JMP RANDEX
	DCA MSBITS
	HLT
	CMA 
	DCA FRSWAT
	IOT 774
	JMS I REWIND
	DCA I LSTBLK
	JMS I NEWDRV
	JMP .-2
	CLA IAC
	DCA LSTDRV
MOFPRO,	JMS I SELRAN
	CLA CMA 
	DCA PASFLG
	TAD CDRIVE
	TAD LSTDRV
	SNA CLA 
	JMP SAMDRV
	TAD CDRIVE
	CMA IAC
	DCA LSTDRV
	CMA 
	DCA RSQFLG
MOFPR1,	JMS I RANGEN
	AND K0037
	CMA 
	DCA NUMBLK
	JMS I RANGEN
	AND K0003
	SNA CLA 
	CMA 
	DCA DIRFLG
	TAD I LSTBLK
	SNA CLA 
	JMP I WRITES
	CLL 
	TAD DIRFLG
	SZA CLA 
	STL
	TAD NUMBLK
	SNL 
	CMA IAC
	TAD I POSITN
	DCA RECORD
	TAD RECORD
	SPA CLA 
	DCA RECORD
	TAD RECORD
	CMA 
	TAD I LSTBLK
	SPA CLA 
	JMP I WRITES
	JMS I RANGEN
	AND K0007
	SNA 
	JMP I .+6
	AND K0003
	SNA CLA 
	JMP .+4
	JMP I .+1
	RDCMOD
	RALLTS
RDTAB,	JMS I READ1
	JMP I READ2
	TAD K0200
	IOT 764
	TAD RECORD
	DCA I POSITN
	TAD DIRFLG
	DCA I DIRECT
	JMS I REGENP
	JMS I DATACO
	RANBFR
	BUFFRS
	201
	ISZ COCNTR
	JMP I READ2A
	JMP MOFPRO
WRITES,	WRITE1
SAMDRV,	JMS I RANGEN
	SPA 
	JMP MOFPR1+1
	ISZ RSQFLG
	JMP MOFPR1+1
	AND K0003
	SNA CLA 
	CMA 
	DCA DIRFLG
	TAD DIRFLG
	CMA IAC
	TAD RBUFST
	DCA RECORD
	TAD DIRFLG
	TAD I RECORD
	AND K3777
	DCA RECORD
	JMP I .+1
	RDSEQ
RSQFLG,	0

*400
RDDATA,	JMP .
	CLA
	JMS I SRCHIT
	TAD K0030
	IOT 764
	TAD K7577
	DCA I WCLOC
	TAD BF1LOC
	DCA I CALOC
	JMS I WAITI
	1
	JMP I RDDATA
	TAD I WCLOC
	SNA CLA 
	ISZ RDDATA
	JMP I RDDATA
REREAD,	CLA CMA
	DCA PASFLG
	JMS I ERRSTP
	JMS I READTY
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	0042
	5457
	4353
	7700
	IOT 772
	DCA 10
	TAD K0010
	JMS I TYPCON
	JMS I TYPTEX
	0063
	6441
	6400
	4200
	7777
	7700
	TAD I WCLOC
	SNA CLA 
	JMP .+10
	TAD WCLOC
	JMS I TYPCON
	JMS I TYPTEX
	0067
	1643
	1677
	JMP REREDA
	JMS I REGENP
	TAD I CALOC
	TAD K7600
	DCA .+3
	JMS I DATACO
	RANBFR
	BUFFRS
	0201
REREDA,	LAS
	AND K6000
	SNA CLA 
	HLT
	ISZ PASFLG
	JMP REWDRV
	TAD DIRFLG
	CMA
	DCA DIRFLG
	JMS I READ1
	JMP REREAD+2
	JMS I REGENP
	JMS I DATACO
	RANBFR
	BUFFRS
	0201
	ISZ COCNTR
	JMP REREDA
	TAD DIRFLG
	CMA 
	DCA DIRFLG
	JMS I READ1
	JMP REREAD+2
	JMS I DATACO
	RANBFR
	BUFFRS
	201
	ISZ COCNTR
	JMP REREDA
REWDRV,	TAD K0604
	TAD UNFUNC
	IOT 766
	JMS I WAITI
	5000
	JMP K7600+1
	DCA I LSTBLK
	DCA I POSITN
	CMA 
	DCA I DIRECT
	IAC
	DCA LSTDRV
	JMP I .+1
	MOFPRO
K7600,	7600
	JMS I .+2
	JMP REWDRV
	MOVER+2
PREGEN,	JMP .
	TAD RBFLOC
	DCA 10
	TAD GETRED+2
	DCA 17
	TAD I CALOC
	DCA GETRED
	TAD I GETRED
	JMS I GETRED+1
	DCA I 10
	CMA 
	TAD GETRED
	DCA GETRED
	ISZ 17
	JMP .-7
	JMS I GENPAT
	JMP I PREGEN
GETRED,	0
	MCOMOB
	7774
/	0	/VRS -- REFERENCED

*600
PATGEN,	JMP .
	TAD MIN4
	DCA GENDEX
	TAD RBUFST
	DCA GENDEX+1
	TAD RBUFND
	DCA GENDEX+2
	TAD RPATO+1
	DCA RPATO
	TAD I GENDEX+1
	DCA RPATO+1
	TAD RPATO+1
	JMS MCOMOB
	DCA I GENDEX+2
	ISZ GENDEX+1
	CLA CMA 
	TAD GENDEX+2
	ISZ GENDEX
	JMP PATGEN+6
	DCA GENDEX+2
	TAD MIN60
	DCA GENDEX
GNPATR,	TAD RPATO
	CLL RAR 
	SZL 
	TAD K4000
	DCA RPATO+2
	TAD RPATO+2
	DCA I GENDEX+1
	TAD RPATO+2
	JMS MCOMOB
	DCA I GENDEX+2
	TAD RPATO+1
	DCA RPATO
	TAD RPATO+2
	DCA RPATO+1
	ISZ GENDEX+1
	CLA CMA 
	TAD GENDEX+2
	DCA GENDEX+2
	ISZ GENDEX
	JMP GNPATR
	DCA RPATO+2
	TAD RPATO
	CLL RAR 
	SZL 
	ISZ RPATO+2
	SZA 
	JMP .-4
	TAD RPATO+1
	CLL RAR 
	SZL 
	ISZ RPATO+2
	SZA 
	JMP .-4
	TAD RPATO+2
	JMS MCOMOB
	AND K7700
	TAD RPATO+2
	DCA I GENDEX+1
	JMP I PATGEN
GENDEX,	0
	0
	0
RPATO,	0
	0
	0
MCOMOB,	JMP .
	DCA COMSTR
	TAD COMSTR
	AND K0700
	CLL RAR 
	RTR 
	DCA COMSTR+1
	TAD COMSTR
	AND K0070
	RTL 
	RAL 
	TAD COMSTR+1
	DCA COMSTR+1
	TAD COMSTR
	AND K0007
	RTR 
	RTR 
	TAD COMSTR+1
	DCA COMSTR+1
	TAD COMSTR
	AND K7000
	RTL 
	RTL 
	TAD COMSTR+1
	CMA 
	JMP I MCOMOB
GENRAN,	JMP .
	CLA 
	TAD RANVAR
	CLL RAL 
	SZL 
	IAC
	DCA RANVAR
	TAD RANVAR
	TAD RANN0
	DCA RANN0
	TAD RANN0
	JMP I GENRAN
RANN0,	2634
RANVAR,	4263
MIN4,	7774
MIN60,	7704
COMSTR,	0
/	0	/VRS -- REFERENCED

*1000
RANSEL,	JMP .
	JMS SELGEN
	AND K0007
	DCA CDRIVE
	TAD CDRIVE
	CLL RAR 
	RTR 
	RAR 
	DCA UNFUNC
	TAD CDRIVE
	CMA 
	DCA 10
	TAD K4000
	DCA 11
	ISZ 10
	SKP 
	JMP EXIST
	TAD 11
	CLL RAR 
	DCA 11
	JMP .-6
EXIST,	TAD 11
	AND MSBITS
	SNA CLA 
	JMP RANSEL+1
	TAD CDRIVE
	TAD POSTBL
	DCA POSITN
	TAD CDRIVE
	TAD DIRTBL
	DCA DIRECT
	TAD CDRIVE
	TAD LSTTBL
	DCA LSTBLK
	JMP I RANSEL
POSTBL,	PNTRS+1
DIRTBL,	PNTRS+12
LSTTBL,	PNTRS+23
SELGEN,	JMP .
	TAD SELVAR
	CLL RAL 
	SZL 
	IAC
	DCA SELVAR
	TAD SELVAR
	TAD SELVAR+1
	DCA SELVAR+1
	TAD SELVAR+1
	JMP I SELGEN
SELVAR,	4263
	2634

*1200
MVDATA,	JMP .
	CLA 
	TAD I MVDATA
	ISZ MVDATA
	DCA MOVDEX
	TAD I MVDATA
	ISZ MVDATA
	DCA MOVDEX+1
	TAD I MVDATA
	ISZ MVDATA
	DCA MOVDEX+2
	TAD I MOVDEX
	DCA I MOVDEX+1
	ISZ MOVDEX
	ISZ MOVDEX+1
	ISZ MOVDEX+2
	JMP .-5
	JMP I MVDATA
MOVDEX,	0
	0
	0
CODATA,	JMP .
	CLA 
	TAD I CODATA
	ISZ CODATA
	DCA CODEX
	TAD I CODATA
	DCA CODEX+1
	ISZ CODATA
	TAD I CODATA
	CMA IAC
	DCA CODEX+2
	ISZ CODATA
	CMA 
	DCA COCNTR
COLOOP,	TAD I CODEX
	CMA IAC
	TAD I CODEX+1
	SZA CLA 
	JMP COERRO
	ISZ CODEX
	ISZ CODEX+1
	ISZ CODEX+2
	JMP COLOOP
	JMP I CODATA
CODEX,	0
	0
	0
	.-2
COERRO,	ISZ COCNTR
	JMP COERR1
	JMS I ERRSTP
	IOT 761
	AND K0010
	SNA CLA 
	JMP .+4
	JMS I .+2
	JMP .+3
	TYRALL
	JMS I READTY
	JMS I TYPTEX
	7777
	4441
	6441
	0045
	6262
	5762
	7700
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	0042
	5457
	4353
	7700
COERR1,	CLA OSR
	AND K1000
	SNA CLA 
	JMP .+5
	TAD COCNTR
	TAD K7774
	SMA CLA 
	JMP COLOOP+5
	JMS I TYPTEX
	7777
	7700
	TAD CODEX
	JMS I TYPCON
	JMS I TYPTEX
	0043
	5762
	7700
	TAD CODEX+1
	JMS I TYPCON
	JMS I TYPTEX
	0051
	5643
	7700
	TAD CODEX+3
	JMS I TYPCON
	JMS I TYPTEX
	41
	4444
	6263
	51
	5643
	7700
	JMP COLOOP+5
K7774,	7774

*1400
WRITE1,	TAD RBFLOC
	DCA 10
	TAD I LSTBLK
	DCA I 10
	TAD NUMBLK
	CMA IAC
	TAD I LSTBLK
	DCA RECORD
	TAD RECORD
	TAD K5075
	SMA CLA 
	JMP REWCK
	TAD RECORD
	DCA I 10
	JMS I RANGEN
	DCA I 10
	JMS I RANGEN
	DCA I 10
	JMS I RANGEN
	AND K0003
	SNA CLA 
	CMA 
	DCA DIRFLG
	TAD DIRFLG
	TAD RBUFST
	DCA 10
	TAD 10
	DCA 11
	TAD K4000
	TAD I 10
	DCA I 11
	JMS I GENPAT
	TAD NUMBLK
	DCA SAVNUM
CORT1R,	TAD NUMBLK
	CMA
	DCA RECORD
	TAD DIRFLG
	SZA CLA 
	TAD RECORD
	TAD I LSTBLK
	DCA RECORD
	JMP I .+1
	WDCMOD
	JMS I SRCHIT
WRT1A,	TAD K0050
	IOT 764
	TAD K7577
	DCA I WCLOC
	TAD RBFLOC
	DCA I CALOC
	JMS I WAITI
	1
	JMP WSTERR
	TAD I WCLOC
	SZA CLA 
	JMP WSTERR
	TAD DIRFLG
	CLL 
	TAD RECORD
	SPA 
	CLA STL 
	DCA RECORD
	SNL
	ISZ RECORD
	ISZ NUMBLK
	JMP WRT1A+1
WDINC,	TAD RECORD
	DCA I POSITN
	TAD DIRFLG
	DCA I DIRECT
	TAD I RBFWD2
	AND K3777
	DCA I LSTBLK
	TAD K0200
	IOT 764
	JMP I .+1
	MOFPRO
	REWDRV
REWCK,	JMS I RANGEN
	SPA CLA 
	JMP I REWCK-1
	DCA RECORD
	DCA DIRFLG
	JMP I .+1
	RDTAB
WSTERR,	JMS I ERRSTP
	JMS I WRTDTY
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	7700
	TAD SAVNUM
	DCA NUMBLK
	IOT 772
	DCA SAVNUM+2
	TAD SAVNUM+1
	JMS I TYPCON
	JMS I TYPTEX
	63
	6441
	6400
	4277
	TAD WCLOC
	JMS I TYPCON
	JMS I TYPTEX
	67
	1643
	1677
	LAS
	AND K6000
	SNA CLA 
	HLT
	ISZ PASFLG
	JMP I .+2
	JMP CORT1R
	REWDRV
SAVNUM,	0
	.+1
/	0	/VRS -- REFERENCED

*1600
RDSEQ,	TAD I RBUFST
	AND K3777
	DCA RECORD
	TAD I RBFWD2
	AND K3777
	DCA NUMBLK
	TAD RECORD
	CMA 
	TAD NUMBLK
	DCA NUMBLK
	JMS I RANGEN
	CLL 
	SPA CLA 
	CMA 
	SZA 
	STL
	DCA DIRFLG
	TAD RECORD
	SZL 
	TAD NUMBLK
	DCA RECORD
	TAD NUMBLK
	CMA 
	DCA NUMBLK
	JMS I READ1
	JMP I READ2
RDBUF1,	ISZ NUMBLK
	JMP .+3
	TAD K0200
	JMP .+5
	TAD BF2LOC
	DCA I CALOC
	TAD K7577
	DCA I WCLOC
	IOT 764
	JMS I DATACO
	RANBFR
	BUFFRS
	0201
	ISZ COCNTR
	JMP I READ2A
	TAD NUMBLK
	SNA CLA 
	JMP NDOFRD
	TAD DIRFLG
	SNA 
	IAC
	TAD RECORD
	DCA RECORD
	JMS I WAITI
	1
	JMP I READ2
	TAD I WCLOC
	SZA CLA 
	JMP I READ2
	ISZ NUMBLK
	JMP .+3
	TAD K0200
	JMP .+5
	TAD BF1LOC
	DCA I CALOC
	TAD K7577
	DCA I WCLOC
	IOT 764
	JMS I DATACO
	RANBFR
	BUFFRS+202
	0201
	ISZ COCNTR
	JMP I READ2A
	TAD NUMBLK
	SNA CLA 
	JMP NDOFRD
	TAD DIRFLG
	SNA 
	IAC
	TAD RECORD
	DCA RECORD
	JMS I WAITI
	1
	JMP I READ2
	TAD I WCLOC
	SZA CLA 
	JMP I READ2
	JMP RDBUF1
NDOFRD,	TAD RECORD
	DCA I POSITN
	TAD DIRFLG
	DCA I DIRECT
	JMP I .+1
	MOFPRO

/PAUSE

/TC01 DECTREX 1  -  TAPE 2
/READ CONTINUOUS MODE
/TWO BLOCKS AND COMPARE DATA READ

*2000
RDCMOD,	TAD DIRFLG
	SZA CLA
	JMP .+10
	TAD RECORD
	CMA 
	TAD I LSTBLK
	SZA 
	JMP .+6
	JMP I .+1
	RDTAB
	TAD RECORD
	SNA CLA 
	JMP I .-3
	JMS I SRCHIT
	TAD K0130
	IOT 764
	TAD K7577
	TAD K7577
	DCA I WCLOC
	TAD BF1LOC
	DCA I CALOC
	JMS I WAITI
	1
	JMP RDCERR
	TAD I WCLOC
	SZA CLA 
	JMP I READ2
	TAD K0200
	IOT 764
	TAD DIRFLG
	SNA 
	IAC
	TAD RECORD
	DCA RECORD
	JMS I REGENP
	JMS I DATACO
	RANBFR
	BUFFRS+201
	0201
	ISZ COCNTR
	JMP I READ2A
	CMA 
	TAD BF2LOC
	DCA I CALOC
	JMS I REGENP
	TAD DIRFLG
	SNA 
	IAC
	CMA IAC
	TAD RECORD
	DCA RECORD
	JMS I DATACO
	RANBFR
	BUFFRS
	0201
	ISZ COCNTR
	JMP I READ2A
	TAD RECORD
	DCA I POSITN
	JMP I .+1
	MOFPRO
RDCERR,	TAD I WCLOC
	SNA 
	JMP .+6
	CMA IAC
	TAD K7577
	DCA I WCLOC
	JMP I .+1
	REREAD
	TAD DIRFLG
	SNA 
	IAC
	TAD RECORD
	DCA RECORD
	JMP I .-6
K0130,	130

*2200
WDCMOD,	DCA TRECTR
	TAD NUMBLK
	TAD K0003
	SNA 
	JMP SWCMOD
	SMA 
	JMP I .+3
	ISZ TRECTR
	JMP WDCMOD+2
	WRT1A-1
SWCMOD,	TAD TRECTR
	CMA 
	DCA TRECTR
	JMS I DATAMV
	RANBFR
	BUFFRS
	7376
	JMS I SRCHIT
	TAD K0150
SWCMDL,	IOT 764
	TAD K7175
	DCA I WCLOC
	TAD RBFLOC
	DCA I CALOC
	JMS I WAITI
	1
	JMP WDCERR
	TAD I WCLOC
	SZA CLA 
	JMP WDCERR
	TAD DIRFLG
	CLL 
	SZA CLA 
	STL
	TAD K0003
	SZL 
	CMA IAC
	TAD RECORD
	DCA RECORD
	ISZ TRECTR
	JMP SWCMDL
	JMP I .+1
	WDINC
WDCERR,	DCA TRECTR
	TAD I WCLOC
	CMA IAC
	TAD K7577
	SPA 
	JMP .+3
	ISZ TRECTR
	JMP .-4
	CLA 
	TAD DIRFLG
	CLL 
	SZA CLA 
	STL 
	TAD TRECTR
	SZL 
	CMA IAC
	TAD RECORD
	DCA RECORD
	JMP I .+1
	WSTERR
TRECTR,	0
K7175,	7175
K0150,	0150

*2400
RALLTS,	TAD DIRFLG
	SNA
	IAC
	CMA IAC
	TAD RECORD
	DCA RECORD
	TAD RECORD
	SPA 
	JMP .+4
	TAD K5076
	SPA CLA 
	JMP .+4
	CLA 
	JMP I .+1
	MOFPR1
	DCA RAEFLG
	JMS I SRCHIT
	IOT 764
	TAD DIRFLG
	SNA 
	IAC
	TAD RECORD
	DCA RECORD
	IOT 773
	JMP .-1
	SPA CLA 
	JMP RASERR
	TAD BLKFND
	CMA IAC
	TAD RECORD
	SZA CLA 
	JMP RASERR
	TAD K0120
	IOT 764
	TAD K7571
	DCA I WCLOC
	TAD BF1LOC
	DCA I CALOC
	JMS I WAITI
	1
	JMP I RARERR
	TAD I WCLOC
	SZA CLA 
	JMP I RARERR
	TAD K0200
	IOT 764
	TAD RADLOC
	DCA 10
	TAD K7577
	DCA 11
	DCA CKSUMR
	TAD I 10
	AND K0077
	DCA REVCHK
	TAD I 10
	JMS XORSUM
	ISZ 11
	JMP .-3
	TAD CKSUMR
	CMA 
	AND K0077
	DCA DATASM
	TAD I 10
	AND K7700
	DCA FWDCHK
	TAD DATASM
	DCA CKSUMR
	TAD FWDCHK
	JMS XORSUM
	TAD REVCHK
	JMS XORSUM
	TAD CKSUMR
	SZA CLA 
	JMP I CKSERR
RADCHK,	TAD RECORD
	DCA I POSITN
	CMA 
	TAD I CALOC
	DCA I CALOC
	JMS I REGENP
	JMS I DATACO
	RANBFR
	BUFFRS+5
	0201
	ISZ RAEFLG
	ISZ COCNTR
	JMP I READ2A
	JMP I .+1
	MOFPRO-2
XORSUM,	JMP .
	CMA 
	DCA XORSAV
	CMA 
	DCA XORSAV+1
	TAD XORSAV
	CMA 
	AND CKSUMR
	DCA XORSAV+2
	TAD CKSUMR
	CMA 
	AND XORSAV
	TAD XORSAV+2
	AND K0077
	DCA CKSUMR
	ISZ XORSAV+1
	JMP I XORSUM
	TAD XORSAV
	RTR 
	RTR 
	RTR 
	DCA XORSAV
	JMP XORSUM+5
CKSERR,	ERRCKS
DATASM,	0
FWDCHK,	0
REVCHK,	0
CKSUMR,	0
XORSAV,	0
	0
	0
RARERR,	ERRRAR
RASERR,	DCA PASFLG
	JMP I .+1
	SRHERR
K0120,	0120
K7571,	7571
RADLOC,	BUFFRS+3
RAEFLG,	0

*2600
ERRCKS,	JMS I CSECON
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	7777
	4353
	6365
	5500
	4562
	6257
	6277
	TAD CSECON+1
	JMS I TYPCON
	JMS I TYPTEX
	62
	4566
	7700
	JMS CKSTYP
	TAD CSECON+2
	JMS I TYPCON
	JMS I CSECON+3
	JMS CKSTYP
	JMS CALCTY
	TAD CSECON+4
	JMS I TYPCON
	JMS CKSTYP
	TAD I CSECON+5
	CMA 
	AND K0077
	DCA I CSECON+5
	TAD CSECON+5
	JMS I TYPCON
	JMS CALCTY
	JMS I TYPTEX
	54
	1660
	1642
	1677
	CMA 
	DCA I .+3
	JMP I .+1
	RADCHK
	RAEFLG
	REWDRV
CKSTYP,	JMP .
	JMS I TYPTEX
	43
	5045
	4353
	63
	6555
	7700
	JMP I CKSTYP
CALCTY,	JMP .
	JMS I TYPTEX
	43
	4154
	4365
	5441
	6445
	4477
	JMP I CALCTY
CSECON,	TYRALL
	REVCHK
	DATASM
	TYDATA
	FWDCHK
	CKSUMR
ERRRAR,	JMS I ERRSTP
	JMS I CSECON
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	7700
	IOT 772
	DCA .+24
	TAD .+22
	JMS I TYPCON
	JMS I TYPTEX
	63
	6441
	6400
	4277
	TAD WCLOC
	JMS I TYPCON
	JMS I TYPTEX
	67
	1643
	1677
	LAS
	AND K6000
	SNA CLA 
	HLT
	JMP I CKSTYP-1
	.+1
	0

*3000
WATINT,	JMP .
	TAD WTKON1
	DCA WTCNTR
	IOT 761
	AND K0070
	SZA CLA 
	JMP .+3
	TAD WTKON2
	DCA WTCNTR
	ISZ FRSWAT
	JMP RESETD
	JMS SETIDX
	ION
	JMP I .+1
	ISZTST
RESETD,	DCA FRSWAT
	ISZ PICNTR
	SKP 
	JMS SETIDX
	TAD 0
	DCA I PIDEX1
	ISZ PIDEX1
	TAD LKSAVE
	RAR 
	CLA 
	TAD ACSAVE
	ION
	JMP I 0
IRECD,	DCA ACSAVE
	RAL 
	DCA LKSAVE
	IOT 771
	JMP NDTSKP
	IOT 772
	DCA SBRECD
	TAD I WATINT
	CMA 
	AND SBRECD
	SNA CLA 
	ISZ WATINT
	ISZ WATINT
	TAD WATINT
	DCA I PIDEX2
	ISZ PIDEX2
	JMP I WATINT
NDTSKP,	JMS I ERRSTP
	JMS I TYPTEX
	7777
	6016
	5116
	0077
	JMP PTSTNS
PTSTND,	.+1
	ISZ WTCNTR
	JMP I PTSTND
	IOF
	IOT 771
	CMA 
	DCA SBRECD
	JMS I ERRSTP
	JMS I TYPTEX
	7777
	5657
	60
	1651
	1677
	ISZ SBRECD
	JMP .+4
PTSTNS,	JMS I TYPTEX
	56
	5777
	JMS I TYPTEX
	44
	4543
	6441
	6045
	63
	5351
	6077
	ISZ WATINT
	CMA 
	DCA FRSWAT
	JMP I WATINT
WTKON1,	7655
WTKON2,	6422
WTCNTR,	0
LKSAVE,	0
ACSAVE,	0
SBRECD,	0
SETIDX,	JMP .
	TAD K7772Y
	DCA PICNTR
	TAD PITBL
	DCA PIDEX1
	TAD PIRTBL
	DCA PIDEX2
	JMP I SETIDX
K7772Y,	7772
PICNTR,	0
PIDEX1,	0
PIDEX2,	0
PITBL,	.+1

*PITBL+7
PIRTBL,	.+1

*3200
ISZTST,	CMA
	DCA TEMP5
	DCA TEMP2
	DCA TEMP1
	ISZ TEMP1
	ISZ TEMP2
	JMP .-2
	TAD TEMP2
	SZA 
	HLT
	CLA CMA 
	TAD TEMP1
	SZA 
	HLT
	ISZ TEMP5
	SKP 
	JMP ISZTST+3
	JMS I NDPTST
ROT1TS,	TAD TEMP2
	STL RAR 
	RAL 
	SNL 
	HLT
	CMA IAC
	TAD TEMP2
	SZA 
	HLT
	ISZ TEMP2
	JMP ROT1TS
	JMS I NDPTST
ROT2TS,	TAD TEMP2
	CLL RTL 
	RTR 
	SZL 
	HLT
	CMA IAC
	TAD TEMP2
	SZA 
	HLT
	ISZ TEMP2
	JMP ROT2TS
	JMS I NDPTST
TADTST,	DCA TEMP3
	TAD PRAN1
	CLL RAL 
	SZL 
	IAC
	DCA PRAN1
	TAD PRAN2
	TAD PRAN1
	DCA PRAN2
	TAD PRAN2
	DCA TEMP4
	TAD PRAN2
	TAD TEMP3
	CMA IAC
	TAD TEMP4
	SZA 
	HLT
	ISZ TEMP4
	NOP
	ISZ TEMP3
	JMP .-11
	JMS I NDPTST
JMSTST,	TAD K7763X
	DCA TEMP1
	TAD K7600X
	DCA TEMP2
	TAD JMSLOC
	DCA TEMP3
	TAD JMSKON
	DCA TEMP4
	TAD TEMP4
	DCA I TEMP3
	ISZ TEMP4
	ISZ TEMP3
	ISZ TEMP2
	JMP .-5
	TAD RETJMP
	DCA I TEMP3
	JMP I JMSLOC
JMRETU,	TAD K7600X
	DCA TEMP2
	TAD JMSLOC
	DCA TEMP3
	TAD TEMP3
	CMA 
	TAD I TEMP3
	SZA 
	HLT
	ISZ TEMP3
	ISZ TEMP2
	JMP JMRETU+4
	ISZ TEMP1
	JMP JMSTST+2
	JMS I NDPTST
	JMP ISZTST
TEMP1,	0
TEMP2,	0
TEMP3,	0
TEMP4,	0
TEMP5,	0
PRAN1,	4263
PRAN2,	2634
NDPTST,	PTSTND
JMSLOC,	6000
JMSKON,	4200
K7600X,	7600
K7763X,	7763
RETJMP,	JMP I RETUJM

/PAUSE

/TC01 DECTEX 1  - TAPE 3

*3400
REPOSI,	JMP .
	JMS RSFDRV
	TAD K0604
	TAD UNFUNC
	IOT 766
	JMS I WAITI
	5000
	JMP MOVER
	CLA CMA 
	DCA I POSITN
	CLA CMA 
	DCA I DIRECT
	JMS CHNGDR
	JMP REPOSI+2
	JMP I REPOSI
RSFDRV,	JMP .
	CLA 
	DCA CDRIVE
	TAD K4000
	DCA COMBIT
	TAD MSBITS
	AND COMBIT
	SZA CLA 
	JMP RSFDR1
	TAD COMBIT
	CLL RAR 
	DCA COMBIT
	ISZ CDRIVE
	JMP RSFDRV+5
RSFDR1,	JMS GNPTRS
	JMP I RSFDRV
CHNGDR,	JMP .
	CLA 
	TAD COMBIT
	CLL RAR 
	AND NBIT8
	SZA 
	JMP .+4
	JMS RSFDRV
	ISZ CHNGDR
	JMP I CHNGDR
	DCA COMBIT
	ISZ CDRIVE
	TAD COMBIT
	AND MSBITS
	SNA CLA 
	JMP CHNGDR+1
	JMS GNPTRS
	JMP I CHNGDR
GNPTRS,	JMP .
	TAD CDRIVE
	CLL RTR 
	RTR 
	DCA UNFUNC
	TAD CDRIVE
	TAD PNTRS
	DCA POSITN
	TAD CDRIVE
	TAD PNTRS+11
	DCA DIRECT
	TAD CDRIVE
	TAD PNTRS+22
	DCA LSTBLK
	JMP I GNPTRS
NBIT8,	7767
PNTRS,	.+1
	0
	0
	0
	0
	0
	0
	0
	0
	.+1
	0
	0
	0
	0
	0
	0
	0
	0
	.+1
	0
	0
	0
	0
	0
	0
	0
	0
	0
	.+1
	0
	TYMOVE
MOVER,	JMS .+2
	JMP REPOSI+2
	JMP .
	JMS I ERRSTP
	JMS I MOVER-1	/TYMOVE
	IOT 772
	DCA MOVER-2
	TAD MOVER-3
	JMS I TYPCON
	JMS I TYPTEX
	63
	6441
	6400
	4277
	LAS
	AND K6000
	SNA CLA 
	HLT
	JMP I MOVER+2

*3600
SEARCH,	JMP .
	CLA CLL 
	TAD DIRFLG
	SZA CLA 
	STL 
	TAD K0003
	SNL 
	CMA IAC
	TAD RECORD
	CMA IAC
	DCA TAPONT
	TAD DIRFLG
	SNA CLA 
	TAD K0400
	TAD K0214
	TAD UNFUNC
	IOT 766
	TAD IDCON
	DCA I CALOC
	CMA 
	DCA BLKFLG
	JMS I WAITI
	1
	JMP SREZTS
	JMS SRCONT
	JMP SRTARN
	JMP SRTARN
	IOT 764
	JMP .-7
SRTARN,	IOT 761
	CMA 
	AND K0200
	TAD K0400
	IOT 764
	TAD RECORD
	CMA IAC
	DCA TAPONT
	CMA 
	DCA BLKFLG
	JMS I WAITI
	1
	JMP I SRCHER
	JMS SRCONT
	JMP I SEARCH
	JMP I SRCHER
	CMA 
	TAD BLKFLG
	SNA CLA 
	JMP SRCMOD
	IOT 764
	JMP .-13
SRCONT,	JMP .
	ISZ BLKFLG
	SKP 
	JMP SRFBLK
	IOT 761
	AND K0400
	SZA CLA 
	CMA 
	SNA 
	IAC
	TAD PREBLK
	CMA IAC
	TAD BLKFND
	SZA CLA 
	JMP I SRCHER
SRFBLK,	TAD BLKFND
	DCA PREBLK
	TAD BLKFND
	TAD TAPONT
	SNA 
	JMP I SRCONT
	ISZ SRCONT
	CLL 
	SPA CLA 
	STL 
	IOT 761
	AND K0400
	SZL 
	JMP .+4
	SZA CLA 
	ISZ SRCONT
	JMP I SRCONT
	SNA CLA 
	ISZ SRCONT
	JMP I SRCONT
SREZTS,	IOT 772
	AND EZBIT
	SNA CLA 
	JMP I SRCHER
	TAD TAPONT
	SMA 
	JMP .+4
	TAD K2701
	SMA CLA 
	JMP .+13
	LAS
	RAR 
	SNL CLA 
	JMP SRTARN
	TAD K0200
	IOT 764
	JMS I WAITI
	5000
	JMP I SRCHER
	JMP SRTARN
	ISZ BLKFLG
	JMP I SRCHER
	JMP SRTARN
SRCMOD,	TAD BLKFND
	CMA IAC
	TAD RECORD
	SMA 
	CMA IAC
	DCA I WCLOC
	TAD K0100
	IOT 764
	JMS I WAITI
	1
	JMP I SRCHER
	TAD BLKFND
	CMA IAC
	TAD RECORD
	SZA CLA 
	JMP I SRCHER
	TAD K0100
	IOT 764
	JMP I SEARCH

*4000
SRHERR,	JMS I ERRSTP
	JMS I SRCHTY
	TAD RECRDK
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	67
	4156
	6445
	4400
	7700
	TAD DIRFLG
	SNA CLA 
	JMP .+3
	JMS I BACKTY
	SKP 
	JMS I FORDTY
	TAD IDCON
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	46
	5765
	5644
	7700
	CMA 
	TAD I SEKONS
	SPA CLA 
	JMP .+12
	TAD SEKONS+1
	JMS I TYPCON
	JMS I TYPTEX
	54
	4163
	6400
	4254
	5743
	5377
	ISZ I SEKONS
	NOP
	TAD SEKONS
	JMS I TYPCON
	JMS I TYPTEX
	42
	5457
	4353
	6300
	6245
	4144
	7700
	IOT 772
	DCA SEKONS+3
	TAD SEKONS+2
	JMS I TYPCON
	JMS I TYPTEX
	63
	6441
	6400
	4277
	LAS 
	AND K6000
	SNA CLA 
	HLT
	ISZ PASFLG
	JMP I .+3
	JMP I .+1
	SEARCH+1
	REWDRV
SEKONS,	BLKFLG
	PREBLK
	.+1
	0
BACKTY,	TYBKW
FORDTY,	TYFWD

*4200
TYTEXT,	JMP .
	CLA 
	TAD I TYTEXT
	CMA 
	DCA TXSTOR
	ISZ TYTEXT
	TAD TXSTOR
	SZA 
	JMP .+3
	JMS CRLFLF
	JMP TYTEXT+1
	AND K7700
	SNA 
	JMP I TYTEXT
	RTR 
	RTR 
	RTR 
	JMS TYCHAR
	TAD TXSTOR
	AND K0077
	SNA 
	JMP I TYTEXT
	JMS TYCHAR
	JMP TYTEXT+1
TYCHAR,	JMP .
	DCA CRLFLF-1
	LAS
	SPA CLA 
	JMP I TYCHAR
	TAD CRLFLF-1
	CMA 
	AND K0077
	TAD K0240
	TLS
	TSF 
	JMP .-1
	CLA 
	TCF
	JMP I TYCHAR
	0
CRLFLF,	JMP .
	LAS 
	SPA CLA 
	JMP I CRLFLF
	TAD K0215
	TLS
	TSF 
	JMP .-1
	CLA 
	TAD K0212
	TLS
	TSF 
	JMP .-1
	TCF
	CLA 
	JMP I CRLFLF
K0215,	0215
K0212,	0212
TYCONT,	JMP .
	DCA TXSTOR
	TAD I TXSTOR
	DCA TXSTOR
	JMS CRLFLF
	JMS TYCOVR
	JMS TYCOVR
	JMS TYCOVR
	JMS TYCOVR
	JMP I TYCONT
TYCOVR,	JMP .
	TAD TXSTOR
	RTL 
	RAL 
	DCA TXSTOR
	TAD TXSTOR
	RAL 
	AND K0007
	TAD K0020
	CMA 
	JMS TYCHAR
	JMP I TYCOVR
TXSTOR,	0
ERSTP,	JMP .
	IOT 761
	AND K0200
	TAD K0003
	IOT 764
	JMP I ERSTP

*4400
TYMOVE,	JMP
	JMS TYDRV
	JMS I TYPTEX
	7777
	5557
	6645
	0077
	JMS TYDIR
	JMP I TYMOVE
TYSRCH,	JMP .
	JMS TYDRV
	JMS I TYPTEX
	6345
	4162
	4350
	0077
	JMS TYDIR
	JMS TYMODE
	JMP I TYSRCH
TYRDAT,	JMP .
	JMS TYDRV
	JMS TYREAD
	JMS TYDATA
	JMS TYDIR
	JMS TYMODE
	JMP I TYRDAT
TYRALL,	JMP .
	JMS TYDRV
	JMS TYREAD
	JMS TYALL
	JMS TYDIR
	JMS TYMODE
	JMP I TYRALL
TYWDAT,	JMP .
	JMS TYDRV
	JMS TYWRIT
	JMS TYDATA
	JMS TYDIR
	JMS TYMODE
	JMP I TYWDAT
TYWALL,	JMP .
	JMS TYDRV
	JMS TYWRIT
	JMS TYALL
	JMS TYDIR
	JMS TYMODE
	JMP I TYWALL
TYREAD,	JMP .
	JMS I TYPTEX
	6245
	4144
	0077
	JMP I TYREAD
TYWRIT,	JMP .
	JMS I TYPTEX
	6762
	5164
	4500
	7700
	JMP I TYWRIT
TYDATA,	JMP .
	JMS I TYPTEX
	0
	4441
	6441
	0077
	JMP I TYDATA
TYALL,	JMP .
	JMS I TYPTEX
	4154
	5400
	7700
	JMP I TYALL
TYDRV,	JMP .
	LAS 
	SPA CLA 
	JMP I TYDRV
	JMS I TYPTEX
	7777
	7777
	4462
	5166
	4500
	0077
	TAD CDRIVE
	SNA 
	TAD K0010
	TAD K260
	TLS
	TSF 
	JMP .-1
	TCF
	JMS I TYPTEX
	7777
	7700
	JMP I TYDRV
TYDIR,	JMP .
	IOT 761
	AND K0400
	SNA CLA 
	JMP TYFWD-2
	JMS TYBKW
	JMP I TYDIR
TYBKW,	JMP .
	JMS I TYPTEX
	4253
	6744
	0077
	JMP I TYBKW
	JMS TYFWD
	JMP I TYDIR
TYFWD,	JMP .
	JMS I TYPTEX
	4667
	4400
	7700
	JMP I TYFWD
TYMODE,	JMP .
	IOT 761
	AND K0100
	SNA CLA 
	JMP I TYMODE
	JMS I TYPTEX
	4300
	5557
	4445
	0077
	JMP I TYMODE
$