*20
	CLR
	PDP	/PROGRAM FOR LINC
	PMODE	/START 20
	JMP I P200
P200,	200
	*4400
	LMODE
	CLR	/PROGRAM TO RETURN
	LDA I	/TO DIAL WITH A
	701	/LINC START 400
	STC 16
	LDA I
	7300
	STC 17
	JMP 16
	PMODE
	*200
START,	CLA CLL
	KCC	/CLEAR TTI FLAG
	TLS	/SET TTO FLAG
	TAD FST	/SET POINTER TO
	DCA PTR	/FIELD-1
	TAD LF
	TYPE	/LINE FEEL
	CLA
	TAD CR	/FIRST POSITION IN
	JMP ECHO/FIELD IS CR- LF.
IN,	KSF
	JMP .-1	/WAIT FOR KEY STRUCK
	KRB
ECHO,	TYPE	/ECHO INPUT
	ISZ PTR
	DCA I PTR/STORE IN FIELD
	TAD I PTR
	TAD NCR	/CR?
	SZA
	JMP .+3	/NO, SEE IF IT IS A BELL
	TAD LF	/YES, ALSO LINE FEED
	JMP ECHO/AND STORE IT.
	TAD CR
	TAD NBL	/BELL?
	SZA
	JMP IN	/NO, SO MORE TTY INPUT
	TAD FST	/YES, SO SET UP OUTPUT
	DCA 10	/AUTO-INDEX TO FIELD-1
OUT,	TAD I 10/BRING IN CHARACTER
	TYPE	/AND OUTPUT IT
	TAD NBL
	SNA	/BELL?
	JMP START/YES, SO START OVER
	CLA	/NO, SO MORE TTY OUTPUT
	JMP OUT
	TYPE=JMS .
	0	/SUBROUTINE FOR TYPING
	TSF	/OUTPUT ON TTY
	JMP .-1
	TLS
	JMP I .-4
FST,	FLD-1	/CONSTANTS TABLE
PTR,	0
NBL,	-207
NCR,	-215
CR,	215
LF,	212
FLD,	0	/CHARACTER STORAGE
	0	/BEGINS HERE.
/
/
/DATE:          OCTOBER 18, 1971
/PROGRAMMER:    DANIEL GRAY
/TITLE:         REPEAT
/DESCRIPTION:   ACCEPTS TTY INPUT AND
/		ECHOS IT.  UPON
/		RECEPTION OF A CTRL G
/		(BELL),	 RETURNS AND
/		TYPES OUT PREVIOUS INPUT/