*20
	PMODE
	*40
EX1,	0
AC1H,	0
AC1L,	0
OVER1,	0
EXP,	0
HORD,	0
LORD,	0
OVER2,	0
EXP1,	0
QUOL,	0
FPAC1,	0
	0
	0
	*61
FLAG,	0
	5
	5
	*5
	FLINTP
	FLOUTP
	FPNT
	*44
EXPONT,	0
HORDER,	0
LORDER,	0
	*52
FPAC1,	0
	0
	0
SWIT1,	7777	/NO CRLF AFTER OUTPUT
SWIT2,	7777		/LF AFTER CR
CHAR,	0
DSWIT,	0
	*1767
PRCHAR,	0
	TAD SWIT2
	SNA CLA
	JMP I PRCHAR
	TAD LFED
	JMS I OPUT
	JMP I PRCHAR
OPUT,	OUT
LFED,	0212
	PMODE
	*600
FPNT,	0
	CLA CLL
	DCA OVER1
	DCA OVER2
	TAD I FPNT
	DCA JUMP
	TAD JUMP
	AND PAGENO
	SNA CLA
	JMP .+3
	TAD MASK5
	AND FPNT
	DCA ADDR
	TAD MASK7
	AND JUMP
	TAD ADDR
	DCA ADDR
	TAD INDRCT
	AND JUMP
	SNA CLA
	JMP LOOPO1
	TAD I ADDR
	DCA ADDR
LOOPO1,	ISZ FPNT
	TAD I ADDR
	DCA EX1
	TAD ADDR
	DCA SAVE
	ISZ SAVE
	TAD I SAVE
	DCA AC1H
	ISZ SAVE
	TAD I SAVE
	DCA AC1L
	TAD JUMP
	CLL RTL
	RTL
	AND MASK3
	TAD TABLE
	DCA JUMP2
	TAD I JUMP2
	DCA JUMP2
	JMP I JUMP2
JUMP,	0
JUMP2,	0
GO2,	0
ADDR,	0
SAVE,	0
MASK3,	0017
MASK5,	7600
MASK7,	0177
PAGENO,	0200
INDRCT,	0400
TABLE,	.+1
	EXIT
	FLAD
	FLSU
	FLMY
	FLDV2
	FLGT
	FLPT
	NORF
FLGT,	TAD EX1
	DCA EXP
	TAD AC1H
	DCA HORD
	TAD AC1L
	DCA LORD
	JMP FPNT+1
FLPT,	TAD EXP
	DCA I ADDR
	ISZ ADDR
	TAD HORD
	DCA I ADDR
	ISZ ADDR
	TAD LORD
	DCA I ADDR
	JMP FPNT+1
FLSU,	JMS I OPMINS
FLAD,	JMS I ALGN
	JMP FPNT+1
	JMS I UNORM
	TAD OVER1
	TAD OVER2
	DCA OVER2
	RAL
	TAD AC1L
	TAD LORD
	DCA LORD
	RAL
	TAD AC1H
	TAD HORD
	DCA HORD
NORF,	JMS I NORM
	JMP FPNT+1
OPMINS,	MINUS2
EXIT,	TAD JUMP
	AND MASK3
	SNA
	JMP I FPNT
	TAD ACON6
	DCA JUMP2
	TAD I JUMP2
	DCA JUMP2
	TAD FPNT
	DCA GO2
	JMS I JUMP2
	TAD GO2
	DCA FPNT
	JMP FPNT+1
ACON6,	TABLE6-1
FLMY,	CLA IAC
	TAD EX1
	TAD EXP
	DCA EXP
	JMS I MULT
	JMP FPNT+1
MULT,	DMULT
NORM,	DNORM
ALGN,	ALIGN
UNORM,	DUNORM
SQUARE,	0
	JMS I 7
	FPUT FPAC1
	FMPY FPAC1
	FEXT
	JMP I SQUARE
	0
	*1000
ACMINS,	0
	CLL CLA
	TAD OVER2
	CMA IAC
	DCA OVER2
	TAD LORD
	CMA
	SZL
	CLL IAC
	DCA LORD
	TAD HORD
	CMA
	SZL
	CLL IAC
	DCA HORD
	JMP I ACMINS
ALIGN,	0
	TAD HORD
	SZA CLA
	JMP .+4
	TAD LORD
	SNA CLA
	JMP NOHERE
	TAD AC1H
	SZA CLA
	JMP .+4
	TAD AC1L
	SNA CLA
	JMP I ALIGN
	TAD EX1
	CMA IAC
	TAD EXP
	SNA
	JMP DONE
	SPA
	CMA IAC
	DCA AMOUNT
	TAD AMOUNT
	TAD TEST2
	SPA CLA
	JMP .+6
	JMS OUTGO
	SZL
	TAD TAG2
	TAD TAG1
	JMP NOGO
	JMS OUTGO
	SNL
	TAD TAG2
	TAD TAG1
	DCA TEST3
	TAD AMOUNT
	TAD I TEST3
	DCA I TEST3
	ISZ TEST3
	TAD TEST3
	DCA TEST4
	ISZ TEST4
	TAD TEST4
	DCA TEST5
	ISZ TEST5
	CLA CMA
	TAD AMOUNT
	DCA FK
	TAD I TEST4
	MQL
	TAD I TEST3
	ASR
FK,	0
	DCA FK
	MQA
	DCA OUTGO
	TAD AMOUNT
	TAD OUTGO-1
	SPA
	JMP FJ
	DCA FM
	TAD I TEST4
	MQL
	TAD I TEST3
	LSR
FM,	0
	CLA!MQA
	DCA I TEST5
	TAD FK
	DCA I TEST3
	TAD OUTGO
	DCA I TEST4
DONE,	ISZ ALIGN
	JMP I ALIGN
	-15
OUTGO,	0
	TAD EX1
	CMA IAC
	TAD EXP
	RAL
	CLA
	JMP I OUTGO
NOGO,	DCA TEST3
	TAD I TEST3
	DCA EXP
	ISZ TEST3
	TAD I TEST3
	DCA HORD
	ISZ TEST3
	TAD I TEST3
	DCA LORD
	JMP I ALIGN
NOHERE,	TAD EX1
	DCA EXP
	JMP DONE
FJ,	CLA CMA
	TAD AMOUNT
	DCA FM
	TAD I TEST5
	MQL
	TAD I TEST4
	JMP FM-1
AMOUNT,	0
TEST2,	-31
TEST3,	0
TEST4,	0
TEST5,	0
TAG1,	EXP
TAG2,	EX1-EXP
EXIT6,	0
	JMP I EXIT6
	0
/			ONE WORD LEFT
	*1200
DIVI,	0
	CLA CLL
	TAD HORD
	SPA
	CLL CML
	RAR
	DCA HORD
	TAD LORD
	RAR
	DCA LORD
	TAD OVER2
	RAR
	DCA OVER2
	CLL
	ISZ EXP
	NOP
	JMP I DIVI
DMULT,	0
	CLA CLL
	JMS SIGN
	TAD AC1L
	DCA FN
	TAD LORD
	MQL!MUY
FN,	0
	DCA OVER2
	TAD HORD
	DCA FP
	TAD AC1L
	MQL!MUY
FP,	0
	DCA FN
	MQA
	TAD OVER2
	DCA OVER2
	RAL
	TAD FN
	DCA FN
	TAD AC1H
	DCA .+3
	TAD LORD
	MQL!MUY
	0
	DCA FP
	MQA
	TAD OVER2
	DCA OVER2
	RAL
	TAD FP
	TAD FN
	DCA FN
	RAL
	DCA FP
	TAD HORD
	DCA FR
	TAD AC1H
	MQL!MUY
FR,	0
	DCA HORD
	MQA
	TAD FN
	DCA LORD
	RAL
	TAD HORD
	TAD FP
	DCA HORD
FLDV,	JMS I NORMF
	DCA OVER2
	ISZ SGN
	JMP I DMULT
	JMS I MINS
	JMP I DMULT
FLDV2,	TAD AC1H
	SZA CLA
	JMP .+4
	TAD AC1L
	SNA CLA
	JMP I ERROR
	TAD EX1
	CMA IAC
	TAD EXP
	DCA EXP
	JMS SIGN
	JMS I DIVIDE
	TAD .+3
	DCA DMULT
	JMP FLDV
	FPNT+1
SIGN,	0
	TAD REST
	DCA SGN
	TAD HORD
	SMA CLA
	JMP .+3
	JMS I MINS
	ISZ SGN
	TAD AC1H
SNSWIT,	SMA CLA
	JMP I SIGN
	JMS I MINS2
	ISZ SGN
	NOP
	JMP I SIGN
NORMF,	DNORM
DIVIDE,	DUBDIV
RETURN,	FPNT+1
SGN,	0
REST,	7776
MINS2,	MINUS2
MINS,	ACMINS
ERROR,	ERROR1
DIV2,	0
	CLA CLL
	TAD AC1H
	SPA
	CLL CML
	RAR
	DCA AC1H
	TAD AC1L
	RAR 
	DCA AC1L
	TAD OVER1
	RAR
	DCA OVER1
	CLL
	JMP I DIV2
	0
	0
	0
	*1400
RETN2,	FPNT+1
ERROR1,	TAD GOOF
	DCA EXP
	TAD GOOF
	DCA HORD
	CMA
	DCA LORD
	ISZ FLAG
	JMP I RETN2
GOOF,	3777
MINUS2,	0
	CLA CLL
	TAD OVER1
	CMA IAC
	DCA OVER1
	TAD AC1L
	CMA
	SZL
	CLL IAC
	DCA AC1L
	TAD AC1H
	CMA 
	SZL
	CLL IAC
	DCA AC1H
	JMP I MINUS2
DUBDIV,	0
	DCA FX
	TAD AC1L
	CLL RAL
	DCA DVX
	TAD AC1H
	RAL
	DCA DV2
	TAD DV2
	DCA DV3
	TAD LORD
	MQL
	TAD HORD
	DVI
DV3,	0
	DCA DV3
	MQA
	DCA HORD
	MUY
DVX,	0
	CLL IAC CMA
	TAD DV3
	SNA
	JMP FT
	SNL
	JMP FU
	DCA DVX
	CMA
	DCA FX
	MQA
	CLL IAC CMA
	MQL
	SNL
	CMA
	TAD DVX
	DVI
DV2,	0
	CLA!MQA
	STL
	ISZ FX
	CLL IAC CMA
FT,	DCA LORD
	SNL
	CMA
	TAD HORD
	SPA
	JMP FX+1
	DCA HORD
	JMP I DUBDIV
FU,	CIA
	DCA DV3
	TAD DV2
	CLL IAC CMA
	TAD DV3
	SNL
	JMP .+5
	DCA DV3
	CMA
	TAD HORD
	DCA HORD
	CLA
	TAD DV3
	SZA
	JMP DV2-1
	JMP FT-1
FX,	0
	CLL RAR
	DCA HORD
	TAD LORD
	RAR
	DCA LORD
	ISZ EXP
	NOP
	JMP I DUBDIV
FDIV2,	DIV2
TABLE6,	SQUARE
	SQROOT
	SINE
	COS
	ARTN
	EXPNT
	LOG
	INPT
	OUTP
	EXIT6
	EXIT6
	EXIT6
	EXIT6
	EXIT6
	EXIT6
DUNORM,	0
	JMS I FDIV2
	JMS I RAR1
	ISZ EX1
	NOP
	JMP I DUNORM
RAR1,	DIVI
	0
	0
	0
	0
	0
/			EMPTY
	*1600
DNORM,	0
	CLA CLL CML
	TAD HORD
	SPA CLA
	JMS I NEG
	SZL
	CMA
	DCA FD1
	TAD HORD
	SZA CLA
	JMP GO6
	TAD LORD
	SPA
	JMP GO6+1
	DCA HORD
	TAD OVER2
	DCA LORD
	DCA OVER2
	TAD FM14
	TAD EXP
	DCA EXP
GO6,	TAD LORD
	MQL
	TAD HORD
	NMI
	SNA
	DCA EXP
	DCA HORD
	SCA
	SNA
	JMP EXIT2
	CIA
	TAD EXP
	DCA EXP
	SCA
	TAD FM1
	DCA .+5
	TAD OVER2
	MQL
	TAD LORD
	SHL
	0
	DCA LORD
	MQA
	DCA OVER2
EXIT2,	ISZ FD1
	JMS I NEG
	JMP I DNORM
FD1,	0
FM14,	-14
FM1,	-1
SQROOT,	0
	DCA FLAG1
	TAD HORD
	SMA CLA
	JMP .+3
	JMS I NEG
	ISZ FLAG1
	JMS I 007
	FPUT FPAC1
	FEXT
	TAD EXP
	CLL
	SPA
	CML
	RAR
	SZL
	IAC
	DCA ITER1
	TAD SQCON1
	DCA ITER1+1
	DCA ITER1+2
	TAD FPAC1+1
	SZA CLA
	JMP CLCU
	TAD FPAC1+2
	SZA CLA
	JMP CLCU
	DCA EXP
	JMP I SQROOT
	JMS I 7
	FPUT ITER1
	FEXT
CLCU,	JMS I 7
	FGET FPAC1
	FDIV ITER1
	FADD ITER1
	FEXT
	CLA CMA
	TAD EXP
	DCA EXP
	TAD EXP
	CIA
	TAD ITER1
	SZA CLA
	JMP CLCU-3
	TAD HORD
	CMA IAC
	TAD ITER1+1
	SZA CLA
	JMP CLCU-3
	TAD LORD
	CMA IAC
	TAD ITER1+2
	SMA
	CMA IAC
	IAC
	SPA CLA
	JMP CLCU-3
	TAD FLAG1
	DCA FLAG
	JMP I SQROOT
ITER1,	0
	0
	0
SQCON1,	3015
FLAG1,	0
NEG,	ACMINS
SIGN1,	0
	*2000
DECONV,	0
	CLA
	DCA HORDER
	DCA LORDER
	DCA SIGNNN
	DCA DNUMBR
	JMS INPUT
	TAD PLUS
	SNA
	JMP DECON
	TAD MINUS
	SZA
	JMP .+4
	CLA CMA
	DCA SIGNNN
DECON,	JMS INPUT
	CLA
	TAD CHAR
	TAD MIN9
	SMA
	JMP I DECONV
	TAD PLUS12
	SPA
	JMP I DECONV
	DCA DIGIT
	TAD HORDER
	AND MASK
	SZA
	JMP DECON
	ISZ DSWIT
	ISZ DNUMBR
	JMS MULT10
	JMP DECON
MULT10,	0
	TAD LORDER
	DCA LTEMP
	TAD HORDER
	DCA HTEMP
	DCA REMAIN
	JMS MULT2
	JMS MULT2
	JMS DUBLAD
	JMS MULT2
	TAD DIGIT
	DCA LTEMP
	DCA HTEMP
	JMS DUBLAD
	TAD REMAIN
	JMP I MULT10
LTEMP,	0
HTEMP,	0
DIGIT,	0
REMAIN,	0
SIGNNN,	0
DNUMBR,	0
MULT2,	0
	CLA CLL
	TAD LORDER
	RAL
	DCA LORDER
	TAD HORDER
	RAL
	DCA HORDER
	TAD REMAIN
	RAL
	DCA REMAIN
	JMP I MULT2
DUBLAD,	0
	CLA CLL
	TAD LORDER
	TAD LTEMP
	DCA LORDER
	RAL
	TAD HORDER
	TAD HTEMP
	DCA HORDER
	RAL
	TAD REMAIN
	DCA REMAIN
	JMP I DUBLAD
MSIGN,	0
	CLA CLL
	ISZ SIGNNN
	JMP I MSIGN
	TAD LORDER
	CMA IAC
	DCA LORDER
	TAD HORDER
	CMA
	SZL
	IAC
	DCA HORDER
	JMP I MSIGN
MINUS,	253-255
PLUS,	-253
MIN9,	-272
PLUS12,	272-260
MASK,	7600
INPUT,	0
	CLA
	KSF
	JMP .-1
	KRB
	DCA CHAR
	TAD CHAR
	JMS I OUTPUT
	TAD CHAR
	SNA
	JMP INPUT+1
	TAD MRBOUT
	SNA
	JMP I RESTRT
	TAD MINCR
	SNA CLA
	JMS I PRINT
	TAD CHAR
	JMP I INPUT
PRINT,	PRCHAR
OUTPUT,	OUT
RESTRT,	FLINTP+1
MRBOUT,	-377
MINCR,	377-215
	*2200
FLOUTP,	0
	JMS I ED2
	JMS FOUTCN
	TAD BEXP
	JMS I ED1
	JMS OUT
	JMS I FEXPPT
	CLA
	SNA CLA
	JMP I FLOUTP
	TAD CARRTN
	JMS OUT
	TAD LNFEED
	JMS OUT
	JMP I FLOUTP
FOUTCN,	0
	CLA CLL
	TAD HORDER
	SPA CLA
	CLA CML
	TAD SPLUS
	SZL
	TAD SMINUS
	DCA I 15
	NOP
	NOP
	NOP
	CLA CLL
	TAD HORDER
	SMA CLA
	JMP FGO1
	CMA
	DCA I SNPT
	JMS I MSNPT
FGO1,	CLA CMA
	TAD EXPONT
	DCA EXPONT
	DCA BEXP
FGO2,	TAD EXPONT
	SMA
	JMP FGO3
	TAD FOUR
	SMA CLA
	JMP FGO4
	JMS I 7
	FMPY I TENPT
	FEXT
	CLA CMA
	TAD BEXP
	DCA BEXP
	JMP FGO2
FGO3,	JMS I 7
	FMPY CCC10
	FEXT
	ISZ BEXP
	JMP FGO2
FGO4,	DCA I DPT
	JMS I M2PT
	JMS I M10PT
	SKP
FGO5A,	JMS DIVTWO
	ISZ EXPONT
	JMP FGO5A
	SNA
	JMP FGO7
FGO6,	DCA I 15
	TAD MINUS7
	DCA EXPONT
FGO6A,	JMS I M10PT
	DCA I 15
	ISZ EXPONT
	JMP FGO6A
	JMP I FOUTCN
FGO7,	CLA CMA
	TAD BEXP
	DCA BEXP
	TAD HORDER
	SZA CLA
	JMP .+4
	TAD LORDER
	SNA CLA
	DCA BEXP
	CLA CMA
	JMP FGO6+1
BEXP,	0
MINUS7,	7772
FOUR,	0004
SPLUS,	253
SMINUS,	255-253
PERIOD,	256
MSNPT,	MSIGN
SNPT,	SIGNNN
DPT,	DIGIT
M10PT,	MULT10
M2PT,	MULT2
FEXPPT,	FEXC
TENPT,	TEN
CARRTN,	0215
LNFEED,	0212
CHE,	305
OUT,	0
	TSF
	JMP .-1
	TLS
	CLA
	JMP I OUT
OUTDG,	0
	TAD C260
	JMS OUT
	JMP I OUTDG
C260,	0260
DIVTWO,	0
	CLL RAR
	DCA OUT
	TAD HORDER
	RAR
	DCA HORDER
	TAD LORDER
	RAR
	DCA LORDER
	TAD OUT
	JMP I DIVTWO
CCC10,	7775
	3146
	3147
ED1,	TGO
ED2,	EDIT
	*2400
FLINTP,	0
	CLA CMA
	DCA PRSW
	DCA DSWIT
	JMS I DPCVPT
	CLA
	TAD CHAR
	TAD PER
	SZA CLA
	JMP FIGO1
	TAD PRSW
	SNA CLA
	JMP FIGO2
	DCA I DPN
	DCA PRSW
	JMP I DPCSPT
FIGO1,	TAD PRSW
	SNA CLA
FIGO2,	TAD I DPN
	CMA IAC
	DCA SEXP
	JMS I MSGNPT
FIGO3,	TAD C27
	DCA EXPONT
	JMS I 7
	FNOR
	FPUT FPAC1
	FEXT
	TAD CHAR
	TAD MINUSE
	SZA CLA
	JMP ENDFI
	JMS I DPCVPT
	JMS I MSGNPT
	TAD HORDER
	SPA
	IAC
	SZA CLA
	JMP EXCESS
	TAD LORDER
	TAD SEXP
	DCA SEXP
ENDFI,	JMS I 7
	FGET FPAC1
	FEXT
	TAD SEXP
	SNA
	JMP I FLINTP
	SMA CLA
	JMP FIGO4
	JMS I 7
	FMPY I PCPC10
	FEXT
	ISZ SEXP
	JMP ENDFI+3
	JMP I FLINTP
FIGO4,	JMS I 7
	FMPY TEN
	FEXT
	CLA CMA
	TAD SEXP
	DCA SEXP
	JMP ENDFI+3
EXCESS,	TAD C3777
	DCA EXPONT
	TAD C3777
	DCA HORDER
	JMP I FLINTP
TEN,	0004
	2400
	0000
PCPC10,	CCC10
MINUSE,	-305
C27,	0027
PER,	-256
PRSW,	0
SEXP,	0
C3777,	3777
DPCVPT,	DECONV
DPCSPT,	DECON
MSGNPT,	MSIGN
DPN,	DNUMBR
FEXC,	0
	CLA CLL
	TAD EXPONT
	SPA
	CMA IAC CML
	DCA EXPONT
	TAD C253
	SZL
	TAD C255
	JMS I DGPT
	DCA HORDER
	TAD EXPONT
	ISZ HORDER
	TAD M144
	SMA
	JMP .-3
	TAD C144
	DCA EXPONT
	CMA
	TAD HORDER
	SZA
	JMS I DGPT
	DCA HORDER
	TAD EXPONT
	ISZ HORDER
	TAD M12
	SMA
	JMP .-3
	TAD C12
	DCA LORDER
	CLA CMA
	TAD HORDER
	JMS I DGPT
	TAD LORDER
	JMS I DGPT
	JMP I FEXC
C253,	0253-260
C255,	255-253
M144,	7634
C144,	0144
M12,	7766
C12,	0012
DGPT,	OUTDG
	FADD=1000
	FSUB=2000
	FMPY=3000
	FDIV=4000
	FGET=5000
	FPUT=6000
	FNOR=7000
	FEXT=0000
	SQRE=1
	SQRT=2
	FSIN=3
	FCOS=4
	FATN=5
	FEXP=6
	FLOG=7
	FINP=10
	FOUT=11
	SCL=7403
	MUY=7405
	DVI=7407
	NMI=7411
	SHL=7413
	ASR=7415
	LSR=7417
	MQL=7421
	SCA=7441
	MQA=7501
	CLA=7601
	CAM=7621
/
/
/
	*2600
EDIT,	0
	DCA SAC
	TAD 62
	CMA IAC
	DCA COUNT1
	TAD M8
	DCA COUNT2
	TAD SAD1
	DCA 15
	JMP I EDIT
TGO,	0
	DCA 44
	TAD SAD1
	DCA 15
	TAD I 15
	JMS I OUT1
	TAD 62
	7700		/CLA CMA
	JMP EFORM
	ISZ TGO
	ISZ TGO
TRYAGN,	TAD 44
	SPA
	JMP MINSS
	TAD SAC
	CMA IAC
	TAD 62
	SPA
	JMP ERR
	SNA
	JMP G01
	CMA IAC
	DCA CNTR
	TAD SPCE
	JMS OUTT
	ISZ CNTR
	JMP .-3
G01,	TAD 44
	CIA
	SNA
	JMP G02
	DCA CNTR
	JMS GET
	JMS OUTT
	ISZ CNTR
	JMP .-3
G02,	TAD SAC
	7650		/SNA CLA
	JMP .+3
	TAD PERID
	JMS I OUT1
	JMS GET
	JMS OUTT
	JMP .-2
ERR,	TAD SAC
	7700		/CLA CMA
	JMP ERGO
	TAD CHX
	JMS OUTT
	JMP .-2
ERGO,	7240		/CLA CMA
	TAD SAC
	DCA SAC
	JMP TRYAGN
MINSS,	CLA
	TAD 62
	CIA
	TAD SAC
	SNA
	JMP G03
	DCA CNTR
	TAD SPCE
	JMS OUTT
	ISZ CNTR
	JMP .-3
G03,	TAD PERID
	JMS I OUT1
	JMS OUTT
	ISZ 44
	JMP .-2
	JMP G02+5
OUTT,	0
	JMS I OUT2
	ISZ COUNT1
	JMP I OUTT
	TAD CHEE
	JMP I TGO
EFORM,	JMS I OUT2
	TAD PERID
	JMS I OUT1
	TAD M7
	DCA COUNT1
	JMS GET
	JMS OUTT
	JMP .-2
GET,	0
	ISZ COUNT2
	JMP .+4
	7240		/CLA CMA
	DCA COUNT2
	JMP I GET
	TAD I 15
	JMP I GET
COUNT1,	0
COUNT2,	0
CNTR,	0
SAC,	0
SPCE,	240-260
PERID,	256
CHEE,	305
CHX,	330-260
M8,	-10
M7,	-7
OUT1,	OUT
OUT2,	OUTDG
SAD1,	BUFFER-1
BUFFER,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	FENT=JMS I 7
	INPF=JMS I 5
	OUTF=JMS I 6
	*3000
FIX,	0
	TAD EXP
	SMA SZA
	JMP .+3
	CLA
	JMP FIXEND
	TAD FM13
	DCA EXP
LOOP,	TAD EXP
	CLA SMA
	JMP I FIX
	JMS I .+2
	JMP LOOP
	DIVI
FIXEND,	DCA HORD
	JMP I FIX
FM13,	-13
INPT,	0
	JMS I 5
	JMP I INPT
OUTP,	0
	JMS I 7
	FPUT FOUTP
	FEXT
	CLA
	TAD 63
	JMS I 6
	JMS I 7
	FGET FOUTP
	FEXT
	JMP I OUTP
FOUTP,	0
	0
	0
SINE,	0
	JMP I SINE
COS,	0
	JMP I COS
ARTN,	0
	JMP I ARTN
EXPNT,	0
	JMP I EXPNT
LOG,	0
	JMP I LOG
/
/
/
/
/
/
/
/
/
/
/
/
/
/
	LMODE
	SEGMNT 2
	*20
	PDP
	PMODE
	TLS
START,	CLA CLL
	OSR
	SPA
	JMP TWO+1
	TAD M777
	SMA
	JMP TWO
	TAD P777
	DCA FUN
	JMP ONE
TWO,	TAD P777
	TAD ADD
	DCA FUN
	INPF
	FENT
	FPUT A
	FEXT
ONE,	INPF
	FENT
FUN,	0
	FEXT
	TAD P5
	OUTF
	JMP START
ADD,	A&177!200
A,	0
	0
	0
P777,	777
M777,	-777
P5,	5
	LMODE